ui-lib.pl

   1 use vars qw($theme_no_table $ui_radio_selector_donejs $module_name
   2             $ui_multi_select_donejs);
   3
   4 =head1 ui-lib.pl
   5
   6 Common functions for generating HTML for Webmin user interface elements.
   7 Some example code :
   8
   9  use WebminCore;
  10  init_config();
  11  ui_print_header(undef, 'My Module', '');
  12
  13  print ui_form_start('save.cgi');
  14  print ui_table_start('My form', undef, 2);
  15
  16  print ui_table_row('Enter your name',
  17         ui_textbox('name', undef, 40));
  18
  19  print ui_table_end();
  20  print ui_form_end([ [ undef, 'Save' ] ]);
  21
  22  ui_print_footer('/', 'Webmin index');
  23
  24 =cut
  25
  26 ####################### table generation functions
  27
  28 =head2 ui_table_start(heading, [tabletags], [cols], [&default-tds], [right-heading])
  29
  30 Returns HTML for the start of a form block into which labelled inputs can
  31 be placed. By default this is implemented as a table with another table inside
  32 it, but themes may override this with their own layout.
  33
  34 The parameters are :
  35
  36 =item heading - Text to show at the top of the form.
  37
  38 =item tabletags - HTML attributes to put in the outer <table>, typically something like width=100%.
  39
  40 =item cols - Desired number of columns for labels and fields. Defaults to 4, but can be 2 for forms with lots of wide inputs.
  41
  42 =item default-tds - An optional array reference of HTML attributes for the <td> tags in each row of the table.
  43
  44 =item right-heading - HTML to appear in the heading, aligned to the right.
  45
  46 =cut
  47 sub ui_table_start
  48 {
  49 return &theme_ui_table_start(@_) if (defined(&theme_ui_table_start));
  50 my ($heading, $tabletags, $cols, $tds, $rightheading) = @_;
  51 if (defined($main::ui_table_cols)) {
  52         # Push on stack, for nested call
  53         push(@main::ui_table_cols_stack, $main::ui_table_cols);
  54         push(@main::ui_table_pos_stack, $main::ui_table_pos);
  55         push(@main::ui_table_default_tds_stack, $main::ui_table_default_tds);
  56         }
  57 my $colspan = 1;
  58 my $rv;
  59 $rv .= "<table class='ui_table' border $tabletags>\n";
  60 if (defined($heading) || defined($rightheading)) {
  61         $rv .= "<tr $tb class='ui_table_head'>";
  62         if (defined($heading)) {
  63                 $rv .= "<td><b>$heading</b></td>"
  64                 }
  65         if (defined($rightheading)) {
  66                 $rv .= "<td align=right>$rightheading</td>";
  67                 $colspan++;
  68                 }
  69         $rv .= "</tr>\n";
  70         }
  71 $rv .= "<tr $cb class='ui_table_body'> <td colspan=$colspan>".
  72        "<table width=100%>\n";
  73 $main::ui_table_cols = $cols || 4;
  74 $main::ui_table_pos = 0;
  75 $main::ui_table_default_tds = $tds;
  76 return $rv;
  77 }
  78
  79 =head2 ui_table_end
  80
  81 Returns HTML for the end of a block started by ui_table_start.
  82
  83 =cut
  84 sub ui_table_end
  85 {
  86 return &theme_ui_table_end(@_) if (defined(&theme_ui_table_end));
  87 my $rv;
  88 if ($main::ui_table_cols == 4 && $main::ui_table_pos) {
  89         # Add an empty block to balance the table
  90         $rv .= &ui_table_row(" ", " ");
  91         }
  92 if (@main::ui_table_cols_stack) {
  93         $main::ui_table_cols = pop(@main::ui_table_cols_stack);
  94         $main::ui_table_pos = pop(@main::ui_table_pos_stack);
  95         $main::ui_table_default_tds = pop(@main::ui_table_default_tds_stack);
  96         }
  97 else {
  98         $main::ui_table_cols = undef;
  99         $main::ui_table_pos = undef;
 100         $main::ui_table_default_tds = undef;
 101         }
 102 $rv .= "</table></td></tr></table>\n";
 103 return $rv;
 104 }
 105
 106 =head2 ui_table_row(label, value, [cols], [&td-tags])
 107
 108 Returns HTML for a row in a table started by ui_table_start, with a 1-column
 109 label and 1+ column value. The parameters are :
 110
 111 =item label - Label for the input field. If this is undef, no label is displayed.
 112
 113 =item value - HTML for the input part of the row.
 114
 115 =item cols - Number of columns the value should take up, defaulting to 1.
 116
 117 =item td-tags - Array reference of HTML attributes for the <td> tags in this row.
 118
 119 =cut
 120 sub ui_table_row
 121 {
 122 return &theme_ui_table_row(@_) if (defined(&theme_ui_table_row));
 123 my ($label, $value, $cols, $tds) = @_;
 124 $cols ||= 1;
 125 $tds ||= $main::ui_table_default_tds;
 126 my $rv;
 127 if ($main::ui_table_pos+$cols+1 > $main::ui_table_cols &&
 128     $main::ui_table_pos != 0) {
 129         # If the requested number of cols won't fit in the number
 130         # remaining, start a new row
 131         $rv .= "</tr>\n";
 132         $main::ui_table_pos = 0;
 133         }
 134 $rv .= "<tr class='ui_table_row'>\n"
 135         if ($main::ui_table_pos%$main::ui_table_cols == 0);
 136 $rv .= "<td valign=top $tds->[0] class='ui_label'><b>$label</b></td>\n"
 137         if (defined($label));
 138 $rv .= "<td valign=top colspan=$cols $tds->[1] class='ui_value'>$value</td>\n";
 139 $main::ui_table_pos += $cols+(defined($label) ? 1 : 0);
 140 if ($main::ui_table_pos%$main::ui_table_cols == 0) {
 141         $rv .= "</tr>\n";
 142         $main::ui_table_pos = 0;
 143         }
 144 return $rv;
 145 }
 146
 147 =head2 ui_table_hr
 148
 149 Returns HTML for a row in a block started by ui_table_row, with a horizontal
 150 line inside it to separate sections.
 151
 152 =cut
 153 sub ui_table_hr
 154 {
 155 return &theme_ui_table_hr(@_) if (defined(&theme_ui_table_hr));
 156 my $rv;
 157 if ($ui_table_pos) {
 158         $rv .= "</tr>\n";
 159         $ui_table_pos = 0;
 160         }
 161 $rv .= "<tr class='ui_table_hr'> ".
 162        "<td colspan=$main::ui_table_cols><hr></td> </tr>\n";
 163 return $rv;
 164 }
 165
 166 =head2 ui_table_span(text)
 167
 168 Outputs a table row that spans the whole table, and contains the given text.
 169
 170 =cut
 171 sub ui_table_span
 172 {
 173 my ($text) = @_;
 174 return &theme_ui_table_hr(@_) if (defined(&theme_ui_table_hr));
 175 my $rv;
 176 if ($ui_table_pos) {
 177         $rv .= "</tr>\n";
 178         $ui_table_pos = 0;
 179         }
 180 $rv .= "<tr class='ui_table_span'> ".
 181        "<td colspan=$main::ui_table_cols>$text</td> </tr>\n";
 182 return $rv;
 183 }
 184
 185 =head2 ui_columns_start(&headings, [width-percent], [noborder], [&tdtags], [heading])
 186
 187 Returns HTML for the start of a multi-column table, with the given headings.
 188 The parameters are :
 189
 190 =item headings - An array reference of headers for the table's columns.
 191
 192 =item width-percent - Desired width as a percentage, or undef to let the browser decide.
 193
 194 =item noborder - Set to 1 if the table should not have a border.
 195
 196 =item tdtags - An optional reference to an array of HTML attributes for the table's <td> tags.
 197
 198 =item heading - An optional heading to put above the table.
 199
 200 =cut
 201 sub ui_columns_start
 202 {
 203 return &theme_ui_columns_start(@_) if (defined(&theme_ui_columns_start));
 204 my ($heads, $width, $noborder, $tdtags, $title) = @_;
 205 my $rv;
 206 $rv .= "<table".($noborder ? "" : " border").
 207                 (defined($width) ? " width=$width%" : "")." class='ui_columns'>\n";
 208 if ($title) {
 209         $rv .= "<tr $tb class='ui_columns_heading'>".
 210                "<td colspan=".scalar(@$heads)."><b>$title</b></td></tr>\n";
 211         }
 212 $rv .= "<tr $tb class='ui_columns_heads'>\n";
 213 my $i;
 214 for($i=0; $i<@$heads; $i++) {
 215         $rv .= "<td ".$tdtags->[$i]."><b>".
 216                ($heads->[$i] eq "" ? "<br>" : $heads->[$i])."</b></td>\n";
 217         }
 218 $rv .= "</tr>\n";
 219 return $rv;
 220 }
 221
 222 =head2 ui_columns_row(&columns, &tdtags)
 223
 224 Returns HTML for a row in a multi-column table. The parameters are :
 225
 226 =item columns - Reference to an array containing the HTML to show in the columns for this row.
 227
 228 =item tdtags - An optional array reference containing HTML attributes for the row's <td> tags.
 229
 230 =cut
 231 sub ui_columns_row
 232 {
 233 return &theme_ui_columns_row(@_) if (defined(&theme_ui_columns_row));
 234 my ($cols, $tdtags) = @_;
 235 my $rv;
 236 $rv .= "<tr $cb class='ui_columns_row'>\n";
 237 my $i;
 238 for($i=0; $i<@$cols; $i++) {
 239         $rv .= "<td ".$tdtags->[$i].">".
 240                ($cols->[$i] !~ /\S/ ? "<br>" : $cols->[$i])."</td>\n";
 241         }
 242 $rv .= "</tr>\n";
 243 return $rv;
 244 }
 245
 246 =head2 ui_columns_header(&columns, &tdtags)
 247
 248 Returns HTML for a row in a multi-column table, styled as a header. Parameters
 249 are the same as ui_columns_row.
 250
 251 =cut
 252 sub ui_columns_header
 253 {
 254 return &theme_ui_columns_header(@_) if (defined(&theme_ui_columns_header));
 255 my ($cols, $tdtags) = @_;
 256 my $rv;
 257 $rv .= "<tr $tb class='ui_columns_header'>\n";
 258 my $i;
 259 for($i=0; $i<@$cols; $i++) {
 260         $rv .= "<td ".$tdtags->[$i]."><b>".
 261                ($cols->[$i] eq "" ? "<br>" : $cols->[$i])."</b></td>\n";
 262         }
 263 $rv .= "</tr>\n";
 264 return $rv;
 265 }
 266
 267 =head2 ui_checked_columns_row(&columns, &tdtags, checkname, checkvalue, [checked?], [disabled])
 268
 269 Returns HTML for a row in a multi-column table, in which the first column
 270 contains a checkbox. The parameters are :
 271
 272 =item columns - Reference to an array containing the HTML to show in the columns for this row.
 273
 274 =item tdtags - An optional array reference containing HTML attributes for the row's <td> tags.
 275
 276 =item checkname - Name for the checkbox input. Should be the same for all rows.
 277
 278 =item checkvalue - Value for this checkbox input.
 279
 280 =item checked - Set to 1 if it should be checked by default.
 281
 282 =item disabled - Set to 1 if the checkbox should be disabled and thus un-clickable.
 283
 284 =cut
 285 sub ui_checked_columns_row
 286 {
 287 return &theme_ui_checked_columns_row(@_) if (defined(&theme_ui_checked_columns_row));
 288 my ($cols, $tdtags, $checkname, $checkvalue, $checked, $disabled) = @_;
 289 my $rv;
 290 $rv .= "<tr $cb class='ui_checked_columns'>\n";
 291 $rv .= "<td class='ui_checked_checkbox' ".$tdtags->[0].">".
 292        &ui_checkbox($checkname, $checkvalue, undef, $checked, undef, $disabled).
 293        "</td>\n";
 294 my $i;
 295 for($i=0; $i<@$cols; $i++) {
 296         $rv .= "<td ".$tdtags->[$i+1].">";
 297         if ($cols->[$i] !~ /<a\s+href|<input|<select|<textarea/) {
 298                 $rv .= "<label for=\"".
 299                         &quote_escape("${checkname}_${checkvalue}")."\">";
 300                 }
 301         $rv .= ($cols->[$i] !~ /\S/ ? "<br>" : $cols->[$i]);
 302         if ($cols->[$i] !~ /<a\s+href|<input|<select|<textarea/) {
 303                 $rv .= "</label>";
 304                 }
 305         $rv .= "</td>\n";
 306         }
 307 $rv .= "</tr>\n";
 308 return $rv;
 309 }
 310
 311 =head2 ui_radio_columns_row(&columns, &tdtags, checkname, checkvalue, [checked], [disabled])
 312
 313 Returns HTML for a row in a multi-column table, in which the first
 314 column is a radio button. The parameters are :
 315
 316 =item columns - Reference to an array containing the HTML to show in the columns for this row.
 317
 318 =item tdtags - An optional array reference containing HTML attributes for the row's <td> tags.
 319
 320 =item checkname - Name for the radio button input. Should be the same for all rows.
 321
 322 =item checkvalue - Value for this radio button option.
 323
 324 =item checked - Set to 1 if it should be checked by default.
 325
 326 =item disabled - Set to 1 if the radio button should be disabled and thus un-clickable.
 327
 328 =cut
 329 sub ui_radio_columns_row
 330 {
 331 return &theme_ui_radio_columns_row(@_) if (defined(&theme_ui_radio_columns_row));
 332 my ($cols, $tdtags, $checkname, $checkvalue, $checked, $dis) = @_;
 333 my $rv;
 334 $rv .= "<tr $cb class='ui_radio_columns'>\n";
 335 $rv .= "<td class='ui_radio_radio' ".$tdtags->[0].">".
 336     &ui_oneradio($checkname, $checkvalue, "", $checked, undef, $dis)."</td>\n";
 337 my $i;
 338 for($i=0; $i<@$cols; $i++) {
 339         $rv .= "<td ".$tdtags->[$i+1].">";
 340         if ($cols->[$i] !~ /<a\s+href|<input|<select|<textarea/) {
 341                 $rv .= "<label for=\"".
 342                         &quote_escape("${checkname}_${checkvalue}")."\">";
 343                 }
 344         $rv .= ($cols->[$i] !~ /\S/ ? "<br>" : $cols->[$i]);
 345         if ($cols->[$i] !~ /<a\s+href|<input|<select|<textarea/) {
 346                 $rv .= "</label>";
 347                 }
 348         $rv .= "</td>\n";
 349         }
 350 $rv .= "</tr>\n";
 351 return $rv;
 352 }
 353
 354 =head2 ui_columns_end
 355
 356 Returns HTML to end a table started by ui_columns_start.
 357
 358 =cut
 359 sub ui_columns_end
 360 {
 361 return &theme_ui_columns_end(@_) if (defined(&theme_ui_columns_end));
 362 return "</table>\n";
 363 }
 364
 365 =head2 ui_columns_table(&headings, width-percent, &data, &types, no-sort, title, empty-msg)
 366
 367 Returns HTML for a complete table, typically generated internally by
 368 ui_columns_start, ui_columns_row and ui_columns_end. The parameters are :
 369
 370 =item headings - An array ref of heading HTML.
 371
 372 =item width-percent - Preferred total width
 373
 374 =item data - A 2x2 array ref of table contents. Each can either be a simple string, or a hash ref like :
 375
 376   { 'type' => 'group', 'desc' => 'Some section title' }
 377   { 'type' => 'string', 'value' => 'Foo', 'colums' => 3,
 378     'nowrap' => 1 }
 379   { 'type' => 'checkbox', 'name' => 'd', 'value' => 'foo',
 380     'label' => 'Yes', 'checked' => 1, 'disabled' => 1 }
 381   { 'type' => 'radio', 'name' => 'd', 'value' => 'foo', ... }
 382
 383 =item types - An array ref of data types, such as 'string', 'number', 'bytes' or 'date'
 384
 385 =item no-sort - Set to 1 to disable sorting by theme.
 386
 387 =item title - Text to appear above the table.
 388
 389 =item empty-msg - Message to display if no data.
 390
 391 =cut
 392 sub ui_columns_table
 393 {
 394 return &theme_ui_columns_table(@_) if (defined(&theme_ui_columns_table));
 395 my ($heads, $width, $data, $types, $nosort, $title, $emptymsg) = @_;
 396 my $rv;
 397
 398 # Just show empty message if no data
 399 if ($emptymsg && !@$data) {
 400         $rv .= &ui_subheading($title) if ($title);
 401         $rv .= "<span class='ui_emptymsg'><b>$emptymsg</b></span><p>\n";
 402         return $rv;
 403         }
 404
 405 # Are there any checkboxes in each column? If so, make those columns narrow
 406 my @tds = map { "valign=top" } @$heads;
 407 my $maxwidth = 0;
 408 foreach my $r (@$data) {
 409         my $cc = 0;
 410         foreach my $c (@$r) {
 411                 if (ref($c) &&
 412                     ($c->{'type'} eq 'checkbox' || $c->{'type'} eq 'radio')) {
 413                         $tds[$cc] .= " width=5" if ($tds[$cc] !~ /width=/);
 414                         }
 415                 $cc++;
 416                 }
 417         $maxwidth = $cc if ($cc > $maxwidth);
 418         }
 419 $rv .= &ui_columns_start($heads, $width, 0, \@tds, $title);
 420
 421 # Add the data rows
 422 foreach my $r (@$data) {
 423         my $c0;
 424         if (ref($r->[0]) && ($r->[0]->{'type'} eq 'checkbox' ||
 425                              $r->[0]->{'type'} eq 'radio')) {
 426                 # First column is special
 427                 $c0 = $r->[0];
 428                 $r = [ @$r[1..(@$r-1)] ];
 429                 }
 430         # Turn data into HTML
 431         my @rtds = @tds;
 432         my @cols;
 433         my $cn = 0;
 434         $cn++ if ($c0);
 435         foreach my $c (@$r) {
 436                 if (!ref($c)) {
 437                         # Plain old string
 438                         push(@cols, $c);
 439                         }
 440                 elsif ($c->{'type'} eq 'checkbox') {
 441                         # Checkbox in non-first column
 442                         push(@cols, &ui_checkbox($c->{'name'}, $c->{'value'},
 443                                                  $c->{'label'}, $c->{'checked'},
 444                                                  undef, $c->{'disabled'}));
 445                         }
 446                 elsif ($c->{'type'} eq 'radio') {
 447                         # Radio button in non-first column
 448                         push(@cols, &ui_oneradio($c->{'name'}, $c->{'value'},
 449                                                  $c->{'label'}, $c->{'checked'},
 450                                                  undef, $c->{'disabled'}));
 451                         }
 452                 elsif ($c->{'type'} eq 'group') {
 453                         # Header row that spans whole table
 454                         $rv .= &ui_columns_header([ $c->{'desc'} ],
 455                                                   [ "colspan=$width" ]);
 456                         next;
 457                         }
 458                 elsif ($c->{'type'} eq 'string') {
 459                         # A string, which might be special
 460                         push(@cols, $c->{'value'});
 461                         if ($c->{'columns'} > 1) {
 462                                 splice(@rtds, $cn, $c->{'columns'},
 463                                        "colspan=".$c->{'columns'});
 464                                 }
 465                         if ($c->{'nowrap'}) {
 466                                 $rtds[$cn] .= " nowrap";
 467                                 }
 468                         }
 469                 $cn++;
 470                 }
 471         # Add the row
 472         if (!$c0) {
 473                 $rv .= &ui_columns_row(\@cols, \@rtds);
 474                 }
 475         elsif ($c0->{'type'} eq 'checkbox') {
 476                 $rv .= &ui_checked_columns_row(\@cols, \@rtds, $c0->{'name'},
 477                                                $c0->{'value'}, $c0->{'checked'},
 478                                                $c0->{'disabled'});
 479                 }
 480         elsif ($c0->{'type'} eq 'radio') {
 481                 $rv .= &ui_radio_columns_row(\@cols, \@rtds, $c0->{'name'},
 482                                              $c0->{'value'}, $c0->{'checked'},
 483                                              $c0->{'disabled'});
 484                 }
 485         }
 486
 487 $rv .= &ui_columns_end();
 488 return $rv;
 489 }
 490
 491 =head2 ui_form_columns_table(cgi, &buttons, select-all, &otherlinks, &hiddens, &headings, width-percent, &data, &types, no-sort, title, empty-msg, form-no)
 492
 493 Similar to ui_columns_table, but wrapped in a form. Parameters are :
 494
 495 =item cgi - URL to submit the form to.
 496
 497 =item buttons - An array ref of buttons at the end of the form, similar to that taken by ui_form_end.
 498
 499 =item select-all - If set to 1, include select all / invert links.
 500
 501 =item otherslinks - An array ref of other links to put at the top of the table, each of which is a 3-element hash ref of url, text and alignment (left or right).
 502
 503 =item hiddens - An array ref of hidden fields, each of which is a 2-element array ref containing the name and value.
 504
 505 All other parameters are the same as ui_columns_table.
 506
 507 =cut
 508 sub ui_form_columns_table
 509 {
 510 return &theme_ui_form_columns_table(@_)
 511         if (defined(&theme_ui_form_columns_table));
 512 my ($cgi, $buttons, $selectall, $others, $hiddens,
 513        $heads, $width, $data, $types, $nosort, $title, $emptymsg, $formno) = @_;
 514 my $rv;
 515
 516 # Build links
 517 my @leftlinks = map { "<a href='$_->[0]'>$_->[1]</a>" }
 518                        grep { $_->[2] ne 'right' } @$others;
 519 my @rightlinks = map { "<a href='$_->[0]'>$_->[1]</a>" }
 520                        grep { $_->[2] eq 'right' } @$others;
 521 my $links;
 522
 523 # Add select links
 524 if (@$data) {
 525         if ($selectall) {
 526                 my $cbname;
 527                 foreach my $r (@$data) {
 528                         foreach my $c (@$r) {
 529                                 if (ref($c) && $c->{'type'} eq 'checkbox') {
 530                                         $cbname = $c->{'name'};
 531                                         last;
 532                                         }
 533                                 }
 534                         }
 535                 if ($cbname) {
 536                         unshift(@leftlinks, &select_all_link($cbname, $formno),
 537                                     &select_invert_link($cbname, $formno));
 538                         }
 539                 }
 540         }
 541
 542 # Turn to HTML
 543 if (@rightlinks) {
 544         $links = &ui_grid_table([ &ui_links_row(\@leftlinks),
 545                                   &ui_links_row(\@rightlinks) ], 2, 100,
 546                                 [ undef, "align=right" ]);
 547         }
 548 elsif (@leftlinks) {
 549         $links = &ui_links_row(\@leftlinks);
 550         }
 551
 552 # Start the form, if we need one
 553 if (@$data) {
 554         $rv .= &ui_form_start($cgi, "post");
 555         foreach my $h (@$hiddens) {
 556                 $rv .= &ui_hidden(@$h);
 557                 }
 558         $rv .= $links;
 559         }
 560
 561 # Add the table
 562 $rv .= &ui_columns_table($heads, $width, $data, $types, $nosort, $title,
 563                          $emptymsg);
 564
 565 # Add form end
 566 $rv .= $links;
 567 if (@$data) {
 568         $rv .= &ui_form_end($buttons);
 569         }
 570
 571 return $rv;
 572 }
 573
 574 ####################### form generation functions
 575
 576 =head2 ui_form_start(script, method, [target], [tags])
 577
 578 Returns HTML for the start of a a form that submits to some script. The
 579 parameters are :
 580
 581 =item script - CGI script to submit to, like save.cgi.
 582
 583 =item method - HTTP method, which must be one of 'get', 'post' or 'form-data'. If form-data is used, the target CGI must call ReadParseMime to parse parameters.
 584
 585 =item target - Optional target window or frame for the form.
 586
 587 =item tags - Additional HTML attributes for the form tag.
 588
 589 =cut
 590 sub ui_form_start
 591 {
 592 return &theme_ui_form_start(@_) if (defined(&theme_ui_form_start));
 593 my ($script, $method, $target, $tags) = @_;
 594 my $rv;
 595 $rv .= "<form class='ui_form' action='".&html_escape($script)."' ".
 596         ($method eq "post" ? "method=post" :
 597          $method eq "form-data" ?
 598                 "method=post enctype=multipart/form-data" :
 599                 "method=get").
 600         ($target ? " target=$target" : "").
 601         " ".$tags.
 602        ">\n";
 603 return $rv;
 604 }
 605
 606 =head2 ui_form_end([&buttons], [width])
 607
 608 Returns HTML for the end of a form, optionally with a row of submit buttons.
 609 These are specified by the buttons parameter, which is an array reference
 610 of array refs, with the following elements :
 611
 612 =item HTML value for the submit input for the button, or undef for none.
 613
 614 =item Text to appear on the button.
 615
 616 =item HTML or other inputs to appear after the button.
 617
 618 =item Set to 1 if the button should be disabled.
 619
 620 =item Additional HTML attributes to appear inside the button's input tag.
 621
 622 =cut
 623 sub ui_form_end
 624 {
 625 return &theme_ui_form_end(@_) if (defined(&theme_ui_form_end));
 626 my ($buttons, $width) = @_;
 627 my $rv;
 628 if ($buttons && @$buttons) {
 629         $rv .= "<table class='ui_form_end_buttons' ".($width ? " width=$width" : "")."><tr>\n";
 630         my $b;
 631         foreach $b (@$buttons) {
 632                 if (ref($b)) {
 633                         $rv .= "<td".(!$width ? "" :
 634                                       $b eq $buttons->[0] ? " align=left" :
 635                                       $b eq $buttons->[@$buttons-1] ?
 636                                         " align=right" : " align=center").">".
 637                                &ui_submit($b->[1], $b->[0], $b->[3], $b->[4]).
 638                                ($b->[2] ? " ".$b->[2] : "")."</td>\n";
 639                         }
 640                 elsif ($b) {
 641                         $rv .= "<td>$b</td>\n";
 642                         }
 643                 else {
 644                         $rv .= "<td>&nbsp;&nbsp;</td>\n";
 645                         }
 646                 }
 647         $rv .= "</tr></table>\n";
 648         }
 649 $rv .= "</form>\n";
 650 return $rv;
 651 }
 652
 653 =head2 ui_textbox(name, value, size, [disabled?], [maxlength], [tags])
 654
 655 Returns HTML for a text input box. The parameters are :
 656
 657 =item name - Name for this input.
 658
 659 =item value - Initial contents for the text box.
 660
 661 =item size - Desired width in characters.
 662
 663 =item disabled - Set to 1 if this text box should be disabled by default.
 664
 665 =item maxlength - Maximum length of the string the user is allowed to input.
 666
 667 =item tags - Additional HTML attributes for the <input> tag.
 668
 669 =cut
 670 sub ui_textbox
 671 {
 672 return &theme_ui_textbox(@_) if (defined(&theme_ui_textbox));
 673 my ($name, $value, $size, $dis, $max, $tags) = @_;
 674 $size = &ui_max_text_width($size);
 675 return "<input class='ui_textbox' name=\"".&quote_escape($name)."\" ".
 676        "value=\"".&quote_escape($value)."\" ".
 677        "size=$size ".($dis ? "disabled=true" : "").
 678        ($max ? " maxlength=$max" : "").
 679        " ".$tags.
 680        ">";
 681 }
 682
 683 =head2 ui_filebox(name, value, size, [disabled?], [maxlength], [tags], [dir-only])
 684
 685 Returns HTML for a text box for choosing a file. Parameters are the same
 686 as ui_textbox, except for the extra dir-only option which limits the chooser
 687 to directories.
 688
 689 =cut
 690 sub ui_filebox
 691 {
 692 return &theme_ui_filebox(@_) if (defined(&theme_ui_filebox));
 693 my ($name, $value, $size, $dis, $max, $tags, $dironly) = @_;
 694 return &ui_textbox($name, $value, $size, $dis, $max, $tags)."&nbsp;".
 695        &file_chooser_button($name, $dironly);
 696 }
 697
 698 =head2 ui_bytesbox(name, bytes, [size], [disabled?])
 699
 700 Returns HTML for entering a number of bytes, but with friendly kB/MB/GB
 701 options. May truncate values to 2 decimal points! The parameters are :
 702
 703 =item name - Name for this input.
 704
 705 =item bytes - Initial number of bytes to show.
 706
 707 =item size - Desired width of the text box part.
 708
 709 =item disabled - Set to 1 if this text box should be disabled by default.
 710
 711 =item tags - Additional HTML attributes for the <input> tag.
 712
 713 =item defaultunits - Units mode selected by default
 714
 715 =cut
 716 sub ui_bytesbox
 717 {
 718 my ($name, $bytes, $size, $dis, $tags, $defaultunits) = @_;
 719 my $units = 1;
 720 if ($bytes eq '' && $defaultunits) {
 721         $units = $defaultunits;
 722         }
 723 elsif ($bytes >= 10*1024*1024*1024*1024) {
 724         $units = 1024*1024*1024*1024;
 725         }
 726 elsif ($bytes >= 10*1024*1024*1024) {
 727         $units = 1024*1024*1024;
 728         }
 729 elsif ($bytes >= 10*1024*1024) {
 730         $units = 1024*1024;
 731         }
 732 elsif ($bytes >= 10*1024) {
 733         $units = 1024;
 734         }
 735 else {
 736         $units = 1;
 737         }
 738 if ($bytes ne "") {
 739         $bytes = sprintf("%.2f", ($bytes*1.0)/$units);
 740         $bytes =~ s/\.00$//;
 741         }
 742 $size = &ui_max_text_width($size || 8);
 743 return &ui_textbox($name, $bytes, $size, $dis, undef, $tags)." ".
 744        &ui_select($name."_units", $units,
 745                  [ [ 1, "bytes" ],
 746                    [ 1024, "kB" ],
 747                    [ 1024*1024, "MB" ],
 748                    [ 1024*1024*1024, "GB" ],
 749                    [ 1024*1024*1024*1024, "TB" ] ], undef, undef, undef, $dis);
 750 }
 751
 752 =head2 ui_upload(name, size, [disabled?], [tags])
 753
 754 Returns HTML for a file upload input, for use in a form with the form-data
 755 method. The parameters are :
 756
 757 =item name - Name for this input.
 758
 759 =item size - Desired width in characters.
 760
 761 =item disabled - Set to 1 if this text box should be disabled by default.
 762
 763 =item tags - Additional HTML attributes for the <input> tag.
 764
 765 =cut
 766 sub ui_upload
 767 {
 768 return &theme_ui_upload(@_) if (defined(&theme_ui_upload));
 769 my ($name, $size, $dis, $tags) = @_;
 770 $size = &ui_max_text_width($size);
 771 return "<input class='ui_upload' type=file name=\"".&quote_escape($name)."\" ".
 772        "size=$size ".
 773        ($dis ? "disabled=true" : "").
 774        ($tags ? " ".$tags : "").">";
 775 }
 776
 777 =head2 ui_password(name, value, size, [disabled?], [maxlength], [tags])
 778
 779 Returns HTML for a password text input. Parameters are the same as ui_textbox,
 780 and behaviour is identical except that the user's input is not visible.
 781
 782 =cut
 783 sub ui_password
 784 {
 785 return &theme_ui_password(@_) if (defined(&theme_ui_password));
 786 my ($name, $value, $size, $dis, $max, $tags) = @_;
 787 $size = &ui_max_text_width($size);
 788 return "<input class='ui_password' ".
 789        "type=password name=\"".&quote_escape($name)."\" ".
 790        "value=\"".&quote_escape($value)."\" ".
 791        "size=$size ".($dis ? "disabled=true" : "").
 792        ($max ? " maxlength=$max" : "").
 793        " ".$tags.
 794        ">";
 795 }
 796
 797 =head2 ui_hidden(name, value)
 798
 799 Returns HTML for a hidden field with the given name and value.
 800
 801 =cut
 802 sub ui_hidden
 803 {
 804 return &theme_ui_hidden(@_) if (defined(&theme_ui_hidden));
 805 my ($name, $value) = @_;
 806 return "<input class='ui_hidden' type=hidden ".
 807        "name=\"".&quote_escape($name)."\" ".
 808        "value=\"".&quote_escape($value)."\">\n";
 809 }
 810
 811 =head2 ui_select(name, value|&values, &options, [size], [multiple], [add-if-missing], [disabled?], [javascript])
 812
 813 Returns HTML for a drop-down menu or multiple selection list. The parameters
 814 are :
 815
 816 =item name - Name for this input.
 817
 818 =item value - Either a single initial value, or an array reference of values if this is a multi-select list.
 819
 820 =item options - An array reference of possible options. Each element can either be a scalar, or a two-element array ref containing a submitted value and displayed text.
 821
 822 =item size - Desired vertical size in rows, which defaults to 1. For multi-select lists, this must be set to something larger.
 823
 824 =item multiple - Set to 1 for a multi-select list, 0 for single.
 825
 826 =item add-if-missing - If set to 1, any value that is not in the list of options will be automatically added (and selected).
 827
 828 =item disabled - Set to 1 to disable this input.
 829
 830 =item javascript - Additional HTML attributes for the <select> input.
 831
 832 =cut
 833 sub ui_select
 834 {
 835 return &theme_ui_select(@_) if (defined(&theme_ui_select));
 836 my ($name, $value, $opts, $size, $multiple, $missing, $dis, $js) = @_;
 837 my $rv;
 838 $rv .= "<select class='ui_select' name=\"".&quote_escape($name)."\"".
 839        ($size ? " size=$size" : "").
 840        ($multiple ? " multiple" : "").
 841        ($dis ? " disabled=true" : "")." ".$js.">\n";
 842 my ($o, %opt, $s);
 843 my %sel = ref($value) ? ( map { $_, 1 } @$value ) : ( $value, 1 );
 844 foreach $o (@$opts) {
 845         $o = [ $o ] if (!ref($o));
 846         $rv .= "<option value=\"".&quote_escape($o->[0])."\"".
 847                ($sel{$o->[0]} ? " selected" : "")." ".$o->[2].">".
 848                ($o->[1] || $o->[0])."\n";
 849         $opt{$o->[0]}++;
 850         }
 851 foreach $s (keys %sel) {
 852         if (!$opt{$s} && $missing) {
 853                 $rv .= "<option value=\"".&quote_escape($s)."\"".
 854                        "selected>".($s eq "" ? "&nbsp;" : $s)."\n";
 855                 }
 856         }
 857 $rv .= "</select>\n";
 858 return $rv;
 859 }
 860
 861 =head2 ui_multi_select(name, &values, &options, size, [add-if-missing], [disabled?], [options-title, values-title], [width])
 862
 863 Returns HTML for selecting many of many from a list. By default, this is
 864 implemented using two <select> lists and Javascript buttons to move elements
 865 between them. The resulting input value is \n separated.
 866
 867 Parameters are :
 868
 869 =item name - HTML name for this input.
 870
 871 =item values - An array reference of two-element array refs, containing the submitted values and descriptions of items that are selected by default.
 872
 873 =item options - An array reference of two-element array refs, containing the submitted values and descriptions of items that the user can select from.
 874
 875 =item size - Vertical size in rows.
 876
 877 =item add-if-missing - If set to 1, any entries that are in values but not in options will be added automatically.
 878
 879 =item disabled - Set to 1 to disable this input by default.
 880
 881 =item options-title - Optional text to appear above the list of options.
 882
 883 =item values-title - Optional text to appear above the list of selected values.
 884
 885 =item width - Optional width of the two lists in pixels.
 886
 887 =cut
 888 sub ui_multi_select
 889 {
 890 return &theme_ui_multi_select(@_) if (defined(&theme_ui_multi_select));
 891 my ($name, $values, $opts, $size, $missing, $dis,
 892        $opts_title, $vals_title, $width) = @_;
 893 my $rv;
 894 my %already = map { $_->[0], $_ } @$values;
 895 my $leftover = [ grep { !$already{$_->[0]} } @$opts ];
 896 if ($missing) {
 897         my %optsalready = map { $_->[0], $_ } @$opts;
 898         push(@$opts, grep { !$optsalready{$_->[0]} } @$values);
 899         }
 900 if (!defined($width)) {
 901         $width = "200";
 902         }
 903 my $wstyle = $width ? "style='width:$width'" : "";
 904
 905 if (!$main::ui_multi_select_donejs++) {
 906         $rv .= &ui_multi_select_javascript();
 907         }
 908 $rv .= "<table cellpadding=0 cellspacing=0 class='ui_multi_select'>";
 909 if (defined($opts_title)) {
 910         $rv .= "<tr class='ui_multi_select_heads'> ".
 911                "<td><b>$opts_title</b></td> ".
 912                "<td></td> <td><b>$vals_title</b></td> </tr>";
 913         }
 914 $rv .= "<tr class='ui_multi_select_row'>";
 915 $rv .= "<td>".&ui_select($name."_opts", [ ], $leftover,
 916                          $size, 0, 0, $dis, $wstyle)."</td>\n";
 917 $rv .= "<td>".&ui_button("->", $name."_add", $dis,
 918                  "onClick='multi_select_move(\"$name\", form, 1)'")."<br>".
 919               &ui_button("<-", $name."_remove", $dis,
 920                  "onClick='multi_select_move(\"$name\", form, 0)'")."</td>\n";
 921 $rv .= "<td>".&ui_select($name."_vals", [ ], $values,
 922                          $size, 0, 0, $dis, $wstyle)."</td>\n";
 923 $rv .= "</tr></table>\n";
 924 $rv .= &ui_hidden($name, join("\n", map { $_->[0] } @$values));
 925 return $rv;
 926 }
 927
 928 =head2 ui_multi_select_javascript
 929
 930 Returns <script> section for left/right select boxes. For internal use only.
 931
 932 =cut
 933 sub ui_multi_select_javascript
 934 {
 935 return &theme_ui_multiselect_javascript()
 936         if (defined(&theme_ui_multiselect_javascript));
 937 return <<EOF;
 938 <script>
 939 // Move an element from the options list to the values list, or vice-versa
 940 function multi_select_move(name, f, dir)
 941 {
 942 var opts = f.elements[name+"_opts"];
 943 var vals = f.elements[name+"_vals"];
 944 var opts_idx = opts.selectedIndex;
 945 var vals_idx = vals.selectedIndex;
 946 if (dir == 1 && opts_idx >= 0) {
 947         // Moving from options to selected list
 948         var o = opts.options[opts_idx];
 949         vals.options[vals.options.length] = new Option(o.text, o.value);
 950         opts.remove(opts_idx);
 951         }
 952 else if (dir == 0 && vals_idx >= 0) {
 953         // Moving the other way
 954         var o = vals.options[vals_idx];
 955         opts.options[opts.options.length] = new Option(o.text, o.value);
 956         vals.remove(vals_idx);
 957         }
 958 // Fill in hidden field
 959 var hid = f.elements[name];
 960 if (hid) {
 961         var hv = new Array();
 962         for(var i=0; i<vals.options.length; i++) {
 963                 hv.push(vals.options[i].value);
 964                 }
 965         hid.value = hv.join("\\n");
 966         }
 967 }
 968 </script>
 969 EOF
 970 }
 971
 972 =head2 ui_radio(name, value, &options, [disabled?])
 973
 974 Returns HTML for a series of radio buttons, of which one can be selected. The
 975 parameters are :
 976
 977 =item name - HTML name for the radio buttons.
 978
 979 =item value - Value of the button that is selected by default.
 980
 981 =item options - Array ref of radio button options, each of which is an array ref containing the submitted value and description for each button.
 982
 983 =item disabled - Set to 1 to disable all radio buttons by default.
 984
 985 =cut
 986 sub ui_radio
 987 {
 988 return &theme_ui_radio(@_) if (defined(&theme_ui_radio));
 989 my ($name, $value, $opts, $dis) = @_;
 990 my $rv;
 991 my $o;
 992 foreach $o (@$opts) {
 993         my $id = &quote_escape($name."_".$o->[0]);
 994         my $label = $o->[1] || $o->[0];
 995         my $after;
 996         if ($label =~ /^(.*?)((<a\s+href|<input|<select|<textarea)[\000-\377]*)$/i) {
 997                 $label = $1;
 998                 $after = $2;
 999                 }
1000         $rv .= "<input class='ui_radio' type=radio ".
1001                "name=\"".&quote_escape($name)."\" ".
1002                "value=\"".&quote_escape($o->[0])."\"".
1003                ($o->[0] eq $value ? " checked" : "").
1004                ($dis ? " disabled=true" : "").
1005                " id=\"$id\"".
1006                " $o->[2]> <label for=\"$id\">".
1007                $label."</label>".$after."\n";
1008         }
1009 return $rv;
1010 }
1011
1012 =head2 ui_yesno_radio(name, value, [yes], [no], [disabled?])
1013
1014 Like ui_radio, but always displays just two inputs (yes and no). The parameters
1015 are :
1016
1017 =item name - HTML name of the inputs.
1018
1019 =item value - Option selected by default, typically 1 or 0.
1020
1021 =item yes - The value for the yes option, defaulting to 1.
1022
1023 =item no - The value for the no option, defaulting to 0.
1024
1025 =item disabled - Set to 1 to disable all radio buttons by default.
1026
1027 =cut
1028 sub ui_yesno_radio
1029 {
1030 my ($name, $value, $yes, $no, $dis) = @_;
1031 return &theme_ui_yesno_radio(@_) if (defined(&theme_ui_yesno_radio));
1032 $yes = 1 if (!defined($yes));
1033 $no = 0 if (!defined($no));
1034 $value = int($value);
1035 return &ui_radio($name, $value, [ [ $yes, $text{'yes'} ],
1036                                   [ $no, $text{'no'} ] ], $dis);
1037 }
1038
1039 =head2 ui_checkbox(name, value, label, selected?, [tags], [disabled?])
1040
1041 Returns HTML for a single checkbox. Parameters are :
1042
1043 =item name - HTML name of the checkbox.
1044
1045 =item value - Value that will be submitted if it is checked.
1046
1047 =item label - Text to appear next to the checkbox.
1048
1049 =item selected - Set to 1 for it to be checked by default.
1050
1051 =item tags - Additional HTML attributes for the <input> tag.
1052
1053 =item disabled - Set to 1 to disable the checkbox by default.
1054
1055 =cut
1056 sub ui_checkbox
1057 {
1058 return &theme_ui_checkbox(@_) if (defined(&theme_ui_checkbox));
1059 my ($name, $value, $label, $sel, $tags, $dis) = @_;
1060 my $after;
1061 if ($label =~ /^([^<]*)(<[\000-\377]*)$/) {
1062         $label = $1;
1063         $after = $2;
1064         }
1065 return "<input class='ui_checkbox' type=checkbox ".
1066        "name=\"".&quote_escape($name)."\" ".
1067        "value=\"".&quote_escape($value)."\" ".
1068        ($sel ? " checked" : "").($dis ? " disabled=true" : "").
1069        " id=\"".&quote_escape("${name}_${value}")."\"".
1070        " $tags> ".
1071        ($label eq "" ? $after :
1072          "<label for=\"".&quote_escape("${name}_${value}").
1073          "\">$label</label>$after")."\n";
1074 }
1075
1076 =head2 ui_oneradio(name, value, label, selected?, [tags], [disabled?])
1077
1078 Returns HTML for a single radio button. The parameters are :
1079
1080 =item name - HTML name of the radio button.
1081
1082 =item value - Value that will be submitted if it is selected.
1083
1084 =item label - Text to appear next to the button.
1085
1086 =item selected - Set to 1 for it to be selected by default.
1087
1088 =item tags - Additional HTML attributes for the <input> tag.
1089
1090 =item disabled - Set to 1 to disable the radio button by default.
1091
1092 =cut
1093 sub ui_oneradio
1094 {
1095 return &theme_ui_oneradio(@_) if (defined(&theme_ui_oneradio));
1096 my ($name, $value, $label, $sel, $tags, $dis) = @_;
1097 my $id = &quote_escape("${name}_${value}");
1098 my $after;
1099 if ($label =~ /^([^<]*)(<[\000-\377]*)$/) {
1100         $label = $1;
1101         $after = $2;
1102         }
1103 return "<input class='ui_radio' type=radio name=\"".&quote_escape($name)."\" ".
1104        "value=\"".&quote_escape($value)."\" ".
1105        ($sel ? " checked" : "").($dis ? " disabled=true" : "").
1106        " id=\"$id\"".
1107        " $tags> <label for=\"$id\">$label</label>$after\n";
1108 }
1109
1110 =head2 ui_textarea(name, value, rows, cols, [wrap], [disabled?], [tags])
1111
1112 Returns HTML for a multi-line text input. The function parameters are :
1113
1114 =item name - Name for this HTML <textarea>.
1115
1116 =item value - Default value. Multiple lines must be separated by \n.
1117
1118 =item rows - Number of rows, in lines.
1119
1120 =item cols - Number of columns, in characters.
1121
1122 =item wrap - Wrapping mode. Can be one of soft, hard or off.
1123
1124 =item disabled - Set to 1 to disable this text area by default.
1125
1126 =item tags - Additional HTML attributes for the <textarea> tag.
1127
1128 =cut
1129 sub ui_textarea
1130 {
1131 return &theme_ui_textarea(@_) if (defined(&theme_ui_textarea));
1132 my ($name, $value, $rows, $cols, $wrap, $dis, $tags) = @_;
1133 $cols = &ui_max_text_width($cols, 1);
1134 return "<textarea class='ui_textarea' name=\"".&quote_escape($name)."\" ".
1135        "rows=$rows cols=$cols".($wrap ? " wrap=$wrap" : "").
1136        ($dis ? " disabled=true" : "").
1137        ($tags ? " $tags" : "").">".
1138        &html_escape($value).
1139        "</textarea>";
1140 }
1141
1142 =head2 ui_user_textbox(name, value, [form], [disabled?], [tags])
1143
1144 Returns HTML for an input for selecting a Unix user. Parameters are the
1145 same as ui_textbox.
1146
1147 =cut
1148 sub ui_user_textbox
1149 {
1150 return &theme_ui_user_textbox(@_) if (defined(&theme_ui_user_textbox));
1151 return &ui_textbox($_[0], $_[1], 13, $_[3], undef, $_[4])." ".
1152        &user_chooser_button($_[0], 0, $_[2]);
1153 }
1154
1155 =head2 ui_group_textbox(name, value, [form], [disabled?], [tags])
1156
1157 Returns HTML for an input for selecting a Unix group. Parameters are the
1158 same as ui_textbox.
1159
1160 =cut
1161 sub ui_group_textbox
1162 {
1163 return &theme_ui_group_textbox(@_) if (defined(&theme_ui_group_textbox));
1164 return &ui_textbox($_[0], $_[1], 13, $_[3], undef, $_[4])." ".
1165        &group_chooser_button($_[0], 0, $_[2]);
1166 }
1167
1168 =head2 ui_opt_textbox(name, value, size, option1, [option2], [disabled?], [&extra-fields], [max])
1169
1170 Returns HTML for a text field that is optional, implemented by default as
1171 a field with radio buttons next to it. The parameters are :
1172
1173 =item name - HTML name for the text box. The radio buttons will have the same name, but with _def appended.
1174
1175 =item value - Initial value, or undef if you want the default radio button selected initially.
1176
1177 =item size - Width of the text box in characters.
1178
1179 =item option1 - Text for the radio button for selecting that no input is being given, such as 'Default'.
1180
1181 =item option2 - Text for the radio button for selecting that you will provide input.
1182
1183 =item disabled - Set to 1 to disable this input by default.
1184
1185 =item extra-fields - An optional array ref of field names that should be disabled by Javascript when this field is disabled.
1186
1187 =item max - Optional maximum allowed input length, in characters.
1188
1189 =item tags - Additional HTML attributes for the text box
1190
1191 =cut
1192 sub ui_opt_textbox
1193 {
1194 return &theme_ui_opt_textbox(@_) if (defined(&theme_ui_opt_textbox));
1195 my ($name, $value, $size, $opt1, $opt2, $dis, $extra, $max, $tags) = @_;
1196 my $dis1 = &js_disable_inputs([ $name, @$extra ], [ ]);
1197 my $dis2 = &js_disable_inputs([ ], [ $name, @$extra ]);
1198 my $rv;
1199 $size = &ui_max_text_width($size);
1200 $rv .= &ui_radio($name."_def", $value eq '' ? 1 : 0,
1201                  [ [ 1, $opt1, "onClick='$dis1'" ],
1202                    [ 0, $opt2 || " ", "onClick='$dis2'" ] ], $dis)."\n";
1203 $rv .= "<input class='ui_opt_textbox' name=\"".&quote_escape($name)."\" ".
1204        "size=$size value=\"".&quote_escape($value)."\" ".
1205        ($value eq "" || $dis ? "disabled=true" : "").
1206        ($max ? " maxlength=$max" : "").
1207        " ".$tags.
1208        ">\n";
1209 return $rv;
1210 }
1211
1212 =head2 ui_submit(label, [name], [disabled?], [tags])
1213
1214 Returns HTML for a form submit button. Parameters are :
1215
1216 =item label - Text to appear on the button.
1217
1218 =item name - Optional HTML name for the button. Useful if the CGI it submits to needs to know which of several buttons was clicked.
1219
1220 =item disabled - Set to 1 if this button should be disabled by default.
1221
1222 =item tags - Additional HTML attributes for the <input> tag.
1223
1224 =cut
1225 sub ui_submit
1226 {
1227 return &theme_ui_submit(@_) if (defined(&theme_ui_submit));
1228 my ($label, $name, $dis, $tags) = @_;
1229 return "<input class='ui_submit' type=submit".
1230        ($name ne '' ? " name=\"".&quote_escape($name)."\"" : "").
1231        " value=\"".&quote_escape($label)."\"".
1232        ($dis ? " disabled=true" : "").
1233        ($tags ? " ".$tags : "").">\n";
1234
1235 }
1236
1237 =head2 ui_reset(label, [disabled?])
1238
1239 Returns HTML for a form reset button, which clears all fields when clicked.
1240 Parameters are :
1241
1242 =item label - Text to appear on the button.
1243
1244 =item disabled - Set to 1 if this button should be disabled by default.
1245
1246 =cut
1247 sub ui_reset
1248 {
1249 return &theme_ui_reset(@_) if (defined(&theme_ui_reset));
1250 my ($label, $dis) = @_;
1251 return "<input type=reset value=\"".&quote_escape($label)."\"".
1252        ($dis ? " disabled=true" : "").">\n";
1253
1254 }
1255
1256 =head2 ui_button(label, [name], [disabled?], [tags])
1257
1258 Returns HTML for a form button, which doesn't do anything when clicked unless
1259 you add some Javascript to it. The parameters are :
1260
1261 =item label - Text to appear on the button.
1262
1263 =item name - HTML name for this input.
1264
1265 =item disabled - Set to 1 if this button should be disabled by default.
1266
1267 =item tags - Additional HTML attributes for the <input> tag, typically Javascript inside an onClick attribute.
1268
1269 =cut
1270 sub ui_button
1271 {
1272 return &theme_ui_button(@_) if (defined(&theme_ui_button));
1273 my ($label, $name, $dis, $tags) = @_;
1274 return "<input type=button".
1275        ($name ne '' ? " name=\"".&quote_escape($name)."\"" : "").
1276        " value=\"".&quote_escape($label)."\"".
1277        ($dis ? " disabled=true" : "").
1278        ($tags ? " ".$tags : "").">\n";
1279 }
1280
1281 =head2 ui_date_input(day, month, year, day-name, month-name, year-name, [disabled?])
1282
1283 Returns HTML for a date-selection field, with day, month and year inputs.
1284 The parameters are :
1285
1286 =item day - Initial day of the month.
1287
1288 =item month - Initial month of the year, indexed from 1.
1289
1290 =item year - Initial year, four-digit.
1291
1292 =item day-name - Name of the day input field.
1293
1294 =item month-name - Name of the month select field.
1295
1296 =item year-name - Name of the year input field.
1297
1298 =item disabled - Set to 1 to disable all fields by default.
1299
1300 =cut
1301 sub ui_date_input
1302 {
1303 my ($day, $month, $year, $dayname, $monthname, $yearname, $dis) = @_;
1304 my $rv;
1305 $rv .= "<span class='ui_data'>";
1306 $rv .= &ui_textbox($dayname, $day, 3, $dis);
1307 $rv .= "/";
1308 $rv .= &ui_select($monthname, $month,
1309                   [ map { [ $_, $text{"smonth_$_"} ] } (1 .. 12) ],
1310                   1, 0, 0, $dis);
1311 $rv .= "/";
1312 $rv .= &ui_textbox($yearname, $year, 5, $dis);
1313 $rv .= "</span>";
1314 return $rv;
1315 }
1316
1317 =head2 ui_buttons_start
1318
1319 Returns HTML for the start of a block of action buttoms with descriptions, as
1320 generated by ui_buttons_row. Some example code :
1321
1322   print ui_buttons_start();
1323   print ui_buttons_row('start.cgi', 'Start server',
1324                        'Click this button to start the server process');
1325   print ui_buttons_row('stop.cgi', 'Stop server',
1326                        'Click this button to stop the server process');
1327   print ui_buttons_end();
1328
1329 =cut
1330 sub ui_buttons_start
1331 {
1332 return &theme_ui_buttons_start(@_) if (defined(&theme_ui_buttons_start));
1333 return "<table width=100% class='ui_buttons_table'>\n";
1334 }
1335
1336 =head2 ui_buttons_end
1337
1338 Returns HTML for the end of a block started by ui_buttons_start.
1339
1340 =cut
1341 sub ui_buttons_end
1342 {
1343 return &theme_ui_buttons_end(@_) if (defined(&theme_ui_buttons_end));
1344 return "</table>\n";
1345 }
1346
1347 =head2 ui_buttons_row(script, button-label, description, [hiddens], [after-submit], [before-submit])
1348
1349 Returns HTML for a button with a description next to it, and perhaps other
1350 inputs. The parameters are :
1351
1352 =item script - CGI script that this button submits to, like start.cgi.
1353
1354 =item button-label - Text to appear on the button.
1355
1356 =item description - Text to appear next to the button, describing in more detail what it does.
1357
1358 =item hiddens - HTML for hidden fields to include in the form this function generates.
1359
1360 =item after-submit - HTML for text or inputs to appear after the submit button.
1361
1362 =item before-submit - HTML for text or inputs to appear before the submit button.
1363
1364 =cut
1365 sub ui_buttons_row
1366 {
1367 return &theme_ui_buttons_row(@_) if (defined(&theme_ui_buttons_row));
1368 my ($script, $label, $desc, $hiddens, $after, $before) = @_;
1369 return "<form action=$script class='ui_buttons_form'>\n".
1370        $hiddens.
1371        "<tr class='ui_buttons_row'> ".
1372        "<td nowrap width=20% valign=top class=ui_buttons_label>".
1373        ($before ? $before." " : "").
1374        &ui_submit($label).($after ? " ".$after : "")."</td>\n".
1375        "<td valign=top width=80% valign=top class=ui_buttons_value>".
1376        $desc."</td> </tr>\n".
1377        "</form>\n";
1378 }
1379
1380 =head2 ui_buttons_hr([title])
1381
1382 Returns HTML for a separator row, for use inside a ui_buttons_start block.
1383
1384 =cut
1385 sub ui_buttons_hr
1386 {
1387 my ($title) = @_;
1388 return &theme_ui_buttons_hr(@_) if (defined(&theme_ui_buttons_hr));
1389 if ($title) {
1390         return "<tr class='ui_buttons_hr'> <td colspan=2><table cellpadding=0 cellspacing=0 width=100%><tr> <td width=50%><hr></td> <td nowrap>$title</td> <td width=50%><hr></td> </tr></table></td> </tr>\n";
1391         }
1392 else {
1393         return "<tr class='ui_buttons_hr'> <td colspan=2><hr></td> </tr>\n";
1394         }
1395 }
1396
1397 ####################### header and footer functions
1398
1399 =head2 ui_post_header([subtext])
1400
1401 Returns HTML to appear directly after a standard header() call. This is never
1402 called directly - instead, ui_print_header calls it. But it can be overridden
1403 by themes.
1404
1405 =cut
1406 sub ui_post_header
1407 {
1408 return &theme_ui_post_header(@_) if (defined(&theme_ui_post_header));
1409 my ($text) = @_;
1410 my $rv;
1411 $rv .= "<center class='ui_post_header'><font size=+1>$text</font></center>\n" if (defined($text));
1412 if (!$tconfig{'nohr'} && !$tconfig{'notophr'}) {
1413         $rv .= "<hr id='post_header_hr'>\n";
1414         }
1415 return $rv;
1416 }
1417
1418 =head2 ui_pre_footer
1419
1420 Returns HTML to appear directly before a standard footer() call. This is never
1421 called directly - instead, ui_print_footer calls it. But it can be overridden
1422 by themes.
1423
1424 =cut
1425 sub ui_pre_footer
1426 {
1427 return &theme_ui_pre_footer(@_) if (defined(&theme_ui_pre_footer));
1428 my $rv;
1429 if (!$tconfig{'nohr'} && !$tconfig{'nobottomhr'}) {
1430         $rv .= "<hr id='pre_footer_hr'>\n";
1431         }
1432 return $rv;
1433 }
1434
1435 =head2 ui_print_header(subtext, image, [help], [config], [nomodule], [nowebmin], [rightside], [head-stuff], [body-stuff], [below])
1436
1437 Print HTML for a header with the post-header line. The args are the same
1438 as those passed to header(), defined in web-lib-funcs.pl, with the addition
1439 of the subtext parameter :
1440
1441 =item subtext - Text to display below the title
1442
1443 =item title - The text to show at the top of the page
1444
1445 =item image - An image to show instead of the title text. This is typically left blank.
1446
1447 =item help - If set, this is the name of a help page that will be linked to in the title.
1448
1449 =item config - If set to 1, the title will contain a link to the module's config page.
1450
1451 =item nomodule - If set to 1, there will be no link in the title section to the module's index.
1452
1453 =item nowebmin - If set to 1, there will be no link in the title section to the Webmin index.
1454
1455 =item rightside - HTML to be shown on the right-hand side of the title. Can contain multiple lines, separated by <br>. Typically this is used for links to stop, start or restart servers.
1456
1457 =item head-stuff - HTML to be included in the <head> section of the page.
1458
1459 =item body-stuff - HTML attributes to be include in the <body> tag.
1460
1461 =item below - HTML to be displayed below the title. Typically this is used for application or server version information.
1462
1463
1464
1465 =cut
1466 sub ui_print_header
1467 {
1468 &load_theme_library();
1469 return &theme_ui_print_header(@_) if (defined(&theme_ui_print_header));
1470 my ($text, @args) = @_;
1471 &header(@args);
1472 print &ui_post_header($text);
1473 }
1474
1475 =head2 ui_print_unbuffered_header(subtext, args...)
1476
1477 Like ui_print_header, but ensures that output for this page is not buffered
1478 or contained in a table. This should be called by scripts that are producing
1479 output while performing some long-running process.
1480
1481 =cut
1482 sub ui_print_unbuffered_header
1483 {
1484 &load_theme_library();
1485 return &theme_ui_print_unbuffered_header(@_) if (defined(&theme_ui_print_unbuffered_header));
1486 $| = 1;
1487 $theme_no_table = 1;
1488 &ui_print_header(@_);
1489 }
1490
1491 =head2 ui_print_footer(args...)
1492
1493 Print HTML for a footer with the pre-footer line. Args are the same as those
1494 passed to footer().
1495
1496 =cut
1497 sub ui_print_footer
1498 {
1499 return &theme_ui_print_footer(@_) if (defined(&theme_ui_print_footer));
1500 my @args = @_;
1501 print &ui_pre_footer();
1502 &footer(@args);
1503 }
1504
1505 =head2 ui_config_link(text, &subs)
1506
1507 Returns HTML for a module config link. The first non-null sub will be
1508 replaced with the appropriate URL for the module's config page.
1509
1510 =cut
1511 sub ui_config_link
1512 {
1513 return &theme_ui_config_link(@_) if (defined(&theme_ui_config_link));
1514 my ($text, $subs) = @_;
1515 my @subs = map { $_ || "../config.cgi?$module_name" }
1516                   ($subs ? @$subs : ( undef ));
1517 return "<p>".&text($text, @subs)."<p>\n";
1518 }
1519
1520 =head2 ui_print_endpage(text)
1521
1522 Prints HTML for an error message followed by a page footer with a link to
1523 /, then exits. Good for main page error messages.
1524
1525 =cut
1526 sub ui_print_endpage
1527 {
1528 return &theme_ui_print_endpage(@_) if (defined(&theme_ui_print_endpage));
1529 my ($text) = @_;
1530 print $text,"<p class='ui_footer'>\n";
1531 print "</p>\n";
1532 &ui_print_footer("/", $text{'index'});
1533 exit;
1534 }
1535
1536 =head2 ui_subheading(text, ...)
1537
1538 Returns HTML for a section heading whose message is the given text strings.
1539
1540 =cut
1541 sub ui_subheading
1542 {
1543 return &theme_ui_subheading(@_) if (defined(&theme_ui_subheading));
1544 return "<h3 class='ui_subheading'>".join("", @_)."</h3>\n";
1545 }
1546
1547 =head2 ui_links_row(&links)
1548
1549 Returns HTML for a row of links, like select all / invert selection / add..
1550 Each element of the links array ref should be an HTML fragment like :
1551
1552   <a href='user_form.cgi'>Create new user</a>
1553
1554 =cut
1555 sub ui_links_row
1556 {
1557 return &theme_ui_links_row(@_) if (defined(&theme_ui_links_row));
1558 my ($links) = @_;
1559 return @$links ? join("\n|\n", @$links)."<br>\n"
1560                : "";
1561 }
1562
1563 ########################### collapsible section / tab functions
1564
1565 =head2 ui_hidden_javascript
1566
1567 Returns <script> and <style> sections for hiding functions and CSS. For
1568 internal use only.
1569
1570 =cut
1571 sub ui_hidden_javascript
1572 {
1573 return &theme_ui_hidden_javascript(@_)
1574         if (defined(&theme_ui_hidden_javascript));
1575 my $rv;
1576 my $imgdir = "$gconfig{'webprefix'}/images";
1577 my ($jscb, $jstb) = ($cb, $tb);
1578 $jscb =~ s/'/\\'/g;
1579 $jstb =~ s/'/\\'/g;
1580
1581 return <<EOF;
1582 <style>
1583 .opener_shown {display:inline}
1584 .opener_hidden {display:none}
1585 </style>
1586 <script>
1587 // Open or close a hidden section
1588 function hidden_opener(divid, openerid)
1589 {
1590 var divobj = document.getElementById(divid);
1591 var openerobj = document.getElementById(openerid);
1592 if (divobj.className == 'opener_shown') {
1593   divobj.className = 'opener_hidden';
1594   openerobj.innerHTML = '<img border=0 src=$imgdir/closed.gif>';
1595   }
1596 else {
1597   divobj.className = 'opener_shown';
1598   openerobj.innerHTML = '<img border=0 src=$imgdir/open.gif>';
1599   }
1600 }
1601
1602 // Show a tab
1603 function select_tab(name, tabname, form)
1604 {
1605 var tabnames = document[name+'_tabnames'];
1606 var tabtitles = document[name+'_tabtitles'];
1607 for(var i=0; i<tabnames.length; i++) {
1608   var tabobj = document.getElementById('tab_'+tabnames[i]);
1609   var divobj = document.getElementById('div_'+tabnames[i]);
1610   var title = tabtitles[i];
1611   if (tabnames[i] == tabname) {
1612     // Selected table
1613     tabobj.innerHTML = '<table cellpadding=0 cellspacing=0><tr>'+
1614                        '<td valign=top $jscb>'+
1615                        '<img src=$imgdir/lc2.gif alt=""></td>'+
1616                        '<td $jscb nowrap>'+
1617                        '&nbsp;<b>'+title+'</b>&nbsp;</td>'+
1618                        '<td valign=top $jscb>'+
1619                        '<img src=$imgdir/rc2.gif alt=""></td>'+
1620                        '</tr></table>';
1621     divobj.className = 'opener_shown';
1622     }
1623   else {
1624     // Non-selected tab
1625     tabobj.innerHTML = '<table cellpadding=0 cellspacing=0><tr>'+
1626                        '<td valign=top $jstb>'+
1627                        '<img src=$imgdir/lc1.gif alt=""></td>'+
1628                        '<td $jstb nowrap>'+
1629                        '&nbsp;<a href=\\'\\' onClick=\\'return select_tab("'+
1630                        name+'", "'+tabnames[i]+'")\\'>'+title+'</a>&nbsp;</td>'+
1631                        '<td valign=top $jstb>'+
1632                        '<img src=$imgdir/rc1.gif alt=""></td>'+
1633                        '</tr></table>';
1634     divobj.className = 'opener_hidden';
1635     }
1636   }
1637 if (document.forms[0] && document.forms[0][name]) {
1638   document.forms[0][name].value = tabname;
1639   }
1640 return false;
1641 }
1642 </script>
1643 EOF
1644 }
1645
1646 =head2 ui_hidden_start(title, name, status, thisurl)
1647
1648 Returns HTML for the start of a collapsible hidden section, such as for
1649 advanced options. When clicked on, the section header will expand to display
1650 whatever is between this function and ui_hidden_end. The parameters are :
1651
1652 =item title - Text for the start of this hidden section.
1653
1654 =item name - A unique name for this section.
1655
1656 =item status - 1 if it should be initially open, 0 if not.
1657
1658 =item thisurl - URL of the current page. This is used by themes on devices that don't support Javascript to implement the opening and closing.
1659
1660 =cut
1661 sub ui_hidden_start
1662 {
1663 return &theme_ui_hidden_start(@_) if (defined(&theme_ui_hidden_start));
1664 my ($title, $name, $status, $url) = @_;
1665 my $rv;
1666 if (!$main::ui_hidden_start_donejs++) {
1667         $rv .= &ui_hidden_javascript();
1668         }
1669 my $divid = "hiddendiv_$name";
1670 my $openerid = "hiddenopener_$name";
1671 my $defimg = $status ? "open.gif" : "closed.gif";
1672 my $defclass = $status ? 'opener_shown' : 'opener_hidden';
1673 $rv .= "<a href=\"javascript:hidden_opener('$divid', '$openerid')\" id='$openerid'><img border=0 src='$gconfig{'webprefix'}/images/$defimg' alt='*'></a>\n";
1674 $rv .= "<a href=\"javascript:hidden_opener('$divid', '$openerid')\">$title</a><br>\n";
1675 $rv .= "<div class='$defclass' id='$divid'>\n";
1676 return $rv;
1677 }
1678
1679 =head2 ui_hidden_end(name)
1680
1681 Returns HTML for the end of a hidden section, started by ui_hidden_start.
1682
1683 =cut
1684 sub ui_hidden_end
1685 {
1686 return &theme_ui_hidden_end(@_) if (defined(&theme_ui_hidden_end));
1687 my ($name) = @_;
1688 return "</div>\n";
1689 }
1690
1691 =head2 ui_hidden_table_row_start(title, name, status, thisurl)
1692
1693 Similar to ui_hidden_start, but for use within a table started with
1694 ui_table_start. I recommend against using this where possible, as it can
1695 be difficult for some themes to implement.
1696
1697 =cut
1698 sub ui_hidden_table_row_start
1699 {
1700 return &theme_ui_hidden_table_row_start(@_)
1701         if (defined(&theme_ui_hidden_table_row_start));
1702 my ($title, $name, $status, $url) = @_;
1703 my ($rv, $rrv);
1704 if (!$main::ui_hidden_start_donejs++) {
1705         $rv .= &ui_hidden_javascript();
1706         }
1707 my $divid = "hiddendiv_$name";
1708 my $openerid = "hiddenopener_$name";
1709 my $defimg = $status ? "open.gif" : "closed.gif";
1710 my $defclass = $status ? 'opener_shown' : 'opener_hidden';
1711 $rrv .= "<a href=\"javascript:hidden_opener('$divid', '$openerid')\" id='$openerid'><img border=0 src='$gconfig{'webprefix'}/images/$defimg'></a>\n";
1712 $rrv .= "<a href=\"javascript:hidden_opener('$divid', '$openerid')\">$title</a><br>\n";
1713 $rv .= &ui_table_row(undef, $rrv, $main::ui_table_cols);
1714 $rv .= "</table>\n";
1715 $rv .= "<div class='$defclass' id='$divid'>\n";
1716 $rv .= "<table width=100%>\n";
1717 return $rv;
1718 }
1719
1720 =head2 ui_hidden_table_row_end(name)
1721
1722 Returns HTML to end a block started by ui_hidden_table_start.
1723
1724 =cut
1725 sub ui_hidden_table_row_end
1726 {
1727 return &theme_ui_hidden_table_row_end(@_)
1728         if (defined(&theme_ui_hidden_table_row_end));
1729 my ($name) = @_;
1730 return "</table></div><table width=100%>\n";
1731 }
1732
1733 =head2 ui_hidden_table_start(heading, [tabletags], [cols], name, status, [&default-tds], [rightheading])
1734
1735 Returns HTML for the start of a form block into which labelled inputs can
1736 be placed, which is collapsible by clicking on the header. Basically the same
1737 as ui_table_start, and must contain HTML generated by ui_table_row.
1738
1739 The parameters are :
1740
1741 =item heading - Text to show at the top of the form.
1742
1743 =item tabletags - HTML attributes to put in the outer <table>, typically something like width=100%.
1744
1745 =item cols - Desired number of columns for labels and fields. Defaults to 4, but can be 2 for forms with lots of wide inputs.
1746
1747 =item name - A unique name for this table.
1748
1749 =item status - Set to 1 if initially open, 0 if initially closed.
1750
1751 =item default-tds - An optional array reference of HTML attributes for the <td> tags in each row of the table.
1752
1753 =item right-heading - HTML to appear in the heading, aligned to the right.
1754
1755 =cut
1756 sub ui_hidden_table_start
1757 {
1758 return &theme_ui_hidden_table_start(@_)
1759         if (defined(&theme_ui_hidden_table_start));
1760 my ($heading, $tabletags, $cols, $name, $status, $tds, $rightheading) = @_;
1761 my $rv;
1762 if (!$main::ui_hidden_start_donejs++) {
1763         $rv .= &ui_hidden_javascript();
1764         }
1765 my $divid = "hiddendiv_$name";
1766 my $openerid = "hiddenopener_$name";
1767 my $defimg = $status ? "open.gif" : "closed.gif";
1768 my $defclass = $status ? 'opener_shown' : 'opener_hidden';
1769 my $text = defined($tconfig{'cs_text'}) ? $tconfig{'cs_text'} :
1770               defined($gconfig{'cs_text'}) ? $gconfig{'cs_text'} : "000000";
1771 $rv .= "<table class='ui_table' border $tabletags>\n";
1772 my $colspan = 1;
1773 if (defined($heading) || defined($rightheading)) {
1774         $rv .= "<tr $tb> <td>";
1775         if (defined($heading)) {
1776                 $rv .= "<a href=\"javascript:hidden_opener('$divid', '$openerid')\" id='$openerid'><img border=0 src='$gconfig{'webprefix'}/images/$defimg'></a> <a href=\"javascript:hidden_opener('$divid', '$openerid')\"><b><font color=#$text>$heading</font></b></a></td>";
1777                 }
1778         if (defined($rightheading)) {
1779                 $rv .= "<td align=right>$rightheading</td>";
1780                 $colspan++;
1781                 }
1782         $rv .= "</td> </tr>\n";
1783         }
1784 $rv .= "<tr $cb> <td colspan=$colspan><div class='$defclass' id='$divid'><table width=100%>\n";
1785 $main::ui_table_cols = $cols || 4;
1786 $main::ui_table_pos = 0;
1787 $main::ui_table_default_tds = $tds;
1788 return $rv;
1789 }
1790
1791 =head2 ui_hidden_table_end(name)
1792
1793 Returns HTML for the end of a form block with hiding, as started by
1794 ui_hidden_table_start.
1795
1796 =cut
1797 sub ui_hidden_table_end
1798 {
1799 my ($name) = @_;
1800 return &theme_ui_hidden_table_end(@_) if (defined(&theme_ui_hidden_table_end));
1801 return "</table></div></td></tr></table>\n";
1802 }
1803
1804 =head2 ui_tabs_start(&tabs, name, selected, show-border)
1805
1806 Returns a row of tabs from which one can be selected, displaying HTML
1807 associated with that tab. The parameters are :
1808
1809 =item tabs - An array reference of array refs, each of which contains the value and user-visible text for a tab.
1810
1811 =item name - Name of the HTML field into which the selected tab will be placed.
1812
1813 =item selected - Value for the tab selected by default.
1814
1815 =item show-border - Set to 1 if there should be a border around the contents of the tabs.
1816
1817 Example code :
1818
1819   @tabs = ( [ 'list', 'List services' ],
1820             [ 'install', 'Install new service' ] );
1821   print ui_tabs_start(\@tabs, 'mode', 'list');
1822
1823   print ui_tabs_start_tab('mode', 'list');
1824   generate_service_list();
1825   print ui_tabs_end_tab('mode', 'list');
1826
1827   print ui_tabs_start_tab('mode', 'install');
1828   generate_install_form();
1829   print ui_tabs_end_tab('mode', 'install);
1830
1831   print ui_tabs_end();
1832
1833 =cut
1834 sub ui_tabs_start
1835 {
1836 return &theme_ui_tabs_start(@_) if (defined(&theme_ui_tabs_start));
1837 my ($tabs, $name, $sel, $border) = @_;
1838 my $rv;
1839 if (!$main::ui_hidden_start_donejs++) {
1840         $rv .= &ui_hidden_javascript();
1841         }
1842
1843 # Build list of tab titles and names
1844 my $tabnames = "[".join(",", map { "\"".&html_escape($_->[0])."\"" } @$tabs)."]";
1845 my $tabtitles = "[".join(",", map { "\"".&html_escape($_->[1])."\"" } @$tabs)."]";
1846 $rv .= "<script>\n";
1847 $rv .= "document.${name}_tabnames = $tabnames;\n";
1848 $rv .= "document.${name}_tabtitles = $tabtitles;\n";
1849 $rv .= "</script>\n";
1850
1851 # Output the tabs
1852 my $imgdir = "$gconfig{'webprefix'}/images";
1853 $rv .= &ui_hidden($name, $sel)."\n";
1854 $rv .= "<table border=0 cellpadding=0 cellspacing=0 class='ui_tabs'>\n";
1855 $rv .= "<tr><td bgcolor=#ffffff colspan=".(scalar(@$tabs)*2+1).">";
1856 if ($ENV{'HTTP_USER_AGENT'} !~ /msie/i) {
1857         # For some reason, the 1-pixel space above the tabs appears huge on IE!
1858         $rv .= "<img src=$imgdir/1x1.gif>";
1859         }
1860 $rv .= "</td></tr>\n";
1861 $rv .= "<tr>\n";
1862 $rv .= "<td bgcolor=#ffffff width=1><img src=$imgdir/1x1.gif></td>\n";
1863 foreach my $t (@$tabs) {
1864         if ($t ne $$tabs[0]) {
1865                 # Spacer
1866                 $rv .= "<td width=2 bgcolor=#ffffff class='ui_tab_spacer'>".
1867                        "<img src=$imgdir/1x1.gif></td>\n";
1868                 }
1869         my $tabid = "tab_".$t->[0];
1870         $rv .= "<td id=${tabid} class='ui_tab'>";
1871         $rv .= "<table cellpadding=0 cellspacing=0 border=0><tr>";
1872         if ($t->[0] eq $sel) {
1873                 # Selected tab
1874                 $rv .= "<td valign=top $cb class='selectedTabLeft'>".
1875                        "<img src=$imgdir/lc2.gif alt=\"\"></td>";
1876                 $rv .= "<td $cb nowrap class='selectedTabMiddle'>".
1877                        "&nbsp;<b>$t->[1]</b>&nbsp;</td>";
1878                 $rv .= "<td valign=top $cb class='selectedTabRight'>".
1879                        "<img src=$imgdir/rc2.gif alt=\"\"></td>";
1880                 }
1881         else {
1882                 # Other tab (which has a link)
1883                 $rv .= "<td valign=top $tb>".
1884                        "<img src=$imgdir/lc1.gif alt=\"\"></td>";
1885                 $rv .= "<td $tb nowrap>".
1886                        "&nbsp;<a href='$t->[2]' ".
1887                        "onClick='return select_tab(\"$name\", \"$t->[0]\")'>".
1888                        "$t->[1]</a>&nbsp;</td>";
1889                 $rv .= "<td valign=top $tb>".
1890                        "<img src=$imgdir/rc1.gif ".
1891                        "alt=\"\"></td>";
1892                 $rv .= "</td>\n";
1893                 }
1894         $rv .= "</tr></table>";
1895         $rv .= "</td>\n";
1896         }
1897 $rv .= "<td bgcolor=#ffffff width=1><img src=$imgdir/1x1.gif></td>\n";
1898 $rv .= "</table>\n";
1899
1900 if ($border) {
1901         # All tabs are within a grey box
1902         $rv .= "<table width=100% cellpadding=0 cellspacing=0 border=0 ".
1903                "class='ui_tabs_box'>\n";
1904         $rv .= "<tr> <td bgcolor=#ffffff rowspan=3 width=1><img src=$imgdir/1x1.gif></td>\n";
1905         $rv .= "<td $cb colspan=3 height=2><img src=$imgdir/1x1.gif></td> </tr>\n";
1906         $rv .= "<tr> <td $cb width=2><img src=$imgdir/1x1.gif></td>\n";
1907         $rv .= "<td valign=top>";
1908         }
1909 $main::ui_tabs_selected = $sel;
1910 return $rv;
1911 }
1912
1913 =head2 ui_tabs_end(show-border)
1914
1915 Returns HTML to end a block started by ui_tabs_start. The show-border parameter
1916 must match the parameter with the same name in the start function.
1917
1918 =cut
1919 sub ui_tabs_end
1920 {
1921 return &theme_ui_tabs_end(@_) if (defined(&theme_ui_tabs_end));
1922 my ($border) = @_;
1923 my $rv;
1924 my $imgdir = "$gconfig{'webprefix'}/images";
1925 if ($border) {
1926         $rv .= "</td>\n";
1927         $rv .= "<td $cb width=2><img src=$imgdir/1x1.gif></td>\n";
1928         $rv .= "</tr>\n";
1929         $rv .= "<tr> <td $cb colspan=3 height=2><img src=$imgdir/1x1.gif></td> </tr>\n";
1930         $rv .= "</table>\n";
1931         }
1932 return $rv;
1933 }
1934
1935 =head2 ui_tabs_start_tab(name, tab)
1936
1937 Must be called before outputting the HTML for the named tab, and returns HTML
1938 for the required <div> block.
1939
1940 =cut
1941 sub ui_tabs_start_tab
1942 {
1943 return &theme_ui_tabs_start_tab(@_) if (defined(&theme_ui_tabs_start_tab));
1944 my ($name, $tab) = @_;
1945 my $defclass = $tab eq $main::ui_tabs_selected ?
1946                         'opener_shown' : 'opener_hidden';
1947 my $rv = "<div id='div_$tab' class='$defclass ui_tabs_start'>\n";
1948 return $rv;
1949 }
1950
1951 =head2 ui_tabs_start_tabletab(name, tab)
1952
1953 Behaves like ui_tabs_start_tab, but for use within a ui_table_start block.
1954 I recommend against using this where possible, as it is difficult for themes
1955 to implement.
1956
1957 =cut
1958 sub ui_tabs_start_tabletab
1959 {
1960 return &theme_ui_tabs_start_tabletab(@_)
1961         if (defined(&theme_ui_tabs_start_tabletab));
1962 my $div = &ui_tabs_start_tab(@_);
1963 return "</table>\n".$div."<table width=100%>\n";
1964 }
1965
1966 =head2 ui_tabs_end_tab
1967
1968 Returns HTML for the end of a block started by ui_tabs_start_tab.
1969
1970 =cut
1971 sub ui_tabs_end_tab
1972 {
1973 return &theme_ui_tabs_end_tab(@_) if (defined(&theme_ui_tabs_end_tab));
1974 return "</div>\n";
1975 }
1976
1977 =head2 ui_tabs_end_tabletab
1978
1979 Returns HTML for the end of a block started by ui_tabs_start_tabletab.
1980
1981 =cut
1982 sub ui_tabs_end_tabletab
1983 {
1984 return &theme_ui_tabs_end_tabletab(@_)
1985         if (defined(&theme_ui_tabs_end_tabletab));
1986 return "</table></div><table width=100%>\n";
1987 }
1988
1989 =head2 ui_max_text_width(width, [text-area?])
1990
1991 Returns a new width for a text field, based on theme settings. For internal
1992 use only.
1993
1994 =cut
1995 sub ui_max_text_width
1996 {
1997 my ($w, $ta) = @_;
1998 my $max = $ta ? $tconfig{'maxareawidth'} : $tconfig{'maxboxwidth'};
1999 return $max && $w > $max ? $max : $w;
2000 }
2001
2002 ####################### radio hidden functions
2003
2004 =head2 ui_radio_selector(&opts, name, selected)
2005
2006 Returns HTML for a set of radio buttons, each of which shows a different
2007 block of HTML when selected. The parameters are :
2008
2009 =item opts - An array ref to arrays containing [ value, label, html ]
2010
2011 =item name - HTML name for the radio buttons
2012
2013 =item selected - Value for the initially selected button.
2014
2015 =cut
2016 sub ui_radio_selector
2017 {
2018 return &theme_ui_radio_selector(@_) if (defined(&theme_ui_radio_selector));
2019 my ($opts, $name, $sel) = @_;
2020 my $rv;
2021 if (!$main::ui_radio_selector_donejs++) {
2022         $rv .= &ui_radio_selector_javascript();
2023         }
2024 my $optnames =
2025         "[".join(",", map { "\"".&html_escape($_->[0])."\"" } @$opts)."]";
2026 foreach my $o (@$opts) {
2027         $rv .= &ui_oneradio($name, $o->[0], $o->[1], $sel eq $o->[0],
2028             "onClick='selector_show(\"$name\", \"$o->[0]\", $optnames)'");
2029         }
2030 $rv .= "<br>\n";
2031 foreach my $o (@$opts) {
2032         my $cls = $o->[0] eq $sel ? "selector_shown" : "selector_hidden";
2033         $rv .= "<div id=sel_${name}_$o->[0] class=$cls>".$o->[2]."</div>\n";
2034         }
2035 return $rv;
2036 }
2037
2038 sub ui_radio_selector_javascript
2039 {
2040 return <<EOF;
2041 <style>
2042 .selector_shown {display:inline}
2043 .selector_hidden {display:none}
2044 </style>
2045 <script>
2046 function selector_show(name, value, values)
2047 {
2048 for(var i=0; i<values.length; i++) {
2049         var divobj = document.getElementById('sel_'+name+'_'+values[i]);
2050         divobj.className = value == values[i] ? 'selector_shown'
2051                                               : 'selector_hidden';
2052         }
2053 }
2054 </script>
2055 EOF
2056 }
2057
2058 ####################### grid layout functions
2059
2060 =head2 ui_grid_table(&elements, columns, [width-percent], [&tds], [tabletags], [title])
2061
2062 Given a list of HTML elements, formats them into a table with the given
2063 number of columns. However, themes are free to override this to use fewer
2064 columns where space is limited. Parameters are :
2065
2066 =item elements - An array reference of table elements, each of which can be any HTML you like.
2067
2068 =item columns - Desired number of columns in the grid.
2069
2070 =item width-percent - Optional desired width as a percentage.
2071
2072 =item tds - Array ref of HTML attributes for <td> tags in the tables.
2073
2074 =item tabletags - HTML attributes for the <table> tag.
2075
2076 =item title - Optional title to add to the top of the grid.
2077
2078 =cut
2079 sub ui_grid_table
2080 {
2081 return &theme_ui_grid_table(@_) if (defined(&theme_ui_grid_table));
2082 my ($elements, $cols, $width, $tds, $tabletags, $title) = @_;
2083 return "" if (!@$elements);
2084 my $rv = "<table class='ui_grid_table'".
2085             ($width ? " width=$width%" : "").
2086             ($tabletags ? " ".$tabletags : "").
2087             ">\n";
2088 my $i;
2089 for($i=0; $i<@$elements; $i++) {
2090         $rv .= "<tr class='ui_grid_row'>" if ($i%$cols == 0);
2091         $rv .= "<td ".$tds->[$i%$cols]." valign=top class='ui_grid_cell'>".
2092                $elements->[$i]."</td>\n";
2093         $rv .= "</tr>" if ($i%$cols == $cols-1);
2094         }
2095 if ($i%$cols) {
2096         while($i%$cols) {
2097                 $rv .= "<td ".$tds->[$i%$cols]." class='ui_grid_cell'>".
2098                        "<br></td>\n";
2099                 $i++;
2100                 }
2101         $rv .= "</tr>\n";
2102         }
2103 $rv .= "</table>\n";
2104 if (defined($title)) {
2105         $rv = "<table class=ui_table border ".
2106               ($width ? " width=$width%" : "").">\n".
2107               ($title ? "<tr $tb> <td><b>$title</b></td> </tr>\n" : "").
2108               "<tr $cb> <td>$rv</td> </tr>\n".
2109               "</table>";
2110         }
2111 return $rv;
2112 }
2113
2114 =head2 ui_radio_table(name, selected, &rows, [no-bold])
2115
2116 Returns HTML for a table of radio buttons, each of which has a label and
2117 some associated inputs to the right. The parameters are :
2118
2119 =item name - Unique name for this table, which is also the radio buttons' name.
2120
2121 =item selected - Value for the initially selected radio button.
2122
2123 =item rows - Array ref of array refs, one per button. The elements of each are the value for this option, a label, and option additional HTML to appear next to it.
2124
2125 =item no-bold - When set to 1, labels in the table will not be bolded
2126
2127 =cut
2128 sub ui_radio_table
2129 {
2130 return &theme_ui_radio_table(@_) if (defined(&theme_ui_radio_table));
2131 my ($name, $sel, $rows, $nobold) = @_;
2132 return "" if (!@$rows);
2133 my $rv = "<table class='ui_radio_table'>\n";
2134 foreach my $r (@$rows) {
2135         $rv .= "<tr>\n";
2136         $rv .= "<td valign=top".(defined($r->[2]) ? "" : " colspan=2").">".
2137                ($nobold ? "" : "<b>").
2138                &ui_oneradio($name, $r->[0], $r->[1], $r->[0] eq $sel, $r->[3]).
2139                ($nobold ? "" : "</b>").
2140                "</td>\n";
2141         if (defined($r->[2])) {
2142                 $rv .= "<td valign=top>".$r->[2]."</td>\n";
2143                 }
2144         $rv .= "</tr>\n";
2145         }
2146 $rv .= "</table>\n";
2147 return $rv;
2148 }
2149
2150 =head2 ui_up_down_arrows(uplink, downlink, up-show, down-show)
2151
2152 Returns HTML for moving some objects in a table up or down. The parameters are :
2153
2154 =item uplink - URL for the up-arrow link.
2155
2156 =item downlink - URL for the down-arrow link.
2157
2158 =item up-show - Set to 1 if the up-arrow should be shown, 0 if not.
2159
2160 =item down-show - Set to 1 if the down-arrow should be shown, 0 if not.
2161
2162 =cut
2163 sub ui_up_down_arrows
2164 {
2165 return &theme_ui_up_down_arrows(@_) if (defined(&theme_ui_up_down_arrows));
2166 my ($uplink, $downlink, $upshow, $downshow) = @_;
2167 my $mover;
2168 my $imgdir = "$gconfig{'webprefix'}/images";
2169 if ($downshow) {
2170         $mover .= "<a href=\"$downlink\">".
2171                   "<img src=$imgdir/movedown.gif border=0></a>";
2172         }
2173 else {
2174         $mover .= "<img src=$imgdir/movegap.gif>";
2175         }
2176 if ($upshow) {
2177         $mover .= "<a href=\"$uplink\">".
2178                   "<img src=$imgdir/moveup.gif border=0></a>";
2179         }
2180 else {
2181         $mover .= "<img src=$imgdir/movegap.gif>";
2182         }
2183 return $mover;
2184 }
2185
2186 =head2 ui_hr
2187
2188 Returns a horizontal row tag, typically just an <hr>
2189
2190 =cut
2191 sub ui_hr
2192 {
2193 return &theme_ui_hr() if (defined(&theme_ui_hr));
2194 return "<hr>\n";
2195 }
2196
2197 =head2 ui_nav_link(direction, url, disabled)
2198
2199 Returns an arrow icon linking to the provided url.
2200
2201 =cut
2202 sub ui_nav_link
2203 {
2204 return &theme_ui_nav_link(@_) if (defined(&theme_ui_nav_link));
2205 my ($direction, $url, $disabled) = @_;
2206 my $alt = $direction eq "left" ? '<-' : '->';
2207 if ($disabled) {
2208         return "<img alt=\"$alt\" align=\"middle\""
2209              . "src=\"$gconfig{'webprefix'}/images/$direction-grey.gif\">\n";
2210         }
2211 else {
2212         return "<a href=\"$url\"><img alt=\"$alt\" align=\"middle\""
2213              . "src=\"$gconfig{'webprefix'}/images/$direction.gif\"></a>\n";
2214         }
2215 }
2216
2217 =head2 ui_confirmation_form(cgi, message, &hiddens, [&buttons], [otherinputs], [extra-warning])
2218
2219 Returns HTML for a form asking for confirmation before performing some
2220 action, such as deleting a user. The parameters are :
2221
2222 =item cgi - Script to which the confirmation form submits, like delete.cgi.
2223
2224 =item message - Warning message for the user to see.
2225
2226 =item hiddens - Array ref of two-element array refs, containing hidden form field names and values.
2227
2228 =item buttons - Array ref of two-element array refs, containing form button names and labels.
2229
2230 =item otherinputs - HTML for extra inputs to include in ther form.
2231
2232 =item extra-warning - An additional separate warning message to show.
2233
2234 =cut
2235 sub ui_confirmation_form
2236 {
2237 my ($cgi, $message, $hiddens, $buttons, $others, $warning) = @_;
2238 my $rv;
2239 $rv .= "<center class=ui_confirmation>\n";
2240 $rv .= &ui_form_start($cgi, "post");
2241 foreach my $h (@$hiddens) {
2242         $rv .= &ui_hidden(@$h);
2243         }
2244 $rv .= "<b>$message</b><p>\n";
2245 if ($warning) {
2246         $rv .= "<b><font color=#ff0000>$warning</font></b><p>\n";
2247         }
2248 if ($others) {
2249         $rv .= $others."<p>\n";
2250         }
2251 $rv .= &ui_form_end($buttons);
2252 $rv .= "</center>\n";
2253 return $rv;
2254 }
2255
2256 ####################### javascript functions
2257
2258 =head2 js_disable_inputs(&disable-inputs, &enable-inputs, [tag])
2259
2260 Returns Javascript to disable some form elements and enable others. Mainly
2261 for internal use.
2262
2263 =cut
2264 sub js_disable_inputs
2265 {
2266 my $rv;
2267 my $f;
2268 foreach $f (@{$_[0]}) {
2269         $rv .= "e = form.elements[\"$f\"]; e.disabled = true; ";
2270         $rv .= "for(i=0; i<e.length; i++) { e[i].disabled = true; } ";
2271         }
2272 foreach $f (@{$_[1]}) {
2273         $rv .= "e = form.elements[\"$f\"]; e.disabled = false; ";
2274         $rv .= "for(i=0; i<e.length; i++) { e[i].disabled = false; } ";
2275         }
2276 foreach $f (@{$_[1]}) {
2277         if ($f =~ /^(.*)_def$/ && &indexof($1, @{$_[1]}) >= 0) {
2278                 # When enabling both a _def field and its associated text field,
2279                 # disable the text if the _def is set to 1
2280                 my $tf = $1;
2281                 $rv .= "e = form.elements[\"$f\"]; for(i=0; i<e.length; i++) { if (e[i].checked && e[i].value == \"1\") { form.elements[\"$tf\"].disabled = true } } ";
2282                 }
2283         }
2284 return $_[2] ? "$_[2]='$rv'" : $rv;
2285 }
2286
2287 =head2 ui_page_flipper(message, [inputs, cgi], left-link, right-link, [far-left-link], [far-right-link], [below])
2288
2289 Returns HTML for moving left and right in some large list, such as an inbox
2290 or database table. If only 5 parameters are given, no far links are included.
2291 If any link is undef, that array will be greyed out. The parameters are :
2292
2293 =item message - Text or display between arrows.
2294
2295 =item inputs - Additional HTML inputs to show after message.
2296
2297 =item cgi - Optional CGI for form wrapping arrows to submit to.
2298
2299 =item left-link - Link for left-facing arrow.
2300
2301 =item right-link - Link for right-facing arrow.
2302
2303 =item far-left-link - Link for far left-facing arrow, optional.
2304
2305 =item far-right-link - Link for far right-facing arrow, optional.
2306
2307 =item below - HTML to display below the arrows.
2308
2309 =cut
2310 sub ui_page_flipper
2311 {
2312 return &theme_ui_page_flipper(@_) if (defined(&theme_ui_page_flipper));
2313 my ($msg, $inputs, $cgi, $left, $right, $farleft, $farright, $below) = @_;
2314 my $rv = "<center>";
2315 $rv .= &ui_form_start($cgi) if ($cgi);
2316
2317 # Far left link, if needed
2318 if (@_ > 5) {
2319         if ($farleft) {
2320                 $rv .= "<a href='$farleft'>".
2321                        "<img src=$gconfig{'webprefix'}/images/first.gif ".
2322                        "border=0 align=middle></a>\n";
2323                 }
2324         else {
2325                 $rv .= "<img src=$gconfig{'webprefix'}/images/first-grey.gif ".
2326                        "border=0 align=middle></a>\n";
2327                 }
2328         }
2329
2330 # Left link
2331 if ($left) {
2332         $rv .= "<a href='$left'>".
2333                "<img src=$gconfig{'webprefix'}/images/left.gif ".
2334                "border=0 align=middle></a>\n";
2335         }
2336 else {
2337         $rv .= "<img src=$gconfig{'webprefix'}/images/left-grey.gif ".
2338                "border=0 align=middle></a>\n";
2339         }
2340
2341 # Message and inputs
2342 $rv .= $msg;
2343 $rv .= " ".$inputs if ($inputs);
2344
2345 # Right link
2346 if ($right) {
2347         $rv .= "<a href='$right'>".
2348                "<img src=$gconfig{'webprefix'}/images/right.gif ".
2349                "border=0 align=middle></a>\n";
2350         }
2351 else {
2352         $rv .= "<img src=$gconfig{'webprefix'}/images/right-grey.gif ".
2353                "border=0 align=middle></a>\n";
2354         }
2355
2356 # Far right link, if needed
2357 if (@_ > 5) {
2358         if ($farright) {
2359                 $rv .= "<a href='$farright'>".
2360                        "<img src=$gconfig{'webprefix'}/images/last.gif ".
2361                        "border=0 align=middle></a>\n";
2362                 }
2363         else {
2364                 $rv .= "<img src=$gconfig{'webprefix'}/images/last-grey.gif ".
2365                        "border=0 align=middle></a>\n";
2366                 }
2367         }
2368
2369 $rv .= "<br>".$below if ($below);
2370 $rv .= &ui_form_end() if ($cgi);
2371 $rv .= "</center>\n";
2372 return $rv;
2373 }
2374
2375 =head2 js_checkbox_disable(name, &checked-disable, &checked-enable, [tag])
2376
2377 For internal use only.
2378
2379 =cut
2380 sub js_checkbox_disable
2381 {
2382 my $rv;
2383 my $f;
2384 foreach $f (@{$_[1]}) {
2385         $rv .= "form.elements[\"$f\"].disabled = $_[0].checked; ";
2386         }
2387 foreach $f (@{$_[2]}) {
2388         $rv .= "form.elements[\"$f\"].disabled = !$_[0].checked; ";
2389         }
2390 return $_[3] ? "$_[3]='$rv'" : $rv;
2391 }
2392
2393 =head2 js_redirect(url, [window-object])
2394
2395 Returns HTML to trigger a redirect to some URL.
2396
2397 =cut
2398 sub js_redirect
2399 {
2400 my ($url, $window) = @_;
2401 if (defined(&theme_js_redirect)) {
2402         return &theme_js_redirect(@_);
2403         }
2404 $window ||= "window";
2405 if ($url =~ /^\//) {
2406         # If the URL is like /foo , add webprefix
2407         $url = $gconfig{'webprefix'}.$url;
2408         }
2409 return "<script>${window}.location = '".&quote_escape($url)."';</script>\n";
2410 }
2411
2412 1;
2413