configure.ac

   1 AC_PREREQ([2.63])
   2
   3 dnl The NM version number
   4 m4_define([nm_major_version], [1])
   5 m4_define([nm_minor_version], [1])
   6 m4_define([nm_micro_version], [0])
   7 m4_define([nm_version],
   8           [nm_major_version.nm_minor_version.nm_micro_version])
   9 m4_define([nm_git_sha], [m4_esyscmd([ ( [ -d ./.git/ ] && [ "$(readlink -f ./.git/)" = "$(readlink -f "$(git rev-parse --git-dir 2>/dev/null)" 2>/dev/null)" ] && git rev-parse --verify -q HEAD 2>/dev/null ) || true ])])
  10
  11 AC_INIT([NetworkManager], [nm_version],
  12         [http://bugzilla.gnome.org/enter_bug.cgi?product=NetworkManager],
  13         [NetworkManager])
  14
  15 AC_CONFIG_HEADERS([config.h])
  16 AC_CONFIG_MACRO_DIR([m4])
  17 AC_CONFIG_AUX_DIR([build-aux])
  18 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  19
  20 AM_INIT_AUTOMAKE(1.12 tar-ustar no-dist-gzip dist-xz -Wno-portability)  dnl NB: Do not [quote] this parameter.
  21 AM_MAINTAINER_MODE([enable])
  22 AM_SILENT_RULES([yes])
  23
  24 dnl Define _SYSTEM_EXTENSIONS for various things like strcasestr()
  25 AC_USE_SYSTEM_EXTENSIONS
  26
  27 dnl
  28 dnl Require programs
  29 dnl
  30 AC_PROG_CC
  31 AM_PROG_CC_C_O
  32
  33 # C++ only required if --enable-qt=yes
  34 AC_PROG_CXX
  35
  36 dnl Initialize libtool
  37 LT_PREREQ([2.2])
  38 LT_INIT([disable-static])
  39
  40 dnl Version stuff
  41 NM_MAJOR_VERSION=nm_major_version
  42 NM_MINOR_VERSION=nm_minor_version
  43 NM_MICRO_VERSION=nm_micro_version
  44 NM_VERSION=nm_version
  45 NM_GIT_SHA=nm_git_sha
  46 AC_SUBST(NM_MAJOR_VERSION)
  47 AC_SUBST(NM_MINOR_VERSION)
  48 AC_SUBST(NM_MICRO_VERSION)
  49 AC_SUBST(NM_VERSION)
  50 AC_DEFINE_UNQUOTED(NM_GIT_SHA,"$NM_GIT_SHA",[git commit id of the original source code version])
  51
  52 dnl
  53 dnl Checks for typedefs, structures, and compiler characteristics.
  54 dnl
  55 AC_TYPE_PID_T
  56 AC_CHECK_SIZEOF(dev_t)
  57
  58 dnl
  59 dnl translation support
  60 dnl
  61 IT_PROG_INTLTOOL([0.40.0])
  62
  63 AM_GNU_GETTEXT([external])
  64 AM_GNU_GETTEXT_VERSION([0.17])
  65
  66 GETTEXT_PACKAGE=NetworkManager
  67 AC_SUBST(GETTEXT_PACKAGE)
  68 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [Gettext package])
  69
  70 dnl
  71 dnl Make sha1.c happy on big endian systems
  72 dnl
  73 AC_C_BIGENDIAN
  74
  75 # Add runstatedir if not specified manually in autoconf < 2.70
  76 AS_IF([test -z "$runstatedir"], runstatedir="$localstatedir/run")
  77 AC_SUBST(runstatedir)
  78
  79 # NetworkManager paths
  80 AC_SUBST(nmbinary, '${sbindir}'/$PACKAGE, [NetworkManager binary executable])
  81 AC_SUBST(nmconfdir, '${sysconfdir}'/$PACKAGE, [NetworkManager configuration directory])
  82 AC_SUBST(nmlibdir, '${prefix}'/lib/$PACKAGE, [NetworkManager library directory])
  83 AC_SUBST(nmdatadir, '${datadir}'/$PACKAGE, [NetworkManager shared data directory])
  84 AC_SUBST(nmstatedir, '${localstatedir}'/lib/$PACKAGE, [NetworkManager persistent state directory])
  85 AC_SUBST(nmrundir, '${runstatedir}'/$PACKAGE, [NetworkManager runtime state directory])
  86
  87 # Alternative configuration plugins
  88 AC_ARG_ENABLE(config-plugin-ibft, AS_HELP_STRING([--enable-config-plugin-ibft], [enable ibft configuration plugin]))
  89 AC_ARG_ENABLE(ifcfg-rh, AS_HELP_STRING([--enable-ifcfg-rh], [enable ifcfg-rh configuration plugin (Fedora/RHEL)]))
  90 AC_ARG_ENABLE(ifcfg-suse, AS_HELP_STRING([--enable-ifcfg-suse], [enable ifcfg-suse configuration plugin (SUSE) (deprecated)]))
  91 AC_ARG_ENABLE(ifupdown, AS_HELP_STRING([--enable-ifupdown], [enable ifupdown configuration plugin (Debian/Ubuntu)]))
  92 AC_ARG_ENABLE(ifnet, AS_HELP_STRING([--enable-ifnet], [enable ifnet configuration plugin (Gentoo)]))
  93 # Default alternative plugins by distribution
  94 AS_IF([test -z "$enable_ifcfg_rh"], AC_CHECK_FILE(/etc/redhat-release, enable_ifcfg_rh=yes))
  95 AS_IF([test -z "$enable_ifcfg_rh"], AC_CHECK_FILE(/etc/fedora-release, enable_ifcfg_rh=yes))
  96 AS_IF([test -z "$enable_ifcfg_rh"], AC_CHECK_FILE(/etc/mandriva-release, enable_ifcfg_rh=yes))
  97 AS_IF([test -z "$enable_ifcfg_suse"], AC_CHECK_FILE(/etc/SuSE-release, enable_ifcfg_suse=yes))
  98 AS_IF([test -z "$enable_ifupdown"], AC_CHECK_FILE(/etc/debian_version, enable_ifupdown=yes))
  99 AS_IF([test -z "$enable_ifnet"], AC_CHECK_FILE(/etc/gentoo-release, enable_ifnet=yes))
 100 # Otherwise plugins default to "no"
 101 AS_IF([test -z "$enable_ifcfg_rh"], enable_ifcfg_rh=no)
 102 AS_IF([test -z "$enable_ifcfg_suse"], enable_ifcfg_suse=no)
 103 AS_IF([test -z "$enable_ifupdown"], enable_ifupdown=no)
 104 AS_IF([test -z "$enable_ifnet"], enable_ifnet=no)
 105 # Enable ibft by default
 106 AS_IF([test -z "$enable_config_plugin_ibft"], enable_config_plugin_ibft="yes")
 107 # Create automake conditionals
 108 AM_CONDITIONAL(CONFIG_PLUGIN_IBFT, test "$enable_config_plugin_ibft" = "yes")
 109 AM_CONDITIONAL(CONFIG_PLUGIN_IFCFG_RH, test "$enable_ifcfg_rh" = "yes")
 110 AM_CONDITIONAL(CONFIG_PLUGIN_IFUPDOWN, test "$enable_ifupdown" = "yes")
 111 AM_CONDITIONAL(CONFIG_PLUGIN_IFNET, test "$enable_ifnet" = "yes")
 112
 113 AC_ARG_WITH(config-plugins-default, AS_HELP_STRING([--with-config-plugins-default=PLUGINS], [Default configuration option for main.plugins setting, used as fallback if the configuration option is unset]), [config_plugins_default="$withval"], [config_plugins_default=""])
 114 if test -z "$config_plugins_default" -o "$config_plugins_default" = no; then
 115     config_plugins_default=''
 116     test "$enable_ifcfg_rh" = "yes"           && config_plugins_default="$config_plugins_default,ifcfg-rh"
 117     test "$enable_ifupdown" = "yes"           && config_plugins_default="$config_plugins_default,ifupdown"
 118     test "$enable_ifnet" = "yes"              && config_plugins_default="$config_plugins_default,ifnet"
 119     test "$enable_config_plugin_ibft" = "yes" && config_plugins_default="$config_plugins_default,ibft"
 120     config_plugins_default="${config_plugins_default#,}"
 121 fi
 122
 123 test "$enable_ifcfg_rh" = "yes"           && distro_plugins="$distro_plugins,ifcfg-rh"
 124 test "$enable_ifcfg_suse" = "yes"         && distro_plugins="$distro_plugins,ifcfg-suse"
 125 test "$enable_ifupdown" = "yes"           && distro_plugins="$distro_plugins,ifupdown"
 126 test "$enable_ifnet" = "yes"              && distro_plugins="$distro_plugins,ifnet"
 127 distro_plugins="${distro_plugins#,}"
 128
 129 AC_DEFINE_UNQUOTED(CONFIG_PLUGINS_DEFAULT, "$config_plugins_default", [Default configuration option for main.plugins setting])
 130 if test "${enable_config_plugin_ibft}" = yes; then
 131         AC_DEFINE(WITH_SETTINGS_PLUGIN_IBFT, 1, [Whether compilation of ibft setting plugin is enabled])
 132 else
 133         AC_DEFINE(WITH_SETTINGS_PLUGIN_IBFT, 0, [Whether compilation of ibft setting plugin is enabled])
 134 fi
 135
 136 if test "$enable_ifcfg_rh" = "yes"; then
 137     DISTRO_NETWORK_SERVICE=network.service
 138 fi
 139 AC_SUBST(DISTRO_NETWORK_SERVICE)
 140
 141 AC_SUBST(NM_CONFIG_KEYFILE_PATH_DEFAULT, "${sysconfdir}/$PACKAGE/system-connections", [The keyfile directory])
 142 AC_DEFINE_UNQUOTED(NM_CONFIG_KEYFILE_PATH_DEFAULT, "$NM_CONFIG_KEYFILE_PATH_DEFAULT", [The keyfile directory])
 143
 144 # Code coverage
 145 GNOME_CODE_COVERAGE
 146
 147 dnl
 148 dnl Distribution version string
 149 dnl
 150 AC_ARG_WITH(dist-version, AS_HELP_STRING([--with-dist-version=<NM-distribution-version>], [Define the NM''s distribution version string]), ac_distver=$withval, ac_distver="")
 151 if ! test x"$ac_distver" = x""; then
 152   AC_DEFINE_UNQUOTED(NM_DIST_VERSION, "$ac_distver", [Define the distribution version string])
 153 fi
 154
 155 AC_ARG_ENABLE(wifi, AS_HELP_STRING([--enable-wifi], [enable Wi-Fi support]))
 156 if test "${enable_wifi}" != "no"; then
 157         enable_wifi='yes'
 158         AC_DEFINE(WITH_WIFI, 1, [Define if you have Wi-Fi support])
 159 else
 160         AC_DEFINE(WITH_WIFI, 0, [Define if you have Wi-Fi support])
 161 fi
 162 AM_CONDITIONAL(WITH_WIFI, test "${enable_wifi}" = "yes")
 163
 164 dnl
 165 dnl Default to using WEXT but allow it to be disabled
 166 dnl
 167 AC_ARG_WITH(wext, AS_HELP_STRING([--with-wext=yes], [Enable or disable Linux Wireless Extensions]), ac_with_wext=$withval, ac_with_wext="$enable_wifi")
 168 if test "$ac_with_wext" != 'no'; then
 169         ac_with_wext='yes'
 170 fi
 171 if test x"$ac_with_wext" = x"yes"; then
 172         if test "$enable_wifi" != "yes"; then
 173                 AC_MSG_ERROR(Enabling WEXT support and disabling Wi-Fi makes no sense)
 174         fi
 175         AC_MSG_CHECKING([Linux kernel WEXT headers])
 176         AC_COMPILE_IFELSE(
 177                 [AC_LANG_PROGRAM(
 178                       [[#ifndef __user
 179                         #define __user
 180                         #endif
 181                         #include <sys/types.h>
 182                         #include <linux/types.h>
 183                         #include <sys/socket.h>
 184                         #include <linux/wireless.h>]],
 185                       [[#ifndef IWEVGENIE
 186                         #error "not found"
 187                         #endif]])],
 188                 [ac_have_iwevgenie=yes],
 189                 [ac_have_iwevgenie=no])
 190         AC_MSG_RESULT($ac_have_iwevgenie)
 191         if test "$ac_have_iwevgenie" = no; then
 192                AC_MSG_ERROR(Linux kernel development header linux/wireless.h not installed or not functional)
 193         fi
 194         AC_DEFINE(HAVE_WEXT, 1, [Define if you have Linux Wireless Extensions support])
 195 else
 196         AC_DEFINE(HAVE_WEXT, 0, [Define if you have Linux Wireless Extensions support])
 197 fi
 198 AM_CONDITIONAL(WITH_WEXT, test x"${ac_with_wext}" = x"yes")
 199
 200 AC_MSG_CHECKING([Linux kernel nl80211 headers])
 201 AC_COMPILE_IFELSE(
 202         [AC_LANG_PROGRAM(
 203               [[#ifndef __user
 204                 #define __user
 205                 #endif
 206                 #include <sys/types.h>
 207                 #include <linux/types.h>
 208                 #include <sys/socket.h>
 209                 #include <linux/nl80211.h>]],
 210               [[int a = NL80211_RATE_INFO_BITRATE; a++;]])],
 211         [ac_have_nl80211=yes],
 212         [ac_have_nl80211=no])
 213 AC_MSG_RESULT($ac_have_nl80211)
 214 if test "$ac_have_nl80211" = no; then
 215         AC_MSG_ERROR(Linux kernel development header linux/nl80211.h not installed or not functional)
 216 fi
 217
 218 if test "$with_wifi" = "yes"; then
 219         AC_MSG_CHECKING([Linux kernel nl80211 Critical Protocol Start/Stop])
 220         AC_COMPILE_IFELSE(
 221                 [AC_LANG_PROGRAM(
 222                   [[#ifndef __user
 223                     #define __user
 224                     #endif
 225                     #include <sys/types.h>
 226                     #include <linux/types.h>
 227                     #include <sys/socket.h>
 228                     #include <linux/nl80211.h>]],
 229                   [[unsigned int a = NL80211_CMD_CRIT_PROTOCOL_START; a++;]])],
 230                 [ac_have_nl80211_critproto=yes],
 231                 [ac_have_nl80211_critproto=no])
 232         AC_MSG_RESULT($ac_have_nl80211_critproto)
 233 else
 234         ac_have_nl80211_critproto='no'
 235 fi
 236 if test "$ac_have_nl80211_critproto" = yes; then
 237         AC_DEFINE(HAVE_NL80211_CRITICAL_PROTOCOL_CMDS, 1, [Define if nl80211 has critical protocol support])
 238 else
 239         AC_DEFINE(HAVE_NL80211_CRITICAL_PROTOCOL_CMDS, 0, [Define if nl80211 has critical protocol support])
 240 fi
 241
 242 dnl
 243 dnl Check for newer VLAN flags
 244 dnl
 245 AC_MSG_CHECKING([Linux kernel VLAN_FLAG_LOOSE_BINDING enum value])
 246 AC_COMPILE_IFELSE(
 247         [AC_LANG_PROGRAM(
 248               [[#ifndef __user
 249                 #define __user
 250                 #endif
 251                 #include <sys/types.h>
 252                 #include <linux/types.h>
 253                 #include <linux/if_vlan.h>]],
 254               [[unsigned int a = VLAN_FLAG_LOOSE_BINDING;]])],
 255         [ac_have_vlan_flag_loose_binding=yes],
 256         [ac_have_vlan_flag_loose_binding=no])
 257 AC_MSG_RESULT($ac_have_vlan_flag_loose_binding)
 258 if test "$ac_have_vlan_flag_loose_binding" = yes; then
 259         AC_DEFINE(HAVE_VLAN_FLAG_LOOSE_BINDING, 1, [Define if you have VLAN_FLAG_LOOSE_BINDING])
 260 else
 261         AC_DEFINE(HAVE_VLAN_FLAG_LOOSE_BINDING, 0, [Define if you have VLAN_FLAG_LOOSE_BINDING])
 262 fi
 263
 264 dnl
 265 dnl Checks for libm - needed for pow()
 266 dnl
 267 LT_LIB_M
 268
 269 dnl
 270 dnl Checks for libdl - on certain platforms its part of libc
 271 dnl
 272 AC_CHECK_LIB([dl], [dladdr], LIBDL="-ldl", LIBDL="")
 273 AC_SUBST(LIBDL)
 274
 275 PKG_CHECK_MODULES(GLIB, [gio-unix-2.0 >= 2.37.6 gmodule-2.0],
 276         [AC_SUBST(LOG_DRIVER, '$(top_srcdir)/build-aux/tap-driver.sh'),
 277          AC_SUBST(AM_TESTS_FD_REDIRECT, '--tap')],
 278         [PKG_CHECK_MODULES(GLIB, gio-unix-2.0 >= 2.32 gmodule-2.0)
 279          AC_SUBST(LOG_DRIVER, '$(top_srcdir)/build-aux/test-driver')])
 280
 281 dnl GLIB_VERSION_MIN_REQUIRED should match the version above.
 282 dnl GLIB_VERSION_MAX_ALLOWED should be set to the same version;
 283 dnl nm-glib.h will cause it to be overridden for the functions
 284 dnl we have compat versions of.
 285 GLIB_CFLAGS="$GLIB_CFLAGS -DGLIB_VERSION_MIN_REQUIRED=GLIB_VERSION_2_32 -DGLIB_VERSION_MAX_ALLOWED=GLIB_VERSION_2_32"
 286
 287 AC_SUBST(GLIB_CFLAGS)
 288 AC_SUBST(GLIB_LIBS)
 289
 290 AC_ARG_WITH(libnm-glib, AS_HELP_STRING([--without-libnm-glib], [don't build legacy libraries]))
 291 if test "$with_libnm_glib" != "no"; then
 292     PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.1 dbus-glib-1 >= 0.94, :,
 293                             [AC_MSG_FAILURE([$DBUS_PKG_ERRORS
 294
 295 Configure with --without-libnm-glib if you do not need the legacy libraries])])
 296     with_libnm_glib=yes
 297 fi
 298 AM_CONDITIONAL(WITH_LEGACY_LIBRARIES, test "$with_libnm_glib" != "no")
 299
 300 PKG_CHECK_MODULES(GUDEV, gudev-1.0 >= 165)
 301
 302 GOBJECT_INTROSPECTION_CHECK([0.9.6])
 303
 304 # Qt4
 305 PKG_CHECK_MODULES(QT, [QtCore >= 4 QtDBus QtNetwork], [have_qt=yes],[have_qt=no])
 306 AC_ARG_ENABLE(qt, AS_HELP_STRING([--enable-qt], [enable Qt examples]),
 307                      [enable_qt=${enableval}], [enable_qt=${have_qt}])
 308 if (test "${enable_qt}" = "yes"); then
 309         if test x"$have_qt" = x"no"; then
 310                 AC_MSG_ERROR(Qt development headers are required)
 311         fi
 312         # Check for moc-qt4 and if not found then moc
 313         QT4_BINDIR=`$PKG_CONFIG QtCore --variable moc_location`
 314         AC_CHECK_PROGS(MOC, [moc-qt4 moc],, [$QT4_BINDIR:$PATH])
 315 fi
 316 AM_CONDITIONAL(WITH_QT, test "${enable_qt}" = "yes")
 317
 318 AC_ARG_WITH(udev-dir, AS_HELP_STRING([--with-udev-dir=DIR], [Absolute path of the udev base directory. Set to 'no' not to install the udev rules]), [], [with_udev_dir="yes"])
 319 if (test "$with_udev_dir" != 'no'); then
 320         if (test "$with_udev_dir" != 'yes' && printf '%s' "$with_udev_dir" | grep -v -q '^/'); then
 321                 AC_MSG_ERROR([--with-udev-dir must be an absolute path or 'yes' or 'no'. Instead it is '$with_udev_dir'])
 322         fi
 323         if (test "$with_udev_dir" = 'yes'); then
 324                 with_udev_dir="/lib/udev"
 325         fi
 326         UDEV_DIR="$with_udev_dir"
 327         AC_SUBST(UDEV_DIR)
 328 fi
 329 AM_CONDITIONAL(WITH_UDEV_DIR, test "$with_udev_dir" != 'no')
 330
 331 # systemd unit support
 332 AC_ARG_WITH([systemdsystemunitdir], AS_HELP_STRING([--with-systemdsystemunitdir=DIR],
 333         [Directory for systemd service files]))
 334 # default location
 335 AS_IF([test -z "$with_systemdsystemunitdir" && $PKG_CONFIG systemd],
 336         with_systemdsystemunitdir="\$(prefix)/lib/systemd/system")
 337 AS_IF([test -z "$with_systemdsystemunitdir"], with_systemdsystemunitdir=no)
 338 # add conditional and subst
 339 AM_CONDITIONAL(HAVE_SYSTEMD, [test "$with_systemdsystemunitdir" != no])
 340 if test "$with_systemdsystemunitdir" != no; then
 341         AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
 342         AC_DEFINE(HAVE_SYSTEMD, 1, [Define if systemd support is available])
 343 else
 344         AC_DEFINE(HAVE_SYSTEMD, 0, [Define if systemd support is available])
 345 fi
 346
 347 PKG_CHECK_MODULES(SYSTEMD_200, [systemd >= 200], [have_systemd_200=yes],[have_systemd_200=no])
 348 AM_CONDITIONAL(HAVE_SYSTEMD_200, test "${have_systemd_200}" = "yes")
 349
 350 # Hostname persist mode
 351 AC_ARG_WITH(hostname-persist, AS_HELP_STRING([--with-hostname-persist=default|suse|gentoo],
 352         [Hostname persist method]))
 353
 354 AS_IF([test "$with_hostname_persist" = "suse"], hostname_persist=suse)
 355 AS_IF([test "$with_hostname_persist" = "gentoo"], hostname_persist=gentoo)
 356 AS_IF([test "$with_hostname_persist" = "default"], hostname_persist=default)
 357 # if the method was not explicitly set, try to guess it from the enabled plugins
 358 AS_IF([test -z "$hostname_persist" -a "$distro_plugins" = "ifcfg-suse"], hostname_persist=suse)
 359 AS_IF([test -z "$hostname_persist" -a "$distro_plugins" = "ifnet"], hostname_persist=gentoo)
 360 AS_IF([test -z "$hostname_persist"], hostname_persist=default)
 361
 362 if test "$hostname_persist" = suse; then
 363         AC_DEFINE(HOSTNAME_PERSIST_SUSE, 1, [Enable SuSE hostname persist method])
 364 elif test "$hostname_persist" = gentoo; then
 365         AC_DEFINE(HOSTNAME_PERSIST_GENTOO, 1, [Enable Gentoo hostname persist method])
 366 fi
 367
 368 AC_ARG_WITH(systemd-journal, AS_HELP_STRING([--with-systemd-journal=yes|no], [Use systemd journal for logging]))
 369 have_systemd_journal=no
 370 if test "$with_systemd_journal" != "no"; then
 371         PKG_CHECK_MODULES(SYSTEMD_JOURNAL,
 372                           [libsystemd >= 209],
 373                           [have_systemd_journal=yes],
 374                           [PKG_CHECK_MODULES(SYSTEMD_JOURNAL,
 375                                              [libsystemd-journal],
 376                                              [have_systemd_journal=yes],
 377                                              [have_systemd_journal=no])])
 378         if test "$have_systemd_journal" != "yes"; then
 379                 if test "$with_systemd_journal" = "yes"; then
 380                         AC_MSG_ERROR([Missing systemd-journald support])
 381                 fi
 382         fi
 383 fi
 384 if test "$have_systemd_journal" = "yes"; then
 385         AC_DEFINE([SYSTEMD_JOURNAL], 1, [Define to 1 if libsystemd-journald is available])
 386 else
 387         AC_DEFINE([SYSTEMD_JOURNAL], 0, [Define to 1 if libsystemd-journald is available])
 388 fi
 389
 390 AC_ARG_WITH(config-logging-backend-default, AS_HELP_STRING([--with-logging-backend-default=backend], [Default value for logging.backend]), nm_config_logging_backend_default="$withval", nm_config_logging_backend_default="")
 391 if test "$nm_config_logging_backend_default" != 'debug' \
 392      -a "$nm_config_logging_backend_default" != 'syslog' \
 393      -a "$nm_config_logging_backend_default" != 'journal' \
 394      -a "$nm_config_logging_backend_default" != 'journal-syslog-style'; then
 395         # unknown backend. Reset to default. Silently accept the invalid value to
 396         # be future proof.
 397         nm_config_logging_backend_default=''
 398 fi
 399 if test "$nm_config_logging_backend_default" = ""; then
 400         if test "$have_systemd_journal" = "yes"; then
 401                 nm_config_logging_backend_default='journal-syslog-style'
 402         else
 403                 nm_config_logging_backend_default='syslog'
 404         fi
 405 fi
 406 AC_DEFINE_UNQUOTED(NM_CONFIG_LOGGING_BACKEND_DEFAULT, "$nm_config_logging_backend_default", [Default configuration option for logging.backend])
 407 NM_CONFIG_LOGGING_BACKEND_DEFAULT_TEXT="$nm_config_logging_backend_default"
 408 AC_SUBST(NM_CONFIG_LOGGING_BACKEND_DEFAULT_TEXT)
 409
 410 # Session tracking support
 411 AC_ARG_WITH(systemd-logind, AS_HELP_STRING([--with-systemd-logind=yes|no],
 412         [Support systemd session tracking]))
 413 AC_ARG_WITH(consolekit, AS_HELP_STRING([--with-consolekit=yes|no],
 414         [Support consolekit session tracking]))
 415 AC_ARG_WITH(session-tracking, AS_HELP_STRING([--with-session-tracking=systemd|consolekit|no],
 416         [Compatibility option to choose one session tracking module]))
 417 # backwards compatibility
 418 AS_IF([test "$with_session_tracking" = "ck"], [use_consolekit="yes" use_systemd_logind="no"])
 419 AS_IF([test "$with_session_tracking" = "consolekit"], [use_consolekit="yes" use_systemd_logind="no"])
 420 AS_IF([test "$with_session_tracking" = "systemd"], [use_consolekit="no" use_systemd_logind="yes"])
 421 AS_IF([test "$with_session_tracking" = "no"], [use_consolekit="no" use_systemd_logind="no"])
 422 AS_IF([test "$with_session_tracking" = "none"], [use_consolekit="no" use_systemd_logind="no"])
 423 # current options
 424 AS_IF([test -n "$with_systemd_logind" ], [use_systemd_logind="$with_systemd_logind"])
 425 AS_IF([test -n "$with_consolekit" ], [use_consolekit="$with_consolekit"])
 426 # defaults
 427 AS_IF([test -z "$use_systemd_logind"], [use_systemd_logind="auto"])
 428 AS_IF([test -z "$use_consolekit"], [use_consolekit="yes"])
 429 # output
 430 session_tracking=
 431 if test "$use_systemd_logind" = "yes" -o "$use_systemd_logind" = "auto"; then
 432     PKG_CHECK_MODULES(SYSTEMD_LOGIN, [libsystemd], [have_systemd_logind=yes], [PKG_CHECK_MODULES(SYSTEMD_LOGIN, [libsystemd-login], [have_systemd_logind=yes], [have_systemd_logind=no])])
 433 else
 434     have_systemd_logind=no
 435 fi
 436 if test "$use_systemd_logind" = "yes" -a "$have_systemd_logind" = "no"; then
 437     AC_MSG_ERROR([You must have libsystemd installed to build with systemd-logind support.])
 438 fi
 439 if test "$have_systemd_logind" = "yes"; then
 440         AC_DEFINE([SESSION_TRACKING_SYSTEMD], 1, [Define to 1 if libsystemd-login is available])
 441         session_tracking="$session_tracking, systemd-logind"
 442 fi
 443 if test "$use_consolekit" = "yes"; then
 444         AC_DEFINE([SESSION_TRACKING_CONSOLEKIT], 1, [Define to 1 if ConsoleKit is available])
 445         AC_DEFINE([CKDB_PATH], "/var/run/ConsoleKit/database", [Path to ConsoleKit database])
 446         session_tracking="$session_tracking, consolekit"
 447 fi
 448 session_tracking="$(printf '%s' "${session_tracking}" | sed 's/^, //')"
 449
 450 AC_ARG_WITH(suspend-resume, AS_HELP_STRING([--with-suspend-resume=upower|systemd|consolekit], [Build NetworkManager with specific suspend/resume support]))
 451 if test "z$with_suspend_resume" = "z"; then
 452     PKG_CHECK_EXISTS([libsystemd >= 209], [have_systemd_inhibit=yes],
 453                      [PKG_CHECK_EXISTS([libsystemd-login >= 183], [have_systemd_inhibit=yes], [have_systemd_inhibit=no])])
 454     if test "z${have_systemd_inhibit}" = "zyes"; then
 455         # Use systemd if it's new enough
 456         with_suspend_resume="systemd"
 457     else
 458         if test "$use_consolekit" = "yes"; then
 459                 # Use consolekit suspend if session tracking is consolekit
 460                 with_suspend_resume="consolekit"
 461         else
 462                 # Fall back to upower
 463                 with_suspend_resume="upower"
 464         fi
 465     fi
 466 fi
 467
 468 case $with_suspend_resume in
 469     upower) ;;
 470     systemd)
 471         PKG_CHECK_MODULES(SYSTEMD_INHIBIT, [libsystemd >= 209],,
 472                           [PKG_CHECK_MODULES(SYSTEMD_INHIBIT, [libsystemd-login >= 183])])
 473         AC_DEFINE([SUSPEND_RESUME_SYSTEMD], 1, [Define to 1 to use systemd suspend api])
 474         ;;
 475     consolekit)
 476         AC_DEFINE([SUSPEND_RESUME_CONSOLEKIT], 1, [Define to 1 to use ConsoleKit2 suspend api])
 477         ;;
 478     *)
 479         AC_MSG_ERROR(--with-suspend-resume must be one of [upower, systemd, consolekit])
 480         ;;
 481 esac
 482 AM_CONDITIONAL(SUSPEND_RESUME_UPOWER, test "x$with_suspend_resume" = "xupower")
 483 AM_CONDITIONAL(SUSPEND_RESUME_SYSTEMD, test "x$with_suspend_resume" = "xsystemd")
 484 AM_CONDITIONAL(SUSPEND_RESUME_CONSOLEKIT, test "x$with_suspend_resume" = "xconsolekit")
 485
 486 # SELinux support
 487 AC_ARG_WITH(selinux, AS_HELP_STRING([--with-selinux=yes|no|auto], [Build with SELinux (default: auto)]),,[with_selinux=auto])
 488 if test "$with_selinux" = "yes" -o "$with_selinux" = "auto"; then
 489     PKG_CHECK_MODULES(SELINUX, libselinux, [have_selinux=yes], [have_selinux=no])
 490 else
 491     have_selinux=no
 492 fi
 493 if test "$with_selinux" = "yes" -a "$have_selinux" = "no"; then
 494     AC_MSG_ERROR([You must have libselinux installed to build --with-selinux=yes.])
 495 fi
 496 if test "$have_selinux" = "yes"; then
 497     AC_DEFINE(HAVE_SELINUX, 1, [Define if you have SELinux support])
 498 else
 499     AC_DEFINE(HAVE_SELINUX, 0, [Define if you have SELinux support])
 500 fi
 501
 502 # libaudit support
 503 AC_ARG_WITH(libaudit, AS_HELP_STRING([--with-libaudit=yes|yes-disabled-by-default|no|auto], [Build with audit daemon support (default: auto). yes-disabled-by-default enables support, but disables it unless explicitly configured via NetworkManager.conf]),,[with_libaudit=auto])
 504 if test "$with_libaudit" = "yes" -o "$with_libaudit" = "yes-disabled-by-default" -o "$with_libaudit" = "auto"; then
 505     PKG_CHECK_MODULES(LIBAUDIT, audit, [have_libaudit=yes], [have_libaudit=no])
 506     if test "$with_libaudit" != "auto" -a "$have_libaudit" = "no"; then
 507         AC_MSG_ERROR([You must have libaudit installed to build --with-libaudit=$with_libaudit.])
 508     fi
 509 else
 510     have_libaudit=no
 511 fi
 512 if test "$have_libaudit" = "yes"; then
 513     AC_DEFINE(HAVE_LIBAUDIT, 1, [Define if you have libaudit support])
 514         if test "$with_libaudit" = "yes-disabled-by-default"; then
 515                 AC_DEFINE(NM_CONFIG_DEFAULT_LOGGING_AUDIT, FALSE, [The default value of the logging.audit configuration option])
 516                 NM_CONFIG_DEFAULT_LOGGING_AUDIT_TEXT='false'
 517         else
 518                 AC_DEFINE(NM_CONFIG_DEFAULT_LOGGING_AUDIT, TRUE,  [The default value of the logging.audit configuration option])
 519                 NM_CONFIG_DEFAULT_LOGGING_AUDIT_TEXT='true'
 520         fi
 521 else
 522     AC_DEFINE(HAVE_LIBAUDIT, 0, [Define if you have libaudit support])
 523         AC_DEFINE(NM_CONFIG_DEFAULT_LOGGING_AUDIT, FALSE, [The default value of the logging.audit configuration option])
 524     NM_CONFIG_DEFAULT_LOGGING_AUDIT_TEXT='false'
 525 fi
 526 AC_SUBST(NM_CONFIG_DEFAULT_LOGGING_AUDIT_TEXT)
 527
 528 # libnl support for the linux platform
 529 PKG_CHECK_MODULES(LIBNL, libnl-3.0 >= 3.2.8)
 530
 531 # uuid library
 532 PKG_CHECK_MODULES(UUID, uuid)
 533
 534 dnl Checks for readline library - used by nmcli
 535 AX_LIB_READLINE
 536
 537 # Teamd control checks
 538 PKG_CHECK_MODULES(LIBTEAMDCTL, [libteamdctl >= 1.9], [have_teamdctl=yes],[have_teamdctl=no])
 539 AC_ARG_ENABLE(teamdctl, AS_HELP_STRING([--enable-teamdctl], [enable Teamd control support]),
 540                      [enable_teamdctl=${enableval}], [enable_teamdctl=${have_teamdctl}])
 541 if (test "${enable_teamdctl}" = "yes"); then
 542         if test x"$have_teamdctl" = x"no"; then
 543                 AC_MSG_ERROR(Teamd control is required)
 544         fi
 545         # temporary bug workaround
 546         LIBTEAMDCTL_CFLAGS=`echo $LIBTEAMDCTL_CFLAGS | sed -e 's:/teamdctl.h::'`
 547         AC_DEFINE(WITH_TEAMDCTL, 1, [Define if you have Teamd control support])
 548 else
 549         AC_DEFINE(WITH_TEAMDCTL, 0, [Define if you have Teamd control support])
 550 fi
 551 AM_CONDITIONAL(WITH_TEAMDCTL, test "${enable_teamdctl}" = "yes")
 552
 553 # we usually compile with polkit support. --enable-polkit=yes|no only sets the
 554 # default configuration for main.auth-polkit. User can always enable/disable polkit
 555 # autorization via config. Only when specifying --enable-polkit=disabled, we do
 556 # not compile support. In this case, the user cannot enable polkit authorization via
 557 # configuration.
 558 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--enable-polkit=yes|no|disabled], [set default value for auth-polkit configuration option. This value can be overwritten by NM configuration. 'disabled' compiles NM without any support]),
 559                      [enable_polkit=${enableval}], [enable_polkit=yes])
 560 if (test "${enable_polkit}" != "no" -a "${enable_polkit}" != "disabled"); then
 561         enable_polkit=yes
 562         AC_DEFINE(NM_CONFIG_DEFAULT_AUTH_POLKIT, TRUE, [The default value of the auth-polkit configuration option])
 563         NM_CONFIG_DEFAULT_AUTH_POLKIT_TEXT='true'
 564 else
 565         AC_DEFINE(NM_CONFIG_DEFAULT_AUTH_POLKIT, FALSE, [The default value of the auth-polkit configuration option])
 566         NM_CONFIG_DEFAULT_AUTH_POLKIT_TEXT='false'
 567 fi
 568 if (test "${enable_polkit}" != "disabled"); then
 569         AC_DEFINE(WITH_POLKIT, 1, [whether to compile polkit support])
 570 else
 571         AC_DEFINE(WITH_POLKIT, 0, [whether to compile polkit support])
 572 fi
 573 AC_SUBST(NM_CONFIG_DEFAULT_AUTH_POLKIT_TEXT)
 574
 575 PKG_CHECK_MODULES(POLKIT, [polkit-agent-1 >= 0.97], [have_pk_agent=yes],[have_pk_agent=no])
 576 AC_ARG_ENABLE(polkit-agent, AS_HELP_STRING([--enable-polkit-agent], [enable polkit agent for clients]),
 577                      [enable_polkit_agent=${enableval}], [enable_polkit_agent=${have_pk_agent}])
 578 if (test "${enable_polkit_agent}" = "yes"); then
 579         if test x"$have_pk_agent" = x"no"; then
 580                 AC_MSG_ERROR(Polkit agent is required)
 581         fi
 582         AC_DEFINE(WITH_POLKIT_AGENT, 1, [Define if you have polkit agent])
 583 else
 584         AC_DEFINE(WITH_POLKIT_AGENT, 0, [Define if you have polkit agent])
 585 fi
 586 AM_CONDITIONAL(WITH_POLKIT_AGENT, test "${enable_polkit_agent}" = "yes")
 587
 588 AC_ARG_ENABLE(modify-system,
 589               AS_HELP_STRING([--enable-modify-system], [Allow users to modify system connections]))
 590 if test "${enable_modify_system}" = "yes"; then
 591         NM_MODIFY_SYSTEM_POLICY="yes"
 592 else
 593         NM_MODIFY_SYSTEM_POLICY="auth_admin_keep"
 594 fi
 595 AC_SUBST(NM_MODIFY_SYSTEM_POLICY)
 596
 597 AC_ARG_WITH(crypto, AS_HELP_STRING([--with-crypto=nss|gnutls], [Cryptography library to use for certificate and key operations]),ac_crypto=$withval, ac_crypto=nss)
 598
 599 with_nss=no
 600 with_gnutls=no
 601 if test x"$ac_crypto" = xnss; then
 602   PKG_CHECK_MODULES(NSS, [nss >= 3.11])
 603
 604   # Work around a pkg-config bug (fdo #29801) where exists != usable
 605   FOO=`$PKG_CONFIG --cflags --libs nss`
 606   if test x"$?" != "x0"; then
 607     AC_MSG_ERROR([No usable NSS found])
 608   fi
 609
 610   AC_DEFINE(HAVE_NSS, 1, [Define if you have NSS])
 611   with_nss=yes
 612 elif test x"$ac_crypto" = xgnutls; then
 613   PKG_CHECK_MODULES(GNUTLS, [gnutls >= 2.12])
 614   AC_DEFINE(HAVE_GNUTLS, 1, [Define if you have libgnutls])
 615   with_gnutls=yes
 616 else
 617   AC_MSG_ERROR([Please choose either 'nss' or 'gnutls' for certificate and crypto operations])
 618 fi
 619 AM_CONDITIONAL(WITH_NSS, test x"$with_nss" != xno)
 620 AM_CONDITIONAL(WITH_GNUTLS, test x"$with_gnutls" != xno)
 621
 622 # Shouldn't ever trigger this, but just in case...
 623 if test x"$ac_nss" = xno -a x"$ac_gnutls" = xno; then
 624   AC_MSG_ERROR([Could not find required development headers and libraries for '$ac_crypto'])
 625 fi
 626
 627 GLIB_MAKEFILE='$(top_srcdir)/Makefile.glib'
 628 AC_SUBST(GLIB_MAKEFILE)
 629 GLIB_GENMARSHAL=`$PKG_CONFIG --variable=glib_genmarshal glib-2.0`
 630 AC_SUBST(GLIB_GENMARSHAL)
 631 GLIB_MKENUMS=`$PKG_CONFIG --variable=glib_mkenums glib-2.0`
 632 AC_SUBST(GLIB_MKENUMS)
 633
 634 AC_ARG_WITH(dbus-sys-dir, AS_HELP_STRING([--with-dbus-sys-dir=DIR], [where D-BUS system.d directory is]))
 635
 636 if test -n "$with_dbus_sys_dir" ; then
 637     DBUS_SYS_DIR="$with_dbus_sys_dir"
 638 else
 639     DBUS_SYS_DIR="${sysconfdir}/dbus-1/system.d"
 640 fi
 641 AC_SUBST(DBUS_SYS_DIR)
 642
 643 # pppd
 644 AC_ARG_ENABLE(ppp, AS_HELP_STRING([--enable-ppp], [enable PPP/PPPoE support]),
 645                      [enable_ppp=${enableval}], [enable_ppp=yes])
 646 if (test "${enable_ppp}" = "yes"); then
 647         AC_CHECK_HEADERS(pppd/pppd.h,,
 648                 AC_MSG_ERROR("couldn't find pppd.h. pppd development headers are required."))
 649
 650         AC_DEFINE(WITH_PPP, 1, [Define if you have PPP support])
 651 else
 652         AC_DEFINE(WITH_PPP, 0, [Define if you have PPP support])
 653 fi
 654 AM_CONDITIONAL(WITH_PPP, test "${enable_ppp}" = "yes")
 655
 656 AC_ARG_WITH([pppd-plugin-dir], AS_HELP_STRING([--with-pppd-plugin-dir=DIR], [path to the pppd plugins directory]))
 657
 658 if test -n "$with_pppd_plugin_dir" ; then
 659         PPPD_PLUGIN_DIR="$with_pppd_plugin_dir"
 660 else
 661         PPPD_PLUGIN_DIR="${libdir}/pppd/2.4.5"
 662 fi
 663 AC_SUBST(PPPD_PLUGIN_DIR)
 664
 665 AC_ARG_WITH(pppd, AS_HELP_STRING([--with-pppd=/path/to/pppd], [path to pppd binary]))
 666 if test "x${with_pppd}" = x; then
 667   AC_PATH_PROG(PPPD_PATH, pppd, [], $PATH:/sbin:/usr/sbin)
 668 else
 669   PPPD_PATH="$with_pppd"
 670 fi
 671 AC_DEFINE_UNQUOTED(PPPD_PATH, "$PPPD_PATH", [Define to path of pppd binary])
 672 AC_SUBST(PPPD_PATH)
 673
 674 # ModemManager1 with libmm-glib
 675 AC_ARG_WITH(modem-manager-1, AS_HELP_STRING([--with-modem-manager-1], [Enable new ModemManager1 interface support]),,[with_modem_manager_1=auto])
 676 if (test "${with_modem_manager_1}" != "no"); then
 677     PKG_CHECK_MODULES(MM_GLIB,
 678                       [mm-glib >= 0.7.991],
 679                       [have_libmm_glib=yes],
 680                       [have_libmm_glib=no])
 681
 682     if (test "${have_libmm_glib}" = "no"); then
 683         if (test "${with_modem_manager_1}" = "yes"); then
 684             AC_MSG_ERROR([Couldn't find libmm-glib])
 685         else
 686             with_modem_manager_1="no"
 687         fi
 688     else
 689         with_modem_manager_1="yes"
 690     fi
 691 fi
 692
 693 if (test "${with_modem_manager_1}" = "yes"); then
 694     AC_DEFINE(WITH_MODEM_MANAGER_1, 1, [Define if you have ModemManager1 support])
 695 else
 696         AC_DEFINE(WITH_MODEM_MANAGER_1, 0, [Define if you have ModemManager1 support])
 697 fi
 698 AM_CONDITIONAL(WITH_MODEM_MANAGER_1, test "${with_modem_manager_1}" = "yes")
 699
 700 # Bluez5 DUN support
 701 PKG_CHECK_MODULES(BLUEZ5, [bluez >= 5], [have_bluez5=yes],[have_bluez5=no])
 702 AC_ARG_ENABLE(bluez5-dun, AS_HELP_STRING([--enable-bluez5-dun], [enable Bluez5 DUN support]),
 703                 [enable_bluez5_dun=${enableval}], [enable_bluez5_dun=${have_bluez5}])
 704 if (test "${enable_bluez5_dun}" = "yes"); then
 705         if test x"$have_bluez5" = x"no"; then
 706                 AC_MSG_ERROR(Bluez 5.x development headers are required)
 707         fi
 708         AC_DEFINE(WITH_BLUEZ5_DUN, 1, [Define if you have Bluez 5 libraries])
 709 else
 710         AC_DEFINE(WITH_BLUEZ5_DUN, 0, [Define if you have Bluez 5 libraries])
 711 fi
 712 AM_CONDITIONAL(WITH_BLUEZ5_DUN, test "${enable_bluez5_dun}" = "yes")
 713
 714 # DHCP client support
 715 AC_ARG_WITH([dhclient], AS_HELP_STRING([--with-dhclient=yes|no|path], [Enable dhclient 4.x support]))
 716 AC_ARG_WITH([dhcpcd], AS_HELP_STRING([--with-dhcpcd=yes|no|path], [Enable dhcpcd 4.x support]))
 717 # Default to "yes"
 718 AS_IF([test -z "$with_dhclient"], with_dhclient=yes)
 719 AS_IF([test -z "$with_dhcpcd"], with_dhcpcd=yes)
 720 # Search and check the executables
 721 if test "$with_dhclient" = "yes"; then
 722         AC_PATH_PROGS(with_dhclient, dhclient, no, /sbin:/usr/sbin:/usr/local/sbin)
 723         if test "$with_dhclient" != "no"; then
 724                 if ! $with_dhclient --version 2>&1 | grep -q "^isc-dhclient-4\."; then
 725                         AC_MSG_WARN([Cannot use dhclient, version 4.x is required])
 726                         with_dhclient=no
 727                 fi
 728         fi
 729 fi
 730 if test "$with_dhcpcd" = "yes"; then
 731         AC_PATH_PROGS(with_dhcpcd, dhcpcd, no, /sbin:/usr/sbin:/usr/local/sbin)
 732         if test "$with_dhcpcd" != "no"; then
 733                 if ! $with_dhcpcd --version 2>&1 | grep -q "^dhcpcd [[456789]]\."; then
 734                         AC_MSG_WARN([Cannot use dhcpcd, version 4.x or higher is required])
 735                         with_dhcpcd=no
 736                 elif $with_dhcpcd --version 2>&1 | grep -q "^dhcpcd [[6789]]\."; then
 737                         AC_DEFINE(DHCPCD_SUPPORTS_IPV6, 1, [Define if dhcpcd supports IPv6 (6.x+)])
 738                 fi
 739         fi
 740 fi
 741 # Fallback
 742 if test "$with_dhclient" = "no" -a "$with_dhcpcd" = "no"; then
 743         AC_MSG_WARN([Could not find a suitable DHCP client, falling back to dhclient])
 744         with_dhclient=/sbin/dhclient
 745 fi
 746 # Add substitutions
 747 if test "$with_dhclient" != "no"; then
 748         AC_DEFINE(WITH_DHCLIENT, TRUE, [Define if you have dhclient])
 749         AC_SUBST(DHCLIENT_PATH, $with_dhclient)
 750 else
 751         AC_DEFINE(WITH_DHCLIENT, FALSE, [Define if you have dhclient])
 752 fi
 753 if test "$with_dhcpcd" != "no"; then
 754         AC_DEFINE(WITH_DHCPCD, TRUE, [Define if you have dhcpcd])
 755         AC_SUBST(DHCPCD_PATH, $with_dhcpcd)
 756 else
 757         AC_DEFINE(WITH_DHCPCD, FALSE, [Define if you have dhcpcd])
 758 fi
 759
 760 # resolvconf and netconfig support
 761 AC_ARG_WITH(resolvconf, AS_HELP_STRING([--with-resolvconf=yes|no|path], [Enable resolvconf support]))
 762 AC_ARG_WITH(netconfig, AS_HELP_STRING([--with-netconfig=yes|no], [Enable SUSE netconfig support]))
 763 # Use netconfig by default on SUSE
 764 AS_IF([test -z "$with_netconfig"], AC_CHECK_FILE(/etc/SuSE-release, with_netconfig=yes))
 765 # Otherwise default to "no"
 766 AS_IF([test -z "$with_resolvconf"], with_resolvconf=no)
 767 AS_IF([test -z "$with_netconfig"], with_netconfig=no)
 768 # Find resolvconf and netconfig
 769 if test "$with_resolvconf" = "yes"; then
 770         AC_PATH_PROGS(with_resolvconf, resolvconf, no, /sbin:/usr/sbin:/usr/local/sbin)
 771 fi
 772 if test "$with_netconfig" = "yes"; then
 773         AC_PATH_PROGS(with_netconfig, netconfig, no, /sbin:/usr/sbin:/usr/local/sbin)
 774 fi
 775 # Define resolvconf and netconfig paths
 776 if test "$with_resolvconf" != "no"; then
 777         AC_DEFINE_UNQUOTED(RESOLVCONF_PATH, "$with_resolvconf", [Path to resolvconf])
 778 fi
 779 if test "$with_netconfig" != "no"; then
 780         AC_DEFINE_UNQUOTED(NETCONFIG_PATH, "$with_netconfig", [Path to netconfig])
 781 fi
 782
 783 # iptables path
 784 AC_ARG_WITH(iptables, AS_HELP_STRING([--with-iptables=/path/to/iptables], [path to iptables]))
 785 if test "x${with_iptables}" = x; then
 786   AC_PATH_PROG(IPTABLES_PATH, iptables, [], $PATH:/sbin:/usr/sbin)
 787   if ! test -x "$IPTABLES_PATH"; then
 788         AC_MSG_ERROR(iptables was not installed.)
 789   fi
 790 else
 791   IPTABLES_PATH="$with_iptables"
 792 fi
 793 AC_DEFINE_UNQUOTED(IPTABLES_PATH, "$IPTABLES_PATH", [Define to path of iptables binary])
 794 AC_SUBST(IPTABLES_PATH)
 795
 796 # dnsmasq path
 797 AC_ARG_WITH(dnsmasq, AS_HELP_STRING([--with-dnsmasq=/path/to/dnsmasq], [path to dnsmasq]))
 798 if test "x${with_dnsmasq}" = x; then
 799   AC_PATH_PROG(DNSMASQ_PATH, dnsmasq, [], $PATH:/sbin:/usr/sbin)
 800 else
 801   DNSMASQ_PATH="$with_dnsmasq"
 802 fi
 803 AC_DEFINE_UNQUOTED(DNSMASQ_PATH, "$DNSMASQ_PATH", [Define to path of dnsmasq binary])
 804 AC_SUBST(DNSMASQ_PATH)
 805
 806 # dnssec-trigger-script path
 807 AC_ARG_WITH(dnssec_trigger, AS_HELP_STRING([--with-dnssec-trigger=/path/to/dnssec-trigger-script], [path to unbound dnssec-trigger-script]))
 808 if test "x${with_dnssec_trigger}" = x; then
 809   AC_PATH_PROG(DNSSEC_TRIGGER_SCRIPT, dnssec-trigger-script, /usr/libexec/dnssec-trigger-script, /usr/local/libexec:/usr/local/lib:/usr/local/lib/dnssec-trigger:/usr/libexec:/usr/lib:/usr/lib/dnssec-trigger)
 810 else
 811   DNSSEC_TRIGGER_SCRIPT="$with_dnssec_trigger"
 812 fi
 813 AC_DEFINE_UNQUOTED(DNSSEC_TRIGGER_SCRIPT, "$DNSSEC_TRIGGER_SCRIPT", [Define to path of unbound dnssec-trigger-script])
 814 AC_SUBST(DNSSEC_TRIGGER_SCRIPT)
 815
 816 # system CA certificates path
 817 AC_ARG_WITH(system-ca-path, AS_HELP_STRING([--with-system-ca-path=/path/to/ssl/certs], [path to system CA certificates]))
 818 if test "x${with_system_ca_path}" = x; then
 819   SYSTEM_CA_PATH=/etc/ssl/certs
 820 else
 821   SYSTEM_CA_PATH="$with_system_ca_path"
 822 fi
 823 AC_DEFINE_UNQUOTED(SYSTEM_CA_PATH, "$SYSTEM_CA_PATH", [Define to path to system CA certificates])
 824 AC_SUBST(SYSTEM_CA_PATH)
 825
 826 AC_ARG_WITH(kernel-firmware-dir, AS_HELP_STRING([--with-kernel-firmware-dir=DIR], [where kernel firmware directory is (default is /lib/firmware)]))
 827
 828 if test -n "$with_kernel_firmware_dir" ; then
 829     KERNEL_FIRMWARE_DIR="$with_kernel_firmware_dir"
 830 else
 831     KERNEL_FIRMWARE_DIR="/lib/firmware"
 832 fi
 833 AC_DEFINE_UNQUOTED(KERNEL_FIRMWARE_DIR, "$KERNEL_FIRMWARE_DIR", [Define to path of the kernel firmware directory])
 834 AC_SUBST(KERNEL_FIRMWARE_DIR)
 835
 836 PKG_CHECK_MODULES(LIBSOUP, [libsoup-2.4 >= 2.26], [have_libsoup=yes],[have_libsoup=no])
 837 AC_ARG_WITH(libsoup, AS_HELP_STRING([--with-libsoup=yes|no], [Link against libsoup]), [], [with_libsoup=${have_libsoup}])
 838 if test "$with_libsoup" != "no"; then
 839         if test "$have_libsoup" != "yes"; then
 840                 AC_MSG_ERROR(libsoup library not found)
 841         fi
 842         with_libsoup='yes'
 843         AC_DEFINE(WITH_LIBSOUP, 1, [Define if you have libsoup])
 844 else
 845         AC_DEFINE(WITH_LIBSOUP, 0, [Define if you have libsoup])
 846 fi
 847 AM_CONDITIONAL(WITH_LIBSOUP, test "$with_libsoup" != "no")
 848
 849 AC_ARG_ENABLE(concheck, AS_HELP_STRING([--enable-concheck], [enable connectivity checking support]),
 850                      [enable_concheck=${enableval}], [enable_concheck=${with_libsoup}])
 851 if (test "${enable_concheck}" = "yes"); then
 852         if test x"$with_libsoup" = x"no"; then
 853                 AC_MSG_ERROR(Connectivity checking requires libsoup)
 854         fi
 855         AC_DEFINE(WITH_CONCHECK, 1, [Define if you want connectivity checking support])
 856 else
 857         AC_DEFINE(WITH_CONCHECK, 0, [Define if you want connectivity checking support])
 858 fi
 859 AM_CONDITIONAL(WITH_CONCHECK, test "${enable_concheck}" = "yes")
 860
 861 PKG_CHECK_MODULES(LIBNDP, [libndp])
 862
 863 AC_ARG_WITH(nmtui, AS_HELP_STRING([--with-nmtui=yes|no], [Build nmtui]))
 864 if test "$with_nmtui" != no; then
 865     PKG_CHECK_MODULES(NEWT, [libnewt >= 0.52.15], [build_nmtui=yes], [build_nmtui=no])
 866 else
 867     build_nmtui=no
 868 fi
 869 if test "$with_nmtui" = yes -a "$build_nmtui" = no; then
 870     AC_MSG_ERROR([You must have libnewt installed to build nmtui.])
 871 fi
 872 AM_CONDITIONAL(BUILD_NMTUI, test "$build_nmtui" = yes)
 873
 874
 875 NM_COMPILER_WARNINGS
 876
 877 AC_ARG_ENABLE(more-asserts,
 878               AS_HELP_STRING([--enable-more-asserts], [Enable more assertions for debugging (default: no). Deprecated option. Use --with-more-asserts=level]))
 879 more_asserts=0
 880 if test "${enable_more_asserts}" = "yes"; then
 881     more_asserts=100
 882 fi
 883 AC_ARG_WITH(more-asserts,
 884             AS_HELP_STRING([--with-more-asserts=level], [Enable more assertions for debugging (default: 0)]),
 885             [more_asserts=${with_more_asserts}],
 886             [])
 887 if test "${more_asserts}" = "no"; then
 888     more_asserts=0
 889 else
 890     if test "${more_asserts}" = "yes"; then
 891         more_asserts=100
 892     fi
 893 fi
 894 AC_DEFINE_UNQUOTED(NM_MORE_ASSERTS, $more_asserts, [Define if more asserts are enabled])
 895
 896 AC_ARG_ENABLE(more-logging,
 897               AS_HELP_STRING([--enable-more-logging], [Enable more debug logging (default: no)]))
 898 if test "${enable_more_logging}" = "yes"; then
 899     AC_DEFINE(NM_MORE_LOGGING, [1], [Define if more debug logging is enabled])
 900 fi
 901
 902 AC_ARG_ENABLE(lto, AS_HELP_STRING([--enable-lto], [Enable Link Time Optimization for smaller size (default: no)]))
 903 if (test "${enable_lto}" = "yes"); then
 904     CFLAGS="-flto $CFLAGS"
 905 else
 906     enable_lto='no'
 907 fi
 908
 909
 910 dnl -------------------------
 911 dnl Vala bindings
 912 dnl -------------------------
 913
 914 VAPIGEN_CHECK(0.17.1.24)
 915
 916 # Tests, utilities and documentation
 917 AC_ARG_ENABLE(tests, AS_HELP_STRING([--enable-tests=root|yes|no], [Build NetworkManager tests (default: yes)]))
 918 AC_ARG_WITH(valgrind, AS_HELP_STRING([--with-valgrind=yes|no|path], [Use valgrind to memory-check the tests (default: no)]))
 919 # Fallback to --with-tests
 920 AC_ARG_WITH(tests, AS_HELP_STRING([--with-tests], [Build NetworkManager tests (deprecated)]))
 921 AS_IF([test -n "$with_tests"], enable_tests="$with_tests")
 922 # Default to --enable-tests --with-valgrind=no
 923 AS_IF([test -z "$enable_tests"], enable_tests="yes")
 924 AS_IF([test -z "$with_valgrind"], with_valgrind="no")
 925 # Normalize values
 926 AS_IF([test "$enable_tests" != "yes" -a "$enable_tests" != "root"], enable_tests="no")
 927 # Search for tools
 928 AS_IF([test "$with_valgrind" == "yes"],
 929         [AC_PATH_PROGS(with_valgrind, valgrind, no)])
 930 # Add conditionals and substitutions
 931 AM_CONDITIONAL(ENABLE_TESTS, test "$enable_tests" != "no")
 932 AM_CONDITIONAL(REQUIRE_ROOT_TESTS, test "$enable_tests" == "root")
 933 AC_ARG_WITH(valgrind-suppressions, AS_HELP_STRING([--with-valgrind-suppressions=path], [Use specific valgrind suppression file]))
 934 if test "$with_valgrind" == no; then
 935         with_valgrind_suppressions=
 936 else
 937         if test  "$with_valgrind_suppressions" == ""; then
 938                 with_valgrind_suppressions='$(top_srcdir)/valgrind.suppressions'
 939         fi
 940 fi
 941 AS_IF([test "$with_valgrind" != "no"],
 942         AC_SUBST(VALGRIND_RULES, 'LOG_COMPILER = "$(top_srcdir)/tools/run-test-valgrind.sh" "$(LIBTOOL)" "$(with_valgrind)" '"$with_valgrind_suppressions"),
 943         AC_SUBST(VALGRIND_RULES, []))
 944 AM_CONDITIONAL(WITH_VALGRIND, test "${with_valgrind}" != "no")
 945
 946 GTK_DOC_CHECK(1.0)
 947
 948 # check for pregenerated manpages to be installed
 949 install_pregen_manpages=no
 950 if test "$enable_gtk_doc" != "yes" \
 951         -a -f man/NetworkManager.conf.5 \
 952         -a -f man/nm-settings.5 \
 953         -a -f man/nm-settings-keyfile.5 \
 954         -a -f man/nm-settings-ifcfg-rh.5 \
 955         -a -f man/nmcli-examples.5 \
 956         -a -f man/NetworkManager.8; then
 957         install_pregen_manpages=yes
 958 fi
 959 AM_CONDITIONAL(INSTALL_PREGEN_MANPAGES, test "x${install_pregen_manpages}" = "xyes")
 960
 961 # check if we can build setting property documentation
 962 if test -n "$INTROSPECTION_MAKEFILE" -a "$enable_gtk_doc" = "yes"; then
 963     # If g-i is installed we know we have python, but we might not have pygobject
 964     if python -c 'from gi.repository import GObject' >& /dev/null; then
 965         have_pyobject=yes
 966     fi
 967
 968     # gtk-doc depends on perl, but we can check for it anyway
 969     AC_PATH_PROG(PERL, perl, no)
 970     # check for needed perl modules (use YAML; YAML::XS is better, but may not be so widespread)
 971     required_perl_modules="YAML"
 972     for module in $required_perl_modules; do
 973       AC_MSG_CHECKING([checking for perl module '$module'])
 974       if ${PERL} -e 'use '$module 2>/dev/null ; then
 975           AC_MSG_RESULT([Ok])
 976           have_perl_modules=yes
 977       else
 978           AC_MSG_RESULT([Failed])
 979           AC_MSG_ERROR([You must have Perl modules to build settings plugin docs: $required_perl_modules.])
 980       fi
 981     done
 982
 983     if test "$have_pyobject" = "yes" -a "$have_perl_modules" = "yes"; then
 984         AC_DEFINE(BUILD_SETTING_DOCS, [1], [Define if you we can build nm-setting-docs.xml, nm-keyfile-docs.xml and nm-ifcfg-rh-docs.xml])
 985         build_setting_docs=yes
 986     fi
 987 fi
 988
 989 # check for pre-built setting docs
 990 if test "$build_setting_docs" != "yes" \
 991         -a -f man/nm-settings.xml \
 992         -a -f man/nm-settings-keyfile.xml \
 993         -a -f man/nm-settings-ifcfg-rh.xml \
 994         -a -f docs/api/settings-spec.xml \
 995         -a -f clients/cli/settings-docs.c; then
 996     AC_DEFINE(HAVE_SETTING_DOCS, [1], [Define if you have pre-built settings docs])
 997     have_setting_docs=yes
 998 fi
 999
1000 AM_CONDITIONAL(BUILD_SETTING_DOCS, test "$build_setting_docs" = "yes")
1001 AM_CONDITIONAL(SETTING_DOCS_AVAILABLE, test "$build_setting_docs" = "yes" -o "$have_setting_docs" = "yes")
1002
1003
1004 AC_CONFIG_FILES([
1005 Makefile
1006 include/Makefile
1007 include/nm-version-macros.h
1008 src/Makefile
1009 src/tests/Makefile
1010 src/tests/config/Makefile
1011 src/dhcp-manager/Makefile
1012 src/dhcp-manager/tests/Makefile
1013 src/dnsmasq-manager/tests/Makefile
1014 src/supplicant-manager/tests/Makefile
1015 src/supplicant-manager/tests/certs/Makefile
1016 src/ppp-manager/Makefile
1017 src/settings/plugins/Makefile
1018 src/settings/plugins/ifupdown/Makefile
1019 src/settings/plugins/ifupdown/tests/Makefile
1020 src/settings/plugins/ifnet/Makefile
1021 src/settings/plugins/ifnet/tests/Makefile
1022 src/settings/plugins/ifcfg-rh/Makefile
1023 src/settings/plugins/ifcfg-rh/tests/Makefile
1024 src/settings/plugins/ifcfg-rh/tests/network-scripts/Makefile
1025 src/settings/plugins/ibft/Makefile
1026 src/settings/plugins/ibft/tests/Makefile
1027 src/settings/plugins/keyfile/Makefile
1028 src/settings/plugins/keyfile/tests/Makefile
1029 src/settings/plugins/keyfile/tests/keyfiles/Makefile
1030 src/platform/Makefile
1031 src/platform/tests/Makefile
1032 src/rdisc/Makefile
1033 src/rdisc/tests/Makefile
1034 src/devices/Makefile
1035 src/devices/tests/Makefile
1036 src/devices/adsl/Makefile
1037 src/devices/bluetooth/Makefile
1038 src/devices/team/Makefile
1039 src/devices/wifi/Makefile
1040 src/devices/wifi/tests/Makefile
1041 src/devices/wwan/Makefile
1042 libnm-core/Makefile
1043 libnm-core/tests/Makefile
1044 libnm/libnm.pc
1045 libnm/Makefile
1046 libnm/tests/Makefile
1047 libnm-util/libnm-util.pc
1048 libnm-util/Makefile
1049 libnm-util/tests/Makefile
1050 libnm-glib/libnm-glib.pc
1051 libnm-glib/libnm-glib-vpn.pc
1052 libnm-glib/Makefile
1053 libnm-glib/tests/Makefile
1054 callouts/Makefile
1055 callouts/tests/Makefile
1056 tools/Makefile
1057 clients/Makefile
1058 clients/cli/Makefile
1059 clients/tui/Makefile
1060 clients/tui/newt/Makefile
1061 initscript/RedHat/NetworkManager
1062 initscript/Debian/NetworkManager
1063 initscript/Slackware/rc.networkmanager
1064 initscript/SUSE/networkmanager
1065 initscript/Arch/networkmanager
1066 initscript/Mandriva/networkmanager
1067 initscript/linexa/networkmanager
1068 introspection/Makefile
1069 introspection/all.xml
1070 man/Makefile
1071 man/NetworkManager.conf.xml
1072 man/nm-system-settings.conf.5
1073 man/nm-online.1
1074 man/nmcli.1
1075 man/nmtui.1
1076 po/Makefile.in
1077 policy/Makefile
1078 policy/org.freedesktop.NetworkManager.policy.in
1079 data/Makefile
1080 docs/Makefile
1081 docs/api/Makefile
1082 docs/api/version.xml
1083 docs/libnm-glib/Makefile
1084 docs/libnm-glib/version.xml
1085 docs/libnm-util/Makefile
1086 docs/libnm-util/version.xml
1087 docs/libnm/Makefile
1088 docs/libnm/version.xml
1089 NetworkManager.pc
1090 examples/Makefile
1091 examples/shell/Makefile
1092 examples/python/Makefile
1093 examples/python/dbus/Makefile
1094 examples/python/gi/Makefile
1095 examples/ruby/Makefile
1096 examples/lua/Makefile
1097 examples/lua/lgi/Makefile
1098 examples/C/Makefile
1099 examples/C/glib/Makefile
1100 examples/C/qt/Makefile
1101 examples/dispatcher/Makefile
1102 vapi/Makefile
1103 ])
1104 AC_CONFIG_SUBDIRS([libndp])
1105 AC_OUTPUT
1106
1107 # Print build configuration
1108 echo
1109 echo "System paths:"
1110 echo "  prefix: $prefix"
1111 echo "  exec_prefix: $exec_prefix"
1112 echo "  systemdunitdir: $with_systemdsystemunitdir"
1113 echo "  nmbinary: $nmbinary"
1114 echo "  nmconfdir: $nmconfdir"
1115 echo "  nmlibdir: $nmlibdir"
1116 echo "  nmdatadir: $nmdatadir"
1117 echo "  nmstatedir: $nmstatedir"
1118 echo "  nmrundir: $nmrundir"
1119 echo
1120
1121 echo "Platform:"
1122 echo "  session tracking: $session_tracking"
1123 echo "  suspend/resume: $with_suspend_resume"
1124 if test "${enable_polkit}" = "yes"; then
1125         if test "${enable_modify_system}" = "yes"; then
1126                 echo "  policykit: yes (permissive modify.system) (default: main.auth-polkit=${enable_polkit})"
1127         else
1128                 echo "  policykit: yes (restrictive modify.system) (default: main.auth-polkit=${enable_polkit})"
1129         fi
1130 else
1131         echo  "  policykit: no"
1132 fi
1133 echo "  polkit agent: ${enable_polkit_agent}"
1134 echo "  selinux: $have_selinux"
1135 echo "  systemd-journald: $have_systemd_journal (default: logging.backend=${nm_config_logging_backend_default})"
1136 echo "  hostname persist: ${hostname_persist}"
1137 echo "  libaudit: $have_libaudit (default: logging.audit=${NM_CONFIG_DEFAULT_LOGGING_AUDIT_TEXT})"
1138 echo
1139
1140 echo "Features:"
1141 echo "  wext: $ac_with_wext"
1142 echo "  wifi: $enable_wifi"
1143 echo "  ppp: $enable_ppp"
1144 echo "  modemmanager-1: $with_modem_manager_1"
1145 echo "  concheck: $enable_concheck"
1146 echo "  libteamdctl: $enable_teamdctl"
1147 echo "  libnm-glib: $with_libnm_glib"
1148 echo "  nmtui: $build_nmtui"
1149 echo
1150
1151 echo "Configuration plugins (main.plugins=${config_plugins_default})"
1152 echo "  ibft: ${enable_config_plugin_ibft}"
1153 echo "  ifcfg-rh: ${enable_ifcfg_rh}"
1154 echo "  ifupdown: ${enable_ifupdown}"
1155 echo "  ifnet: ${enable_ifnet}"
1156 echo
1157
1158 echo "Handlers for /etc/resolv.conf:"
1159 echo "  resolvconf: ${with_resolvconf}"
1160 echo "  netconfig: ${with_netconfig}"
1161 echo
1162
1163 echo "DHCP clients:"
1164 echo "  dhclient: $with_dhclient"
1165 echo "  dhcpcd: $with_dhcpcd"
1166 echo
1167
1168 echo "Miscellaneous:"
1169 echo "  documentation: $enable_gtk_doc"
1170 echo "  tests: $enable_tests"
1171 echo "  more-asserts: $more_asserts"
1172 echo "  valgrind: $with_valgrind   $with_valgrind_suppressions"
1173 echo "  code coverage: $enable_code_coverage"
1174 echo "  LTO: $enable_lto"
1175 echo