configure.ac.in

   1 # vi:set et ai sw=2 sts=2 ts=2: */
   2 #-
   3 # Copyright (c) 2004-2007 Benedikt Meurer <benny@xfce.org>
   4 # Copyright (c) 2009-2011 Jannis Pohlmann <jannis@xfce.org>
   5 #
   6 # This program is free software; you can redistribute it and/or
   7 # modify it under the terms of the GNU General Public License as
   8 # published by the Free Software Foundation; either version 2 of
   9 # the License, or (at your option) any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public
  17 # License along with this program; if not, write to the Free
  18 # Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  19 # Boston, MA 02110-1301, USA.
  20
  21 dnl ***************************
  22 dnl *** Version information ***
  23 dnl ***************************
  24 m4_define([thunarx_verinfo], [0:0:0])
  25 m4_define([thunarx_version_api], [2])
  26 m4_define([thunar_version_major], [1])
  27 m4_define([thunar_version_minor], [6])
  28 m4_define([thunar_version_micro], [3])
  29 m4_define([thunar_version_nano], [])
  30 m4_define([thunar_version_build], [@REVISION@])
  31 m4_define([thunar_version_tag], [])
  32 m4_define([thunar_version], [thunar_version_major().thunar_version_minor().thunar_version_micro()ifelse(thunar_version_nano(), [], [], [.thunar_version_nano()])ifelse(thunar_version_tag(), [git], [thunar_version_tag()-thunar_version_build()], [thunar_version_tag()])])
  33
  34 dnl *******************************************
  35 dnl *** Debugging support for GIT snapshots ***
  36 dnl *******************************************
  37 m4_define([thunar_debug_default], [ifelse(thunar_version_tag(), [git], [yes], [minimum])])
  38
  39 dnl ***************************
  40 dnl *** Initialize autoconf ***
  41 dnl ***************************
  42 AC_COPYRIGHT([Copyright (c) 2004-2012 The Thunar development team. All rights reserved.])
  43 AC_INIT([Thunar], [thunar_version], [http://bugzilla.xfce.org/], [Thunar])
  44 AC_PREREQ([2.50])
  45 AC_CANONICAL_TARGET()
  46 AC_REVISION([$Id$])
  47
  48 dnl ***************************
  49 dnl *** Initialize automake ***
  50 dnl ***************************
  51 AM_INIT_AUTOMAKE([1.8 dist-bzip2 tar-ustar no-dist-gzip])
  52 AC_CONFIG_HEADERS([config.h])
  53 AM_MAINTAINER_MODE()
  54 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  55
  56 dnl *******************************
  57 dnl *** Check for UNIX variants ***
  58 dnl *******************************
  59 AC_AIX()
  60 AC_ISC_POSIX()
  61 AC_MINIX()
  62
  63 if test "x$target_os" = "xlinux-gnu"; then
  64   AC_DEFINE([HAVE_LINUX], [], [Whether we are building on Linux or not])
  65 fi
  66
  67 dnl ********************************
  68 dnl *** Check for basic programs ***
  69 dnl ********************************
  70 AC_PROG_CC()
  71 AC_PROG_LD()
  72 AM_PROG_CC_C_O()
  73 AC_PROG_INSTALL()
  74 AC_PROG_INTLTOOL()
  75 AC_CHECK_PROGS([PERL], [perl5 perl])
  76 m4_ifdef([AC_PROG_SED], [AC_PROG_SED], [AC_CHECK_PROG(SED, sed, sed)])
  77
  78 dnl **************************
  79 dnl *** Initialize libtool ***
  80 dnl **************************
  81 LT_PREREQ([2.2.6])
  82 LT_INIT([disable-static])
  83
  84 dnl **************************************
  85 dnl *** Substitute version information ***
  86 dnl **************************************
  87 THUNARX_VERINFO=thunarx_verinfo()
  88 THUNARX_VERSION_API=thunarx_version_api()
  89 THUNAR_VERSION_MAJOR=thunar_version_major()
  90 THUNAR_VERSION_MINOR=thunar_version_minor()
  91 THUNAR_VERSION_MICRO=thunar_version_micro()
  92 AC_SUBST([THUNARX_VERINFO])
  93 AC_SUBST([THUNARX_VERSION_API])
  94 AC_SUBST([THUNAR_VERSION_MAJOR])
  95 AC_SUBST([THUNAR_VERSION_MINOR])
  96 AC_SUBST([THUNAR_VERSION_MICRO])
  97
  98 dnl ******************************
  99 dnl *** Set helper path prefix ***
 100 dnl ******************************
 101 AC_ARG_WITH([helper-path-prefix],
 102             [AC_HELP_STRING([--with-helper-path-prefix=PATH],
 103                             [Path prefix under which helper executables will be installed (default: $libdir)])],
 104             [HELPER_PATH_PREFIX="$withval"],
 105             [HELPER_PATH_PREFIX="$libdir"])
 106 AC_SUBST([HELPER_PATH_PREFIX])
 107
 108 dnl ***********************************************
 109 dnl *** Work-around system-specific limitations ***
 110 dnl ***********************************************
 111 AC_SYS_LARGEFILE()
 112
 113 dnl **********************************
 114 dnl *** Check for standard headers ***
 115 dnl **********************************
 116 AC_CHECK_HEADERS([ctype.h errno.h fcntl.h grp.h limits.h locale.h memory.h \
 117                   paths.h pwd.h sched.h signal.h stdarg.h stdlib.h string.h \
 118                   sys/mman.h sys/param.h sys/stat.h sys/time.h sys/types.h \
 119                   sys/uio.h sys/wait.h time.h])
 120
 121 dnl ************************************
 122 dnl *** Check for standard functions ***
 123 dnl ************************************
 124 AC_FUNC_MMAP()
 125 AC_CHECK_FUNCS([localeconv mkdtemp pread pwrite sched_yield setgroupent \
 126                 setpassent strcoll strlcpy strptime symlink atexit])
 127
 128 dnl ******************************
 129 dnl *** Check for i18n support ***
 130 dnl ******************************
 131 XDT_I18N([@LINGUAS@])
 132
 133 dnl *********************
 134 dnl *** Check for X11 ***
 135 dnl *********************
 136 XDT_CHECK_LIBX11_REQUIRE()
 137
 138 dnl ***********************************
 139 dnl *** Check for required packages ***
 140 dnl ***********************************
 141 XDT_CHECK_PACKAGE([EXO], [exo-1], [0.10.0])
 142 XDT_CHECK_PACKAGE([GLIB], [glib-2.0], [2.30.0])
 143 XDT_CHECK_PACKAGE([GIO], [gio-2.0], [2.30.0])
 144 XDT_CHECK_PACKAGE([GTHREAD], [gthread-2.0], [2.30.0])
 145 XDT_CHECK_PACKAGE([GMODULE], [gmodule-2.0], [2.30.0])
 146 XDT_CHECK_PACKAGE([GTK], [gtk+-2.0], [2.24.0])
 147 XDT_CHECK_PACKAGE([GDK_PIXBUF], [gdk-pixbuf-2.0], [2.14.0])
 148 XDT_CHECK_PACKAGE([LIBXFCE4UTIL], [libxfce4util-1.0], [4.10.0])
 149 XDT_CHECK_PACKAGE([LIBXFCE4UI], [libxfce4ui-1], [4.10.0])
 150 XDT_CHECK_PACKAGE([XFCONF], [libxfconf-0], [4.10.0])
 151
 152 dnl ********************************************
 153 dnl *** Check for session management support ***
 154 dnl ********************************************
 155 XDT_CHECK_LIBSM()
 156
 157 dnl **********************************
 158 dnl *** Optional GIO UNIX features ***
 159 dnl **********************************
 160 XDT_CHECK_OPTIONAL_PACKAGE([GIO_UNIX], [gio-unix-2.0],
 161                            [2.30.0], [gio-unix], [GIO UNIX features])
 162
 163 dnl **********************************
 164 dnl *** Optional support for D-BUS ***
 165 dnl **********************************
 166 XDT_CHECK_OPTIONAL_PACKAGE([DBUS], [dbus-glib-1],
 167                            [0.34], [dbus], [D-BUS support])
 168
 169 dnl *************************************************
 170 dnl *** Optional support for startup notification ***
 171 dnl *************************************************
 172 XDT_CHECK_OPTIONAL_PACKAGE([LIBSTARTUP_NOTIFICATION],
 173                            [libstartup-notification-1.0],
 174                            [0.4], [startup-notification],
 175                            [startup notification library])
 176
 177 dnl ***************************************************************
 178 dnl *** Optional support for GUDev (required for thunar-volman) ***
 179 dnl ***************************************************************
 180 XDT_CHECK_OPTIONAL_PACKAGE([GUDEV], [gudev-1.0], [145], [gudev],
 181                            [GUDev (required for thunar-volman)])
 182
 183 dnl **************************************
 184 dnl *** Optional support for libnotify ***
 185 dnl **************************************
 186 XDT_CHECK_OPTIONAL_PACKAGE([LIBNOTIFY], [libnotify], [0.4.0], [notifications],
 187                            [Mount notification support], [yes])
 188
 189 dnl *************************
 190 dnl *** Check for gtk-doc ***
 191 dnl *************************
 192 GTK_DOC_CHECK([1.0])
 193
 194 dnl ***********************************
 195 dnl *** Check for debugging support ***
 196 dnl ***********************************
 197 XDT_FEATURE_DEBUG([thunar_debug_default])
 198
 199 dnl *************************************
 200 dnl *** Compensate for broken gtk-doc ***
 201 dnl *************************************
 202 XDT_SUPPORTED_FLAGS([GTK_DOC_EXTRA_CFLAGS], [-Wno-sign-compare])
 203 AC_SUBST([GTK_DOC_EXTRA_CFLAGS])
 204
 205 dnl **************************************
 206 dnl *** Check for linker optimizations ***
 207 dnl **************************************
 208 XDT_FEATURE_LINKER_OPTS()
 209
 210 dnl dnl ****************************************
 211 dnl dnl *** Check for ELF visibility support ***
 212 dnl dnl ****************************************
 213 dnl XDT_FEATURE_VISIBILITY()
 214
 215 dnl *********************************
 216 dnl *** Substitute platform flags ***
 217 dnl *********************************
 218 AC_MSG_CHECKING([PLATFORM_CPPFLAGS])
 219 AC_MSG_RESULT([$PLATFORM_CPPFLAGS])
 220 AC_SUBST([PLATFORM_CPPFLAGS])
 221 AC_MSG_CHECKING([PLATFORM_CFLAGS])
 222 AC_MSG_RESULT([$PLATFORM_CFLAGS])
 223 AC_SUBST([PLATFORM_CFLAGS])
 224 AC_MSG_CHECKING([PLATFORM_LDFLAGS])
 225 AC_MSG_RESULT([$PLATFORM_LDFLAGS])
 226 AC_SUBST([PLATFORM_LDFLAGS])
 227
 228 dnl ************************************
 229 dnl *** Check for additional plugins ***
 230 dnl ************************************
 231 BM_THUNAR_PLUGIN_APR()
 232 BM_THUNAR_PLUGIN_SBR()
 233 BM_THUNAR_PLUGIN_TPA()
 234 BM_THUNAR_PLUGIN_UCA()
 235 BM_THUNAR_PLUGIN_WALLPAPER()
 236
 237 AC_OUTPUT([
 238 Makefile
 239 docs/Makefile
 240 docs/design/Makefile
 241 docs/papers/Makefile
 242 docs/reference/Makefile
 243 docs/reference/thunarx/Makefile
 244 docs/reference/thunarx/version.xml
 245 examples/Makefile
 246 examples/tex-open-terminal/Makefile
 247 icons/Makefile
 248 icons/16x16/Makefile
 249 icons/24x24/Makefile
 250 icons/48x48/Makefile
 251 icons/64x64/Makefile
 252 icons/128x128/Makefile
 253 icons/scalable/Makefile
 254 pixmaps/Makefile
 255 plugins/Makefile
 256 plugins/thunar-apr/Makefile
 257 plugins/thunar-sbr/Makefile
 258 plugins/thunar-sendto-email/Makefile
 259 plugins/thunar-tpa/Makefile
 260 plugins/thunar-uca/Makefile
 261 plugins/thunar-wallpaper/Makefile
 262 po/Makefile.in
 263 thunar/Makefile
 264 thunarx/Makefile
 265 thunarx/thunarx-2.pc
 266 thunarx/thunarx-config.h
 267 ])
 268
 269 dnl ***************************
 270 dnl *** Print configuration ***
 271 dnl ***************************
 272 echo
 273 echo "Build Configuration:"
 274 echo
 275 if test x"$DBUS_FOUND" = x"yes"; then
 276 echo "* D-BUS support:                      yes"
 277 else
 278 echo "* D-BUS support:                      no"
 279 fi
 280 if test x"$GIO_UNIX_FOUND" = x"yes"; then
 281 echo "* GIO UNIX features:                  yes"
 282 else
 283 echo "* GIO UNIX features:                  no"
 284 fi
 285 if test x"$LIBSTARTUP_NOTIFICATION_FOUND" = x"yes"; then
 286 echo "* Startup Notification:               yes"
 287 else
 288 echo "* Startup Notification:               no"
 289 fi
 290 if test x"$GUDEV_FOUND" = x"yes"; then
 291 echo "* GUDev (required for thunar-volman): yes"
 292 else
 293 echo "* GUDev (required for thunar-volman): no"
 294 fi
 295 if test x"$LIBNOTIFY_FOUND" = x"yes"; then
 296 echo "* Mount notification support:         yes"
 297 else
 298 echo "* Mount notification support:         no"
 299 fi
 300 echo "* Debug Support:                      $enable_debug"
 301 echo
 302 echo "Additional Plugins:"
 303 echo
 304 echo "* Advanced Properties:                $ac_bm_thunar_plugin_apr"
 305 echo "* Simple Builtin Renamers:            $ac_bm_thunar_plugin_sbr"
 306 echo "* Trash Panel Applet:                 $ac_bm_thunar_plugin_tpa"
 307 echo "* User Customizable Actions:          $ac_bm_thunar_plugin_uca"
 308 echo "* Wallpaper support:                  $ac_bm_thunar_plugin_wallpaper"
 309 echo