configure.ac

   1 AC_PREREQ([2.63])
   2
   3 dnl The NM version number
   4 m4_define([nm_major_version], [1])
   5 m4_define([nm_minor_version], [1])
   6 m4_define([nm_micro_version], [0])
   7 m4_define([nm_version],
   8           [nm_major_version.nm_minor_version.nm_micro_version])
   9 m4_define([nm_git_sha], [m4_esyscmd([ ( [ -d ./.git/ ] && [ "$(readlink -f ./.git/)" = "$(readlink -f "$(git rev-parse --git-dir 2>/dev/null)" 2>/dev/null)" ] && git rev-parse --verify -q HEAD 2>/dev/null ) || true ])])
  10
  11 AC_INIT([NetworkManager], [nm_version],
  12         [http://bugzilla.gnome.org/enter_bug.cgi?product=NetworkManager],
  13         [NetworkManager])
  14
  15 AC_CONFIG_HEADERS([config.h])
  16 AC_CONFIG_MACRO_DIR([m4])
  17 AC_CONFIG_AUX_DIR([build-aux])
  18 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  19
  20 AM_INIT_AUTOMAKE(1.12 tar-ustar no-dist-gzip dist-bzip2 -Wno-portability)  dnl NB: Do not [quote] this parameter.
  21 AM_MAINTAINER_MODE([enable])
  22 AM_SILENT_RULES([yes])
  23
  24 dnl Define _SYSTEM_EXTENSIONS for various things like strcasestr()
  25 AC_USE_SYSTEM_EXTENSIONS
  26
  27 dnl
  28 dnl Require programs
  29 dnl
  30 AC_PROG_CC
  31 AM_PROG_CC_C_O
  32
  33 # C++ only required if --enable-qt=yes
  34 AC_PROG_CXX
  35
  36 dnl Initialize libtool
  37 LT_PREREQ([2.2])
  38 LT_INIT([disable-static])
  39
  40 dnl Version stuff
  41 NM_MAJOR_VERSION=nm_major_version
  42 NM_MINOR_VERSION=nm_minor_version
  43 NM_MICRO_VERSION=nm_micro_version
  44 NM_VERSION=nm_version
  45 NM_GIT_SHA=nm_git_sha
  46 AC_SUBST(NM_MAJOR_VERSION)
  47 AC_SUBST(NM_MINOR_VERSION)
  48 AC_SUBST(NM_MICRO_VERSION)
  49 AC_SUBST(NM_VERSION)
  50 AC_DEFINE_UNQUOTED(NM_GIT_SHA,"$NM_GIT_SHA",[git commit id of the original source code version])
  51
  52 dnl
  53 dnl Checks for typedefs, structures, and compiler characteristics.
  54 dnl
  55 AC_TYPE_PID_T
  56
  57 dnl
  58 dnl translation support
  59 dnl
  60 IT_PROG_INTLTOOL([0.40.0])
  61
  62 AM_GNU_GETTEXT([external])
  63 AM_GNU_GETTEXT_VERSION([0.17])
  64
  65 GETTEXT_PACKAGE=NetworkManager
  66 AC_SUBST(GETTEXT_PACKAGE)
  67 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [Gettext package])
  68
  69 dnl
  70 dnl Make sha1.c happy on big endian systems
  71 dnl
  72 AC_C_BIGENDIAN
  73
  74 # Add runstatedir if not specified manually in autoconf < 2.70
  75 AS_IF([test -z "$runstatedir"], runstatedir="$localstatedir/run")
  76 AC_SUBST(runstatedir)
  77
  78 # NetworkManager paths
  79 AC_SUBST(nmbinary, "$sbindir/$PACKAGE", [NetworkManager binary executable])
  80 AC_SUBST(nmconfdir, "$sysconfdir/$PACKAGE", [NetworkManager configuration directory])
  81 AC_SUBST(nmlibdir, "$prefix/lib/$PACKAGE", [NetworkManager library directory])
  82 AC_SUBST(nmdatadir, "$datadir/$PACKAGE", [NetworkManager shared data directory])
  83 AC_SUBST(nmstatedir, "$localstatedir/lib/$PACKAGE", [NetworkManager persistent state directory])
  84 AC_SUBST(nmrundir, "$runstatedir/$PACKAGE", [NetworkManager runtime state directory])
  85
  86 # Alternative configuration plugins
  87 AC_ARG_ENABLE(config-plugin-ibft, AS_HELP_STRING([--enable-config-plugin-ibft], [enable ibft configuration plugin]))
  88 AC_ARG_ENABLE(ifcfg-rh, AS_HELP_STRING([--enable-ifcfg-rh], [enable ifcfg-rh configuration plugin (Fedora/RHEL)]))
  89 AC_ARG_ENABLE(ifcfg-suse, AS_HELP_STRING([--enable-ifcfg-suse], [enable ifcfg-suse configuration plugin (SUSE) (deprecated)]))
  90 AC_ARG_ENABLE(ifupdown, AS_HELP_STRING([--enable-ifupdown], [enable ifupdown configuration plugin (Debian/Ubuntu)]))
  91 AC_ARG_ENABLE(ifnet, AS_HELP_STRING([--enable-ifnet], [enable ifnet configuration plugin (Gentoo)]))
  92 # Default alternative plugins by distribution
  93 AS_IF([test -z "$enable_ifcfg_rh"], AC_CHECK_FILE(/etc/redhat-release, enable_ifcfg_rh=yes))
  94 AS_IF([test -z "$enable_ifcfg_rh"], AC_CHECK_FILE(/etc/fedora-release, enable_ifcfg_rh=yes))
  95 AS_IF([test -z "$enable_ifcfg_rh"], AC_CHECK_FILE(/etc/mandriva-release, enable_ifcfg_rh=yes))
  96 AS_IF([test -z "$enable_ifcfg_suse"], AC_CHECK_FILE(/etc/SuSE-release, enable_ifcfg_suse=yes))
  97 AS_IF([test -z "$enable_ifupdown"], AC_CHECK_FILE(/etc/debian_version, enable_ifupdown=yes))
  98 AS_IF([test -z "$enable_ifnet"], AC_CHECK_FILE(/etc/gentoo-release, enable_ifnet=yes))
  99 # Otherwise plugins default to "no"
 100 AS_IF([test -z "$enable_ifcfg_rh"], enable_ifcfg_rh=no)
 101 AS_IF([test -z "$enable_ifcfg_suse"], enable_ifcfg_suse=no)
 102 AS_IF([test -z "$enable_ifupdown"], enable_ifupdown=no)
 103 AS_IF([test -z "$enable_ifnet"], enable_ifnet=no)
 104 # Enable ibft by default
 105 AS_IF([test -z "$enable_config_plugin_ibft"], enable_config_plugin_ibft="yes")
 106 # Create automake conditionals
 107 AM_CONDITIONAL(CONFIG_PLUGIN_IBFT, test "$enable_config_plugin_ibft" = "yes")
 108 AM_CONDITIONAL(CONFIG_PLUGIN_IFCFG_RH, test "$enable_ifcfg_rh" = "yes")
 109 AM_CONDITIONAL(CONFIG_PLUGIN_IFUPDOWN, test "$enable_ifupdown" = "yes")
 110 AM_CONDITIONAL(CONFIG_PLUGIN_IFNET, test "$enable_ifnet" = "yes")
 111
 112 AC_ARG_WITH(config-plugins-default, AS_HELP_STRING([--with-config-plugins-default=PLUGINS], [Default configuration option for main.plugins setting, used as fallback if the configuration option is unset]), [config_plugins_default="$withval"], [config_plugins_default=""])
 113 if test -z "$config_plugins_default" -o "$config_plugins_default" = no; then
 114     config_plugins_default=''
 115     test "$enable_ifcfg_rh" = "yes"           && config_plugins_default="$config_plugins_default,ifcfg-rh"
 116     test "$enable_ifupdown" = "yes"           && config_plugins_default="$config_plugins_default,ifupdown"
 117     test "$enable_ifnet" = "yes"              && config_plugins_default="$config_plugins_default,ifnet"
 118     test "$enable_config_plugin_ibft" = "yes" && config_plugins_default="$config_plugins_default,ibft"
 119     config_plugins_default="${config_plugins_default#,}"
 120 fi
 121
 122 test "$enable_ifcfg_rh" = "yes"           && distro_plugins="$distro_plugins,ifcfg-rh"
 123 test "$enable_ifcfg_suse" = "yes"         && distro_plugins="$distro_plugins,ifcfg-suse"
 124 test "$enable_ifupdown" = "yes"           && distro_plugins="$distro_plugins,ifupdown"
 125 test "$enable_ifnet" = "yes"              && distro_plugins="$distro_plugins,ifnet"
 126 distro_plugins="${distro_plugins#,}"
 127
 128 AC_DEFINE_UNQUOTED(CONFIG_PLUGINS_DEFAULT, "$config_plugins_default", [Default configuration option for main.plugins setting])
 129 if test "${enable_config_plugin_ibft}" = yes; then
 130         AC_DEFINE(WITH_SETTINGS_PLUGIN_IBFT, 1, [Whether compilation of ibft setting plugin is enabled])
 131 else
 132         AC_DEFINE(WITH_SETTINGS_PLUGIN_IBFT, 0, [Whether compilation of ibft setting plugin is enabled])
 133 fi
 134
 135 if test "$enable_ifcfg_rh" = "yes"; then
 136     DISTRO_NETWORK_SERVICE=network.service
 137 fi
 138 AC_SUBST(DISTRO_NETWORK_SERVICE)
 139
 140 # Code coverage
 141 GNOME_CODE_COVERAGE
 142
 143 dnl
 144 dnl Distribution version string
 145 dnl
 146 AC_ARG_WITH(dist-version, AS_HELP_STRING([--with-dist-version=<NM-distribution-version>], [Define the NM''s distribution version string]), ac_distver=$withval, ac_distver="")
 147 if ! test x"$ac_distver" = x""; then
 148   AC_DEFINE_UNQUOTED(NM_DIST_VERSION, "$ac_distver", [Define the distribution version string])
 149 fi
 150
 151 AC_ARG_ENABLE(wifi, AS_HELP_STRING([--enable-wifi], [enable Wi-Fi support]))
 152 if test "${enable_wifi}" != "no"; then
 153         enable_wifi='yes'
 154         AC_DEFINE(WITH_WIFI, 1, [Define if you have Wi-Fi support])
 155 else
 156         AC_DEFINE(WITH_WIFI, 0, [Define if you have Wi-Fi support])
 157 fi
 158 AM_CONDITIONAL(WITH_WIFI, test "${enable_wifi}" = "yes")
 159
 160 dnl
 161 dnl Default to using WEXT but allow it to be disabled
 162 dnl
 163 AC_ARG_WITH(wext, AS_HELP_STRING([--with-wext=yes], [Enable or disable Linux Wireless Extensions]), ac_with_wext=$withval, ac_with_wext="$enable_wifi")
 164 if test "$ac_with_wext" != 'no'; then
 165         ac_with_wext='yes'
 166 fi
 167 if test x"$ac_with_wext" = x"yes"; then
 168         if test "$enable_wifi" != "yes"; then
 169                 AC_MSG_ERROR(Enabling WEXT support and disabling Wi-Fi makes no sense)
 170         fi
 171         AC_MSG_CHECKING([Linux kernel WEXT headers])
 172         AC_COMPILE_IFELSE(
 173                 [AC_LANG_PROGRAM(
 174                       [[#ifndef __user
 175                         #define __user
 176                         #endif
 177                         #include <sys/types.h>
 178                         #include <linux/types.h>
 179                         #include <sys/socket.h>
 180                         #include <linux/wireless.h>]],
 181                       [[#ifndef IWEVGENIE
 182                         #error "not found"
 183                         #endif]])],
 184                 [ac_have_iwevgenie=yes],
 185                 [ac_have_iwevgenie=no])
 186         AC_MSG_RESULT($ac_have_iwevgenie)
 187         if test "$ac_have_iwevgenie" = no; then
 188                AC_MSG_ERROR(Linux kernel development header linux/wireless.h not installed or not functional)
 189         fi
 190         AC_DEFINE(HAVE_WEXT, 1, [Define if you have Linux Wireless Extensions support])
 191 else
 192         AC_DEFINE(HAVE_WEXT, 0, [Define if you have Linux Wireless Extensions support])
 193 fi
 194 AM_CONDITIONAL(WITH_WEXT, test x"${ac_with_wext}" = x"yes")
 195
 196 AC_MSG_CHECKING([Linux kernel nl80211 headers])
 197 AC_COMPILE_IFELSE(
 198         [AC_LANG_PROGRAM(
 199               [[#ifndef __user
 200                 #define __user
 201                 #endif
 202                 #include <sys/types.h>
 203                 #include <linux/types.h>
 204                 #include <sys/socket.h>
 205                 #include <linux/nl80211.h>]],
 206               [[int a = NL80211_RATE_INFO_BITRATE; a++;]])],
 207         [ac_have_nl80211=yes],
 208         [ac_have_nl80211=no])
 209 AC_MSG_RESULT($ac_have_nl80211)
 210 if test "$ac_have_nl80211" = no; then
 211         AC_MSG_ERROR(Linux kernel development header linux/nl80211.h not installed or not functional)
 212 fi
 213
 214 if test "$with_wifi" = "yes"; then
 215         AC_MSG_CHECKING([Linux kernel nl80211 Critical Protocol Start/Stop])
 216         AC_COMPILE_IFELSE(
 217                 [AC_LANG_PROGRAM(
 218                   [[#ifndef __user
 219                     #define __user
 220                     #endif
 221                     #include <sys/types.h>
 222                     #include <linux/types.h>
 223                     #include <sys/socket.h>
 224                     #include <linux/nl80211.h>]],
 225                   [[unsigned int a = NL80211_CMD_CRIT_PROTOCOL_START; a++;]])],
 226                 [ac_have_nl80211_critproto=yes],
 227                 [ac_have_nl80211_critproto=no])
 228         AC_MSG_RESULT($ac_have_nl80211_critproto)
 229 else
 230         ac_have_nl80211_critproto='no'
 231 fi
 232 if test "$ac_have_nl80211_critproto" = yes; then
 233         AC_DEFINE(HAVE_NL80211_CRITICAL_PROTOCOL_CMDS, 1, [Define if nl80211 has critical protocol support])
 234 else
 235         AC_DEFINE(HAVE_NL80211_CRITICAL_PROTOCOL_CMDS, 0, [Define if nl80211 has critical protocol support])
 236 fi
 237
 238 dnl
 239 dnl Check for newer VLAN flags
 240 dnl
 241 AC_MSG_CHECKING([Linux kernel VLAN_FLAG_LOOSE_BINDING enum value])
 242 AC_COMPILE_IFELSE(
 243         [AC_LANG_PROGRAM(
 244               [[#ifndef __user
 245                 #define __user
 246                 #endif
 247                 #include <sys/types.h>
 248                 #include <linux/types.h>
 249                 #include <linux/if_vlan.h>]],
 250               [[unsigned int a = VLAN_FLAG_LOOSE_BINDING;]])],
 251         [ac_have_vlan_flag_loose_binding=yes],
 252         [ac_have_vlan_flag_loose_binding=no])
 253 AC_MSG_RESULT($ac_have_vlan_flag_loose_binding)
 254 if test "$ac_have_vlan_flag_loose_binding" = yes; then
 255         AC_DEFINE(HAVE_VLAN_FLAG_LOOSE_BINDING, 1, [Define if you have VLAN_FLAG_LOOSE_BINDING])
 256 else
 257         AC_DEFINE(HAVE_VLAN_FLAG_LOOSE_BINDING, 0, [Define if you have VLAN_FLAG_LOOSE_BINDING])
 258 fi
 259
 260 dnl
 261 dnl Checks for libm - needed for pow()
 262 dnl
 263 LT_LIB_M
 264
 265 dnl
 266 dnl Checks for libdl - on certain platforms its part of libc
 267 dnl
 268 AC_CHECK_LIB([dl], [dladdr], LIBDL="-ldl", LIBDL="")
 269 AC_SUBST(LIBDL)
 270
 271 dnl
 272 dnl Checks for dbus-glib
 273 dnl
 274 PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.1 dbus-glib-1 >= 0.94)
 275 AC_SUBST(DBUS_CFLAGS)
 276 AC_SUBST(DBUS_LIBS)
 277
 278 AC_CHECK_LIB([dbus-glib-1], [dbus_g_method_invocation_get_g_connection], ac_have_gmi_get_con="1", ac_have_gmi_get_con="0")
 279 AC_DEFINE_UNQUOTED(HAVE_DBUS_GLIB_GMI_GET_CONNECTION, $ac_have_gmi_get_con, [Define if you have a dbus-glib with dbus_g_method_invocation_get_g_connection()])
 280
 281 dnl
 282 dnl Only dbus-glib >= 0.100 can use private dbus connections
 283 dnl
 284 PKG_CHECK_MODULES(DBUS_GLIB_100, [dbus-glib-1 >= 0.100], [have_dbus_glib_100=yes],[have_dbus_glib_100=no])
 285 if (test "${have_dbus_glib_100}" = "yes"); then
 286         AC_DEFINE(HAVE_DBUS_GLIB_100, 1, [Define if you have dbus-glib >= 0.100])
 287 else
 288         AC_DEFINE(HAVE_DBUS_GLIB_100, 0, [Define if you have dbus-glib >= 0.100])
 289 fi
 290 AM_CONDITIONAL(HAVE_DBUS_GLIB_100, test "${have_dbus_glib_100}" = "yes")
 291
 292 PKG_CHECK_MODULES(GLIB, [gio-unix-2.0 >= 2.37.6 gmodule-2.0],
 293         [AC_SUBST(LOG_DRIVER, '$(top_srcdir)/build-aux/tap-driver.sh'),
 294          AC_SUBST(AM_TESTS_FD_REDIRECT, '--tap')],
 295         [PKG_CHECK_MODULES(GLIB, gio-unix-2.0 >= 2.32 gmodule-2.0)
 296          AC_SUBST(LOG_DRIVER, '$(top_srcdir)/build-aux/test-driver')])
 297
 298 dnl GLIB_VERSION_MIN_REQUIRED should match the version above.
 299 dnl GLIB_VERSION_MAX_ALLOWED should be set to the same version;
 300 dnl nm-glib-compat.h will cause it to be overridden for the functions
 301 dnl we have compat versions of.
 302 GLIB_CFLAGS="$GLIB_CFLAGS -DGLIB_VERSION_MIN_REQUIRED=GLIB_VERSION_2_32 -DGLIB_VERSION_MAX_ALLOWED=GLIB_VERSION_2_32"
 303
 304 AC_SUBST(GLIB_CFLAGS)
 305 AC_SUBST(GLIB_LIBS)
 306
 307 PKG_CHECK_MODULES(GUDEV, gudev-1.0 >= 165)
 308 AC_SUBST(GUDEV_CFLAGS)
 309 AC_SUBST(GUDEV_LIBS)
 310
 311 GOBJECT_INTROSPECTION_CHECK([0.9.6])
 312
 313 # Qt4
 314 PKG_CHECK_MODULES(QT, [QtCore >= 4 QtDBus QtNetwork], [have_qt=yes],[have_qt=no])
 315 AC_ARG_ENABLE(qt, AS_HELP_STRING([--enable-qt], [enable Qt examples]),
 316                      [enable_qt=${enableval}], [enable_qt=${have_qt}])
 317 if (test "${enable_qt}" = "yes"); then
 318         if test x"$have_qt" = x"no"; then
 319                 AC_MSG_ERROR(Qt development headers are required)
 320         fi
 321         AC_SUBST(QT_CFLAGS)
 322         AC_SUBST(QT_LIBS)
 323         # Check for moc-qt4 and if not found then moc
 324         QT4_BINDIR=`$PKG_CONFIG QtCore --variable moc_location`
 325         AC_CHECK_PROGS(MOC, [moc-qt4 moc],, [$QT4_BINDIR:$PATH])
 326 fi
 327 AM_CONDITIONAL(WITH_QT, test "${enable_qt}" = "yes")
 328
 329 AC_ARG_WITH(udev-dir, AS_HELP_STRING([--with-udev-dir=DIR], [Absolute path of the udev base directory. Set to 'no' not to install the udev rules]), [], [with_udev_dir="yes"])
 330 if (test "$with_udev_dir" != 'no'); then
 331         if (test "$with_udev_dir" != 'yes' && printf '%s' "$with_udev_dir" | grep -v -q '^/'); then
 332                 AC_MSG_ERROR([--with-udev-dir must be an absolute path or 'yes' or 'no'. Instead it is '$with_udev_dir'])
 333         fi
 334         if (test "$with_udev_dir" = 'yes'); then
 335                 with_udev_dir="/lib/udev"
 336         fi
 337         UDEV_DIR="$with_udev_dir"
 338         AC_SUBST(UDEV_DIR)
 339 fi
 340 AM_CONDITIONAL(WITH_UDEV_DIR, test "$with_udev_dir" != 'no')
 341
 342 # systemd unit support
 343 AC_ARG_WITH([systemdsystemunitdir], AS_HELP_STRING([--with-systemdsystemunitdir=DIR],
 344         [Directory for systemd service files]))
 345 # default location
 346 AS_IF([test -z "$with_systemdsystemunitdir" && $PKG_CONFIG systemd],
 347         with_systemdsystemunitdir="\$(prefix)/lib/systemd/system")
 348 AS_IF([test -z "$with_systemdsystemunitdir"], with_systemdsystemunitdir=no)
 349 # add conditional and subst
 350 AM_CONDITIONAL(HAVE_SYSTEMD, [test "$with_systemdsystemunitdir" != no])
 351 if test "$with_systemdsystemunitdir" != no; then
 352         AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
 353         AC_DEFINE(HAVE_SYSTEMD, 1, [Define if systemd support is available])
 354 else
 355         AC_DEFINE(HAVE_SYSTEMD, 0, [Define if systemd support is available])
 356 fi
 357
 358 PKG_CHECK_MODULES(SYSTEMD_200, [systemd >= 200], [have_systemd_200=yes],[have_systemd_200=no])
 359 AM_CONDITIONAL(HAVE_SYSTEMD_200, test "${have_systemd_200}" = "yes")
 360
 361 # Hostname persist mode
 362 AC_ARG_WITH(hostname-persist, AS_HELP_STRING([--with-hostname-persist=default|suse|gentoo],
 363         [Hostname persist method]))
 364
 365 AS_IF([test "$with_hostname_persist" = "suse"], hostname_persist=suse)
 366 AS_IF([test "$with_hostname_persist" = "gentoo"], hostname_persist=gentoo)
 367 AS_IF([test "$with_hostname_persist" = "default"], hostname_persist=default)
 368 # if the method was not explicitly set, try to guess it from the enabled plugins
 369 AS_IF([test -z "$hostname_persist" -a "$distro_plugins" = "ifcfg-suse"], hostname_persist=suse)
 370 AS_IF([test -z "$hostname_persist" -a "$distro_plugins" = "ifnet"], hostname_persist=gentoo)
 371 AS_IF([test -z "$hostname_persist"], hostname_persist=default)
 372
 373 if test "$hostname_persist" = suse; then
 374         AC_DEFINE(HOSTNAME_PERSIST_SUSE, 1, [Enable SuSE hostname persist method])
 375 elif test "$hostname_persist" = gentoo; then
 376         AC_DEFINE(HOSTNAME_PERSIST_GENTOO, 1, [Enable Gentoo hostname persist method])
 377 fi
 378
 379 AC_ARG_WITH(systemd-journal, AS_HELP_STRING([--with-systemd-journal=yes|no], [Use systemd journal for logging]))
 380 have_systemd_journal=no
 381 if test "$with_systemd_journal" != "no"; then
 382         PKG_CHECK_MODULES(SYSTEMD_JOURNAL,
 383                           [libsystemd >= 209],
 384                           [have_systemd_journal=yes],
 385                           [PKG_CHECK_MODULES(SYSTEMD_JOURNAL,
 386                                              [libsystemd-journal],
 387                                              [have_systemd_journal=yes],
 388                                              [have_systemd_journal=no])])
 389         if test "$have_systemd_journal" != "yes"; then
 390                 if test "$with_systemd_journal" = "yes"; then
 391                         AC_MSG_ERROR([Missing systemd-journald support])
 392                 fi
 393         fi
 394 fi
 395 if test "$have_systemd_journal" = "yes"; then
 396         AC_SUBST(SYSTEMD_JOURNAL_CFLAGS)
 397         AC_SUBST(SYSTEMD_JOURNAL_LIBS)
 398         AC_DEFINE([SYSTEMD_JOURNAL], 1, [Define to 1 if libsystemd-journald is available])
 399 else
 400         AC_DEFINE([SYSTEMD_JOURNAL], 0, [Define to 1 if libsystemd-journald is available])
 401 fi
 402
 403 # Session tracking support
 404 AC_ARG_WITH(systemd-logind, AS_HELP_STRING([--with-systemd-logind=yes|no],
 405         [Support systemd session tracking]))
 406 AC_ARG_WITH(consolekit, AS_HELP_STRING([--with-consolekit=yes|no],
 407         [Support consolekit session tracking]))
 408 AC_ARG_WITH(session-tracking, AS_HELP_STRING([--with-session-tracking=systemd|consolekit|no],
 409         [Compatibility option to choose one session tracking module]))
 410 # backwards compatibility
 411 AS_IF([test "$with_session_tracking" = "ck"], [use_consolekit="yes" use_systemd_logind="no"])
 412 AS_IF([test "$with_session_tracking" = "consolekit"], [use_consolekit="yes" use_systemd_logind="no"])
 413 AS_IF([test "$with_session_tracking" = "systemd"], [use_consolekit="no" use_systemd_logind="yes"])
 414 AS_IF([test "$with_session_tracking" = "no"], [use_consolekit="no" use_systemd_logind="no"])
 415 AS_IF([test "$with_session_tracking" = "none"], [use_consolekit="no" use_systemd_logind="no"])
 416 # current options
 417 AS_IF([test -n "$with_systemd_logind" ], [use_systemd_logind="$with_systemd_logind"])
 418 AS_IF([test -n "$with_consolekit" ], [use_consolekit="$with_consolekit"])
 419 # defaults
 420 AS_IF([test -z "$use_systemd_logind"], [use_systemd_logind="auto"])
 421 AS_IF([test -z "$use_consolekit"], [use_consolekit="yes"])
 422 # output
 423 session_tracking=
 424 if test "$use_systemd_logind" = "yes" -o "$use_systemd_logind" = "auto"; then
 425     PKG_CHECK_MODULES(SYSTEMD_LOGIN, [libsystemd], [have_systemd_logind=yes], [PKG_CHECK_MODULES(SYSTEMD_LOGIN, [libsystemd-login], [have_systemd_logind=yes], [have_systemd_logind=no])])
 426 else
 427     have_systemd_logind=no
 428 fi
 429 if test "$use_systemd_logind" = "yes" -a "$have_systemd_logind" = "no"; then
 430     AC_MSG_ERROR([You must have libsystemd installed to build with systemd-logind support.])
 431 fi
 432 if test "$have_systemd_logind" = "yes"; then
 433         AC_SUBST(SYSTEMD_LOGIN_CFLAGS)
 434         AC_SUBST(SYSTEMD_LOGIN_LIBS)
 435         AC_DEFINE([SESSION_TRACKING_SYSTEMD], 1, [Define to 1 if libsystemd-login is available])
 436         session_tracking="$session_tracking, systemd-logind"
 437 fi
 438 if test "$use_consolekit" = "yes"; then
 439         AC_DEFINE([SESSION_TRACKING_CONSOLEKIT], 1, [Define to 1 if ConsoleKit is available])
 440         AC_DEFINE([CKDB_PATH], "/var/run/ConsoleKit/database", [Path to ConsoleKit database])
 441         session_tracking="$session_tracking, consolekit"
 442 fi
 443 session_tracking="$(printf '%s' "${session_tracking}" | sed 's/^, //')"
 444
 445 AC_ARG_WITH(suspend-resume, AS_HELP_STRING([--with-suspend-resume=upower|systemd], [Build NetworkManager with specific suspend/resume support]))
 446 if test "z$with_suspend_resume" = "z"; then
 447     PKG_CHECK_EXISTS([libsystemd >= 209], [have_systemd_inhibit=yes],
 448                      [PKG_CHECK_EXISTS([libsystemd-login >= 183], [have_systemd_inhibit=yes], [have_systemd_inhibit=no])])
 449     if test "z${have_systemd_inhibit}" = "zyes"; then
 450         # Use systemd if it's new enough
 451         with_suspend_resume="systemd"
 452     else
 453         # Fall back to upower
 454         with_suspend_resume="upower"
 455     fi
 456 fi
 457
 458 case $with_suspend_resume in
 459     upower) ;;
 460     systemd)
 461         PKG_CHECK_MODULES(SYSTEMD_INHIBIT, [libsystemd >= 209],,
 462                           [PKG_CHECK_MODULES(SYSTEMD_INHIBIT, [libsystemd-login >= 183])])
 463         ;;
 464     *)
 465         AC_MSG_ERROR(--with-suspend-resume must be one of [upower, systemd])
 466         ;;
 467 esac
 468 AM_CONDITIONAL(SUSPEND_RESUME_UPOWER, test "x$with_suspend_resume" = "xupower")
 469 AM_CONDITIONAL(SUSPEND_RESUME_SYSTEMD, test "x$with_suspend_resume" = "xsystemd")
 470
 471 # SELinux support
 472 AC_ARG_WITH(selinux, AS_HELP_STRING([--with-selinux=yes|no|auto], [Build with SELinux (default: auto)]),,[with_selinux=auto])
 473 if test "$with_selinux" = "yes" -o "$with_selinux" = "auto"; then
 474     PKG_CHECK_MODULES(SELINUX, libselinux, [have_selinux=yes], [have_selinux=no])
 475 else
 476     have_selinux=no
 477 fi
 478 if test "$with_selinux" = "yes" -a "$have_selinux" = "no"; then
 479     AC_MSG_ERROR([You must have libselinux installed to build --with-selinux=yes.])
 480 fi
 481 if test "$have_selinux" = "yes"; then
 482     AC_DEFINE(HAVE_SELINUX, 1, [Define if you have SELinux support])
 483 else
 484     AC_DEFINE(HAVE_SELINUX, 0, [Define if you have SELinux support])
 485 fi
 486 AM_CONDITIONAL(HAVE_SELINUX, test "${have_selinux}" = "yes")
 487
 488 # libnl support for the linux platform
 489 PKG_CHECK_MODULES(LIBNL, libnl-3.0 >= 3.2.8 libnl-route-3.0 libnl-genl-3.0)
 490 AC_SUBST(LIBNL_CFLAGS)
 491 AC_SUBST(LIBNL_LIBS)
 492
 493 AC_CHECK_LIB([nl-route-3], [rtnl_link_inet6_get_addr_gen_mode],
 494         ac_have_addr_gen_mode="1",
 495         ac_have_addr_gen_mode="0")
 496 AC_DEFINE_UNQUOTED(HAVE_LIBNL_INET6_ADDR_GEN_MODE,
 497         $ac_have_addr_gen_mode, [Define if libnl has rtnl_link_inet6_get_addr_gen_mode()])
 498
 499 AC_MSG_CHECKING([Linux kernel IN6_ADDR_GEN_MODE enum])
 500 AC_COMPILE_IFELSE(
 501         [AC_LANG_PROGRAM(
 502               [[#ifndef __user
 503                 #define __user
 504                 #endif
 505                 #include <linux/if_link.h>]],
 506               [[int a = IN6_ADDR_GEN_MODE_EUI64; a++;]])],
 507         [ac_have_kernel_gen_mode=yes],
 508         [ac_have_kernel_gen_mode=no])
 509 AC_MSG_RESULT($ac_have_kernel_gen_mode)
 510 if test "$ac_have_kernel_gen_mode" = yes; then
 511         AC_DEFINE(HAVE_KERNEL_INET6_ADDR_GEN_MODE, 1, [Define if the kernel has IN6_ADDR_GEN_MODE_*])
 512 else
 513         AC_DEFINE(HAVE_KERNEL_INET6_ADDR_GEN_MODE, 0, [Define if the kernel has IN6_ADDR_GEN_MODE_*])
 514 fi
 515
 516 # IPv6 tokenized identifiers support in libnl
 517 AC_CHECK_LIB([nl-route-3], [rtnl_link_inet6_get_token],
 518         ac_have_ipv6_token="1",
 519         ac_have_ipv6_token="0")
 520 AC_DEFINE_UNQUOTED(HAVE_LIBNL_INET6_TOKEN,
 521         $ac_have_ipv6_token, [Define if libnl has rtnl_link_inet6_get_token()])
 522
 523 # uuid library
 524 PKG_CHECK_MODULES(UUID, uuid)
 525 AC_SUBST(UUID_CFLAGS)
 526 AC_SUBST(UUID_LIBS)
 527
 528 dnl Checks for readline library - used by nmcli
 529 AX_LIB_READLINE
 530
 531 # Teamd control checks
 532 PKG_CHECK_MODULES(LIBTEAMDCTL, [libteamdctl >= 1.9], [have_teamdctl=yes],[have_teamdctl=no])
 533 AC_ARG_ENABLE(teamdctl, AS_HELP_STRING([--enable-teamdctl], [enable Teamd control support]),
 534                      [enable_teamdctl=${enableval}], [enable_teamdctl=${have_teamdctl}])
 535 if (test "${enable_teamdctl}" = "yes"); then
 536         if test x"$have_teamdctl" = x"no"; then
 537                 AC_MSG_ERROR(Teamd control is required)
 538         fi
 539
 540         AC_SUBST(LIBTEAMDCTL_CFLAGS)
 541         AC_SUBST(LIBTEAMDCTL_LIBS)
 542         # temporary bug workaround
 543         LIBTEAMDCTL_CFLAGS=`echo $LIBTEAMDCTL_CFLAGS | sed -e 's:/teamdctl.h::'`
 544         AC_DEFINE(WITH_TEAMDCTL, 1, [Define if you have Teamd control support])
 545 else
 546         AC_DEFINE(WITH_TEAMDCTL, 0, [Define if you have Teamd control support])
 547 fi
 548 AM_CONDITIONAL(WITH_TEAMDCTL, test "${enable_teamdctl}" = "yes")
 549
 550 # we usually compile with polkit support. --enable-polkit=yes|no only sets the
 551 # default configuration for main.auth-polkit. User can always enable/disable polkit
 552 # autorization via config. Only when specifying --enable-polkit=disabled, we do
 553 # not compile support. In this case, the user cannot enable polkit authorization via
 554 # configuration.
 555 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--enable-polkit=yes|no|disabled], [set default value for auth-polkit configuration option. This value can be overwritten by NM configuration. 'disabled' compiles NM without any support]),
 556                      [enable_polkit=${enableval}], [enable_polkit=yes])
 557 if (test "${enable_polkit}" != "no" -a "${enable_polkit}" != "disabled"); then
 558         enable_polkit=yes
 559         AC_DEFINE(NM_CONFIG_DEFAULT_AUTH_POLKIT, TRUE, [The default value of the auth-polkit configuration option])
 560         NM_CONFIG_DEFAULT_AUTH_POLKIT_TEXT='true'
 561 else
 562         AC_DEFINE(NM_CONFIG_DEFAULT_AUTH_POLKIT, FALSE, [The default value of the auth-polkit configuration option])
 563         NM_CONFIG_DEFAULT_AUTH_POLKIT_TEXT='false'
 564 fi
 565 if (test "${enable_polkit}" != "disabled"); then
 566         AC_DEFINE(WITH_POLKIT, 1, [whether to compile polkit support])
 567 else
 568         AC_DEFINE(WITH_POLKIT, 0, [whether to compile polkit support])
 569 fi
 570 AC_SUBST(NM_CONFIG_DEFAULT_AUTH_POLKIT_TEXT)
 571
 572 PKG_CHECK_MODULES(POLKIT, [polkit-agent-1 >= 0.97], [have_pk_agent=yes],[have_pk_agent=no])
 573 AC_ARG_ENABLE(polkit-agent, AS_HELP_STRING([--enable-polkit-agent], [enable polkit agent for clients]),
 574                      [enable_polkit_agent=${enableval}], [enable_polkit_agent=${have_pk_agent}])
 575 if (test "${enable_polkit_agent}" = "yes"); then
 576         if test x"$have_pk_agent" = x"no"; then
 577                 AC_MSG_ERROR(Polkit agent is required)
 578         fi
 579
 580         AC_SUBST(POLKIT_CFLAGS)
 581         AC_SUBST(POLKIT_LIBS)
 582         AC_DEFINE(WITH_POLKIT_AGENT, 1, [Define if you have polkit agent])
 583 else
 584         AC_DEFINE(WITH_POLKIT_AGENT, 0, [Define if you have polkit agent])
 585 fi
 586 AM_CONDITIONAL(WITH_POLKIT_AGENT, test "${enable_polkit_agent}" = "yes")
 587
 588 AC_ARG_ENABLE(modify-system,
 589               AS_HELP_STRING([--enable-modify-system], [Allow users to modify system connections]))
 590 if test "${enable_modify_system}" = "yes"; then
 591         NM_MODIFY_SYSTEM_POLICY="yes"
 592 else
 593         NM_MODIFY_SYSTEM_POLICY="auth_admin_keep"
 594 fi
 595 AC_SUBST(NM_MODIFY_SYSTEM_POLICY)
 596
 597 AC_ARG_WITH(crypto, AS_HELP_STRING([--with-crypto=nss|gnutls], [Cryptography library to use for certificate and key operations]),ac_crypto=$withval, ac_crypto=nss)
 598
 599 with_nss=no
 600 with_gnutls=no
 601 if test x"$ac_crypto" = xnss; then
 602   PKG_CHECK_MODULES(NSS, [nss >= 3.11])
 603
 604   # Work around a pkg-config bug (fdo #29801) where exists != usable
 605   FOO=`$PKG_CONFIG --cflags --libs nss`
 606   if test x"$?" != "x0"; then
 607     AC_MSG_ERROR([No usable NSS found])
 608   fi
 609
 610   AC_SUBST(NSS_CFLAGS)
 611   AC_SUBST(NSS_LIBS)
 612   AC_DEFINE(HAVE_NSS, 1, [Define if you have NSS])
 613   with_nss=yes
 614 elif test x"$ac_crypto" = xgnutls; then
 615   PKG_CHECK_MODULES(GNUTLS, [gnutls >= 2.12])
 616   AC_DEFINE(HAVE_GNUTLS, 1, [Define if you have libgnutls])
 617   AC_SUBST(GNUTLS_CFLAGS)
 618   AC_SUBST(GNUTLS_LIBS)
 619   with_gnutls=yes
 620 else
 621   AC_MSG_ERROR([Please choose either 'nss' or 'gnutls' for certificate and crypto operations])
 622 fi
 623 AM_CONDITIONAL(WITH_NSS, test x"$with_nss" != xno)
 624 AM_CONDITIONAL(WITH_GNUTLS, test x"$with_gnutls" != xno)
 625
 626 # Shouldn't ever trigger this, but just in case...
 627 if test x"$ac_nss" = xno -a x"$ac_gnutls" = xno; then
 628   AC_MSG_ERROR([Could not find required development headers and libraries for '$ac_crypto'])
 629 fi
 630
 631 GLIB_MAKEFILE='$(top_srcdir)/Makefile.glib'
 632 AC_SUBST(GLIB_MAKEFILE)
 633 GLIB_GENMARSHAL=`pkg-config --variable=glib_genmarshal glib-2.0`
 634 AC_SUBST(GLIB_GENMARSHAL)
 635 GLIB_MKENUMS=`pkg-config --variable=glib_mkenums glib-2.0`
 636 AC_SUBST(GLIB_MKENUMS)
 637
 638 AC_ARG_WITH(dbus-sys-dir, AS_HELP_STRING([--with-dbus-sys-dir=DIR], [where D-BUS system.d directory is]))
 639
 640 if test -n "$with_dbus_sys_dir" ; then
 641     DBUS_SYS_DIR="$with_dbus_sys_dir"
 642 else
 643     DBUS_SYS_DIR="${sysconfdir}/dbus-1/system.d"
 644 fi
 645 AC_SUBST(DBUS_SYS_DIR)
 646
 647 # pppd
 648 AC_ARG_ENABLE(ppp, AS_HELP_STRING([--enable-ppp], [enable PPP/PPPoE support]),
 649                      [enable_ppp=${enableval}], [enable_ppp=yes])
 650 if (test "${enable_ppp}" = "yes"); then
 651         AC_CHECK_HEADERS(pppd/pppd.h,,
 652                 AC_MSG_ERROR("couldn't find pppd.h. pppd development headers are required."))
 653
 654         AC_DEFINE(WITH_PPP, 1, [Define if you have PPP support])
 655 else
 656         AC_DEFINE(WITH_PPP, 0, [Define if you have PPP support])
 657 fi
 658 AM_CONDITIONAL(WITH_PPP, test "${enable_ppp}" = "yes")
 659
 660 AC_ARG_WITH([pppd-plugin-dir], AS_HELP_STRING([--with-pppd-plugin-dir=DIR], [path to the pppd plugins directory]))
 661
 662 if test -n "$with_pppd_plugin_dir" ; then
 663         PPPD_PLUGIN_DIR="$with_pppd_plugin_dir"
 664 else
 665         PPPD_PLUGIN_DIR="${libdir}/pppd/2.4.5"
 666 fi
 667 AC_SUBST(PPPD_PLUGIN_DIR)
 668
 669 AC_ARG_WITH(pppd, AS_HELP_STRING([--with-pppd=/path/to/pppd], [path to pppd binary]))
 670 if test "x${with_pppd}" = x; then
 671   AC_PATH_PROG(PPPD_PATH, pppd, [], $PATH:/sbin:/usr/sbin)
 672 else
 673   PPPD_PATH="$with_pppd"
 674 fi
 675 AC_DEFINE_UNQUOTED(PPPD_PATH, "$PPPD_PATH", [Define to path of pppd binary])
 676 AC_SUBST(PPPD_PATH)
 677
 678 # ModemManager1 with libmm-glib
 679 AC_ARG_WITH(modem-manager-1, AS_HELP_STRING([--with-modem-manager-1], [Enable new ModemManager1 interface support]),,[with_modem_manager_1=auto])
 680 if (test "${with_modem_manager_1}" != "no"); then
 681     PKG_CHECK_MODULES(MM_GLIB,
 682                       [mm-glib >= 0.7.991],
 683                       [have_libmm_glib=yes],
 684                       [have_libmm_glib=no])
 685     AC_SUBST(MM_GLIB_CFLAGS)
 686     AC_SUBST(MM_GLIB_LIBS)
 687
 688     if (test "${have_libmm_glib}" = "no"); then
 689         if (test "${with_modem_manager_1}" = "yes"); then
 690             AC_MSG_ERROR([Couldn't find libmm-glib])
 691         else
 692             with_modem_manager_1="no"
 693         fi
 694     else
 695         with_modem_manager_1="yes"
 696     fi
 697 fi
 698
 699 if (test "${with_modem_manager_1}" = "yes"); then
 700     AC_DEFINE(WITH_MODEM_MANAGER_1, 1, [Define if you have ModemManager1 support])
 701 else
 702         AC_DEFINE(WITH_MODEM_MANAGER_1, 0, [Define if you have ModemManager1 support])
 703 fi
 704 AM_CONDITIONAL(WITH_MODEM_MANAGER_1, test "${with_modem_manager_1}" = "yes")
 705
 706 # Bluez5 DUN support
 707 PKG_CHECK_MODULES(BLUEZ5, [bluez >= 5], [have_bluez5=yes],[have_bluez5=no])
 708 AC_ARG_ENABLE(bluez5-dun, AS_HELP_STRING([--enable-bluez5-dun], [enable Bluez5 DUN support]),
 709                 [enable_bluez5_dun=${enableval}], [enable_bluez5_dun=${have_bluez5}])
 710 if (test "${enable_bluez5_dun}" = "yes"); then
 711         if test x"$have_bluez5" = x"no"; then
 712                 AC_MSG_ERROR(Bluez 5.x development headers are required)
 713         fi
 714         AC_DEFINE(WITH_BLUEZ5_DUN, 1, [Define if you have Bluez 5 libraries])
 715 else
 716         AC_DEFINE(WITH_BLUEZ5_DUN, 0, [Define if you have Bluez 5 libraries])
 717 fi
 718 AM_CONDITIONAL(WITH_BLUEZ5_DUN, test "${enable_bluez5_dun}" = "yes")
 719
 720 # DHCP client support
 721 AC_ARG_WITH([dhclient], AS_HELP_STRING([--with-dhclient=yes|no|path], [Enable dhclient 4.x support]))
 722 AC_ARG_WITH([dhcpcd], AS_HELP_STRING([--with-dhcpcd=yes|no|path], [Enable dhcpcd 4.x support]))
 723 # Default to "yes"
 724 AS_IF([test -z "$with_dhclient"], with_dhclient=yes)
 725 AS_IF([test -z "$with_dhcpcd"], with_dhcpcd=yes)
 726 # Search and check the executables
 727 if test "$with_dhclient" = "yes"; then
 728         AC_PATH_PROGS(with_dhclient, dhclient, no, /sbin:/usr/sbin:/usr/local/sbin)
 729         if test "$with_dhclient" != "no"; then
 730                 if ! $with_dhclient --version 2>&1 | grep -q "^isc-dhclient-4\."; then
 731                         AC_MSG_WARN([Cannot use dhclient, version 4.x is required])
 732                         with_dhclient=no
 733                 fi
 734         fi
 735 fi
 736 if test "$with_dhcpcd" = "yes"; then
 737         AC_PATH_PROGS(with_dhcpcd, dhcpcd, no, /sbin:/usr/sbin:/usr/local/sbin)
 738         if test "$with_dhcpcd" != "no"; then
 739                 if ! $with_dhcpcd --version 2>&1 | grep -q "^dhcpcd [[456789]]\."; then
 740                         AC_MSG_WARN([Cannot use dhcpcd, version 4.x or higher is required])
 741                         with_dhcpcd=no
 742                 elif $with_dhcpcd --version 2>&1 | grep -q "^dhcpcd [[6789]]\."; then
 743                         AC_DEFINE(DHCPCD_SUPPORTS_IPV6, 1, [Define if dhcpcd supports IPv6 (6.x+)])
 744                 fi
 745         fi
 746 fi
 747 # Fallback
 748 if test "$with_dhclient" = "no" -a "$with_dhcpcd" = "no"; then
 749         AC_MSG_WARN([Could not find a suitable DHCP client, falling back to dhclient])
 750         with_dhclient=/sbin/dhclient
 751 fi
 752 # Add substitutions
 753 if test "$with_dhclient" != "no"; then
 754         AC_DEFINE(WITH_DHCLIENT, TRUE, [Define if you have dhclient])
 755         AC_SUBST(DHCLIENT_PATH, $with_dhclient)
 756 else
 757         AC_DEFINE(WITH_DHCLIENT, FALSE, [Define if you have dhclient])
 758 fi
 759 if test "$with_dhcpcd" != "no"; then
 760         AC_DEFINE(WITH_DHCPCD, TRUE, [Define if you have dhcpcd])
 761         AC_SUBST(DHCPCD_PATH, $with_dhcpcd)
 762 else
 763         AC_DEFINE(WITH_DHCPCD, FALSE, [Define if you have dhcpcd])
 764 fi
 765
 766 # resolvconf and netconfig support
 767 AC_ARG_WITH(resolvconf, AS_HELP_STRING([--with-resolvconf=yes|no|path], [Enable resolvconf support]))
 768 AC_ARG_WITH(netconfig, AS_HELP_STRING([--with-netconfig=yes|no], [Enable SUSE netconfig support]))
 769 # Use netconfig by default on SUSE
 770 AS_IF([test -z "$with_netconfig"], AC_CHECK_FILE(/etc/SuSE-release, with_netconfig=yes))
 771 # Otherwise default to "no"
 772 AS_IF([test -z "$with_resolvconf"], with_resolvconf=no)
 773 AS_IF([test -z "$with_netconfig"], with_netconfig=no)
 774 # Find resolvconf and netconfig
 775 if test "$with_resolvconf" = "yes"; then
 776         AC_PATH_PROGS(with_resolvconf, resolvconf, no, /sbin:/usr/sbin:/usr/local/sbin)
 777 fi
 778 if test "$with_netconfig" = "yes"; then
 779         AC_PATH_PROGS(with_netconfig, netconfig, no, /sbin:/usr/sbin:/usr/local/sbin)
 780 fi
 781 # Define resolvconf and netconfig paths
 782 if test "$with_resolvconf" != "no"; then
 783         AC_DEFINE_UNQUOTED(RESOLVCONF_PATH, "$with_resolvconf", [Path to resolvconf])
 784 fi
 785 if test "$with_netconfig" != "no"; then
 786         AC_DEFINE_UNQUOTED(NETCONFIG_PATH, "$with_netconfig", [Path to netconfig])
 787 fi
 788
 789 # iptables path
 790 AC_ARG_WITH(iptables, AS_HELP_STRING([--with-iptables=/path/to/iptables], [path to iptables]))
 791 if test "x${with_iptables}" = x; then
 792   AC_PATH_PROG(IPTABLES_PATH, iptables, [], $PATH:/sbin:/usr/sbin)
 793   if ! test -x "$IPTABLES_PATH"; then
 794         AC_MSG_ERROR(iptables was not installed.)
 795   fi
 796 else
 797   IPTABLES_PATH="$with_iptables"
 798 fi
 799 AC_DEFINE_UNQUOTED(IPTABLES_PATH, "$IPTABLES_PATH", [Define to path of iptables binary])
 800 AC_SUBST(IPTABLES_PATH)
 801
 802 # dnsmasq path
 803 AC_ARG_WITH(dnsmasq, AS_HELP_STRING([--with-dnsmasq=/path/to/dnsmasq], [path to dnsmasq]))
 804 if test "x${with_dnsmasq}" = x; then
 805   AC_PATH_PROG(DNSMASQ_PATH, dnsmasq, [], $PATH:/sbin:/usr/sbin)
 806 else
 807   DNSMASQ_PATH="$with_dnsmasq"
 808 fi
 809 AC_DEFINE_UNQUOTED(DNSMASQ_PATH, "$DNSMASQ_PATH", [Define to path of dnsmasq binary])
 810 AC_SUBST(DNSMASQ_PATH)
 811
 812 # system CA certificates path
 813 AC_ARG_WITH(system-ca-path, AS_HELP_STRING([--with-system-ca-path=/path/to/ssl/certs], [path to system CA certificates]))
 814 if test "x${with_system_ca_path}" = x; then
 815   SYSTEM_CA_PATH=/etc/ssl/certs
 816 else
 817   SYSTEM_CA_PATH="$with_system_ca_path"
 818 fi
 819 AC_DEFINE_UNQUOTED(SYSTEM_CA_PATH, "$SYSTEM_CA_PATH", [Define to path to system CA certificates])
 820 AC_SUBST(SYSTEM_CA_PATH)
 821
 822 AC_ARG_WITH(kernel-firmware-dir, AS_HELP_STRING([--with-kernel-firmware-dir=DIR], [where kernel firmware directory is (default is /lib/firmware)]))
 823
 824 if test -n "$with_kernel_firmware_dir" ; then
 825     KERNEL_FIRMWARE_DIR="$with_kernel_firmware_dir"
 826 else
 827     KERNEL_FIRMWARE_DIR="/lib/firmware"
 828 fi
 829 AC_DEFINE_UNQUOTED(KERNEL_FIRMWARE_DIR, "$KERNEL_FIRMWARE_DIR", [Define to path of the kernel firmware directory])
 830 AC_SUBST(KERNEL_FIRMWARE_DIR)
 831
 832 PKG_CHECK_MODULES(LIBSOUP, [libsoup-2.4 >= 2.26], [have_libsoup=yes],[have_libsoup=no])
 833 AC_ARG_WITH(libsoup, AS_HELP_STRING([--with-libsoup=yes|no], [Link against libsoup]), [], [with_libsoup=${have_libsoup}])
 834 if test "$with_libsoup" != "no"; then
 835         if test "$have_libsoup" != "yes"; then
 836                 AC_MSG_ERROR(libsoup library not found)
 837         fi
 838         with_libsoup='yes'
 839         AC_DEFINE(WITH_LIBSOUP, 1, [Define if you have libsoup])
 840 else
 841         AC_DEFINE(WITH_LIBSOUP, 0, [Define if you have libsoup])
 842 fi
 843 AM_CONDITIONAL(WITH_LIBSOUP, test "$with_libsoup" != "no")
 844
 845 AC_ARG_ENABLE(concheck, AS_HELP_STRING([--enable-concheck], [enable connectivity checking support]),
 846                      [enable_concheck=${enableval}], [enable_concheck=${with_libsoup}])
 847 if (test "${enable_concheck}" = "yes"); then
 848         if test x"$with_libsoup" = x"no"; then
 849                 AC_MSG_ERROR(Connectivity checking requires libsoup)
 850         fi
 851         AC_SUBST(LIBSOUP_CFLAGS)
 852         AC_SUBST(LIBSOUP_LIBS)
 853         AC_DEFINE(WITH_CONCHECK, 1, [Define if you want connectivity checking support])
 854 else
 855         AC_DEFINE(WITH_CONCHECK, 0, [Define if you want connectivity checking support])
 856 fi
 857 AM_CONDITIONAL(WITH_CONCHECK, test "${enable_concheck}" = "yes")
 858
 859 PKG_CHECK_MODULES(LIBNDP, [libndp])
 860
 861 AC_ARG_WITH(nmtui, AS_HELP_STRING([--with-nmtui=yes|no], [Build nmtui]))
 862 if test "$with_nmtui" != no; then
 863     PKG_CHECK_MODULES(NEWT, [libnewt >= 0.52.15], [build_nmtui=yes], [build_nmtui=no])
 864 else
 865     build_nmtui=no
 866 fi
 867 if test "$with_nmtui" = yes -a "$build_nmtui" = no; then
 868     AC_MSG_ERROR([You must have libnewt installed to build nmtui.])
 869 fi
 870 AM_CONDITIONAL(BUILD_NMTUI, test "$build_nmtui" = yes)
 871
 872
 873 NM_COMPILER_WARNINGS
 874
 875 AC_ARG_ENABLE(more-asserts,
 876               AS_HELP_STRING([--enable-more-asserts], [Enable more assertions for debugging (default: no)]))
 877 if test "${enable_more_asserts}" = "yes"; then
 878     AC_DEFINE(NM_MORE_ASSERTS, [1], [Define if more asserts are enabled])
 879 fi
 880
 881 AC_ARG_ENABLE(more-logging,
 882               AS_HELP_STRING([--enable-more-logging], [Enable more debug logging (default: no)]))
 883 if test "${enable_more_logging}" = "yes"; then
 884     AC_DEFINE(NM_MORE_LOGGING, [1], [Define if more asserts are enabled])
 885 fi
 886
 887 AC_ARG_ENABLE(lto, AS_HELP_STRING([--enable-lto], [Enable Link Time Optimization for smaller size (default: no)]))
 888 if (test "${enable_lto}" = "yes"); then
 889     CFLAGS="-flto $CFLAGS"
 890 else
 891     enable_lto='no'
 892 fi
 893
 894
 895 dnl -------------------------
 896 dnl Vala bindings
 897 dnl -------------------------
 898
 899 VAPIGEN_CHECK(0.17.1.24)
 900
 901 # Tests, utilities and documentation
 902 AC_ARG_ENABLE(tests, AS_HELP_STRING([--enable-tests=root|yes|no], [Build NetworkManager tests (default: yes)]))
 903 AC_ARG_WITH(valgrind, AS_HELP_STRING([--with-valgrind=yes|no|path], [Use valgrind to memory-check the tests (default: no)]))
 904 # Fallback to --with-tests
 905 AC_ARG_WITH(tests, AS_HELP_STRING([--with-tests], [Build NetworkManager tests (deprecated)]))
 906 AS_IF([test -n "$with_tests"], enable_tests="$with_tests")
 907 # Default to --enable-tests --with-valgrind=no
 908 AS_IF([test -z "$enable_tests"], enable_tests="yes")
 909 AS_IF([test -z "$with_valgrind"], with_valgrind="no")
 910 # Normalize values
 911 AS_IF([test "$enable_tests" != "yes" -a "$enable_tests" != "root"], enable_tests="no")
 912 # Search for tools
 913 AS_IF([test "$with_valgrind" == "yes"],
 914         [AC_PATH_PROGS(with_valgrind, valgrind, no)])
 915 # Add conditionals and substitutions
 916 AM_CONDITIONAL(ENABLE_TESTS, test "$enable_tests" != "no")
 917 AM_CONDITIONAL(REQUIRE_ROOT_TESTS, test "$enable_tests" == "root")
 918 AC_ARG_WITH(valgrind-suppressions, AS_HELP_STRING([--with-valgrind-suppressions=path], [Use specific valgrind suppression file]))
 919 if test "$with_valgrind" == no; then
 920         with_valgrind_suppressions=
 921 else
 922         if test  "$with_valgrind_suppressions" == ""; then
 923                 with_valgrind_suppressions='$(top_srcdir)/valgrind.suppressions'
 924         fi
 925 fi
 926 AS_IF([test "$with_valgrind" != "no"],
 927         AC_SUBST(VALGRIND_RULES, 'LOG_COMPILER = "$(top_srcdir)/tools/run-test-valgrind.sh" "$(LIBTOOL)" "$(with_valgrind)" '"$with_valgrind_suppressions"),
 928         AC_SUBST(VALGRIND_RULES, []))
 929 AM_CONDITIONAL(WITH_VALGRIND, test "${with_valgrind}" != "no")
 930
 931 GTK_DOC_CHECK(1.0)
 932
 933 # check for pregenerated manpages to be installed
 934 install_pregen_manpages=no
 935 if test "$enable_gtk_doc" != "yes" \
 936         -a -f man/NetworkManager.conf.5 \
 937         -a -f man/nm-settings.5 \
 938         -a -f man/nm-settings-keyfile.5 \
 939         -a -f man/nm-settings-ifcfg-rh.5 \
 940         -a -f man/nmcli-examples.5 \
 941         -a -f man/NetworkManager.8; then
 942         install_pregen_manpages=yes
 943 fi
 944 AM_CONDITIONAL(INSTALL_PREGEN_MANPAGES, test "x${install_pregen_manpages}" = "xyes")
 945
 946 # check if we can build setting property documentation
 947 if test -n "$INTROSPECTION_MAKEFILE" -a "$enable_gtk_doc" = "yes"; then
 948     # If g-i is installed we know we have python, but we might not have pygobject
 949     if python -c 'from gi.repository import GObject' >& /dev/null; then
 950         have_pyobject=yes
 951     fi
 952
 953     # gtk-doc depends on perl, but we can check for it anyway
 954     AC_PATH_PROG(PERL, perl, no)
 955     # check for needed perl modules (use YAML; YAML::XS is better, but may not be so widespread)
 956     required_perl_modules="YAML"
 957     for module in $required_perl_modules; do
 958       AC_MSG_CHECKING([checking for perl module '$module'])
 959       if ${PERL} -e 'use '$module 2>/dev/null ; then
 960           AC_MSG_RESULT([Ok])
 961           have_perl_modules=yes
 962       else
 963           AC_MSG_RESULT([Failed])
 964           AC_MSG_ERROR([You must have Perl modules to build settings plugin docs: $required_perl_modules.])
 965       fi
 966     done
 967
 968     if test "$have_pyobject" = "yes" -a "$have_perl_modules" = "yes"; then
 969         AC_DEFINE(BUILD_SETTING_DOCS, [1], [Define if you we can build nm-setting-docs.xml, nm-keyfile-docs.xml and nm-ifcfg-rh-docs.xml])
 970         build_setting_docs=yes
 971     fi
 972 fi
 973
 974 # check for pre-built setting docs
 975 if test "$build_setting_docs" != "yes" \
 976         -a -f man/nm-settings.xml \
 977         -a -f man/nm-settings-keyfile.xml \
 978         -a -f man/nm-settings-ifcfg-rh.xml \
 979         -a -f docs/api/settings-spec.xml \
 980         -a -f clients/cli/settings-docs.c; then
 981     AC_DEFINE(HAVE_SETTING_DOCS, [1], [Define if you have pre-built settings docs])
 982     have_setting_docs=yes
 983 fi
 984
 985 AM_CONDITIONAL(BUILD_SETTING_DOCS, test "$build_setting_docs" = "yes")
 986 AM_CONDITIONAL(SETTING_DOCS_AVAILABLE, test "$build_setting_docs" = "yes" -o "$have_setting_docs" = "yes")
 987
 988
 989 AC_CONFIG_FILES([
 990 Makefile
 991 include/Makefile
 992 src/Makefile
 993 src/tests/Makefile
 994 src/tests/config/Makefile
 995 src/dhcp-manager/Makefile
 996 src/dhcp-manager/tests/Makefile
 997 src/dnsmasq-manager/tests/Makefile
 998 src/supplicant-manager/tests/Makefile
 999 src/ppp-manager/Makefile
1000 src/settings/plugins/Makefile
1001 src/settings/plugins/ifupdown/Makefile
1002 src/settings/plugins/ifupdown/tests/Makefile
1003 src/settings/plugins/ifnet/Makefile
1004 src/settings/plugins/ifnet/tests/Makefile
1005 src/settings/plugins/ifcfg-rh/Makefile
1006 src/settings/plugins/ifcfg-rh/tests/Makefile
1007 src/settings/plugins/ifcfg-rh/tests/network-scripts/Makefile
1008 src/settings/plugins/ibft/Makefile
1009 src/settings/plugins/ibft/tests/Makefile
1010 src/settings/plugins/keyfile/Makefile
1011 src/settings/plugins/keyfile/tests/Makefile
1012 src/settings/plugins/keyfile/tests/keyfiles/Makefile
1013 src/platform/Makefile
1014 src/platform/tests/Makefile
1015 src/rdisc/Makefile
1016 src/rdisc/tests/Makefile
1017 src/devices/adsl/Makefile
1018 src/devices/bluetooth/Makefile
1019 src/devices/team/Makefile
1020 src/devices/wifi/Makefile
1021 src/devices/wifi/tests/Makefile
1022 src/devices/wwan/Makefile
1023 libnm-core/nm-version.h
1024 libnm-core/Makefile
1025 libnm-core/tests/Makefile
1026 libnm/libnm.pc
1027 libnm/Makefile
1028 libnm/tests/Makefile
1029 libnm-util/libnm-util.pc
1030 libnm-util/nm-version.h
1031 libnm-util/Makefile
1032 libnm-util/tests/Makefile
1033 libnm-glib/libnm-glib.pc
1034 libnm-glib/libnm-glib-vpn.pc
1035 libnm-glib/Makefile
1036 libnm-glib/tests/Makefile
1037 callouts/Makefile
1038 callouts/tests/Makefile
1039 tools/Makefile
1040 clients/Makefile
1041 clients/cli/Makefile
1042 clients/tui/Makefile
1043 clients/tui/newt/Makefile
1044 initscript/RedHat/NetworkManager
1045 initscript/Debian/NetworkManager
1046 initscript/Slackware/rc.networkmanager
1047 initscript/SUSE/networkmanager
1048 initscript/Arch/networkmanager
1049 initscript/Mandriva/networkmanager
1050 initscript/linexa/networkmanager
1051 introspection/Makefile
1052 introspection/all.xml
1053 man/Makefile
1054 man/NetworkManager.conf.xml
1055 man/nm-system-settings.conf.5
1056 man/nm-online.1
1057 man/nmcli.1
1058 man/nmtui.1
1059 po/Makefile.in
1060 policy/Makefile
1061 policy/org.freedesktop.NetworkManager.policy.in
1062 data/Makefile
1063 docs/Makefile
1064 docs/api/Makefile
1065 docs/api/version.xml
1066 docs/libnm-glib/Makefile
1067 docs/libnm-glib/version.xml
1068 docs/libnm-util/Makefile
1069 docs/libnm-util/version.xml
1070 docs/libnm/Makefile
1071 docs/libnm/version.xml
1072 NetworkManager.pc
1073 examples/Makefile
1074 examples/shell/Makefile
1075 examples/python/Makefile
1076 examples/python/dbus/Makefile
1077 examples/python/gi/Makefile
1078 examples/ruby/Makefile
1079 examples/lua/Makefile
1080 examples/lua/lgi/Makefile
1081 examples/C/Makefile
1082 examples/C/glib/Makefile
1083 examples/C/qt/Makefile
1084 examples/dispatcher/Makefile
1085 vapi/Makefile
1086 ])
1087 AC_CONFIG_SUBDIRS([libndp])
1088 AC_OUTPUT
1089
1090 # Print build configuration
1091 echo
1092 echo "System paths:"
1093 echo "  prefix: $prefix"
1094 echo "  exec_prefix: $exec_prefix"
1095 echo "  systemdunitdir: $with_systemdsystemunitdir"
1096 echo "  nmbinary: $nmbinary"
1097 echo "  nmconfdir: $nmconfdir"
1098 echo "  nmlibdir: $nmlibdir"
1099 echo "  nmdatadir: $nmdatadir"
1100 echo "  nmstatedir: $nmstatedir"
1101 echo "  nmrundir: $nmrundir"
1102 echo
1103
1104 echo "Platform:"
1105 echo "  session tracking: $session_tracking"
1106 echo "  suspend/resume: $with_suspend_resume"
1107 if test "${enable_polkit}" = "yes"; then
1108         if test "${enable_modify_system}" = "yes"; then
1109                 echo "  policykit: yes (permissive modify.system) (default=${enable_polkit})"
1110         else
1111                 echo "  policykit: yes (restrictive modify.system) (default=${enable_polkit})"
1112         fi
1113 else
1114         echo  "  policykit: no"
1115 fi
1116 echo "  polkit agent: ${enable_polkit_agent}"
1117 echo "  selinux: $have_selinux"
1118 echo "  systemd-journald: $have_systemd_journal"
1119 echo "  hostname persist: ${hostname_persist}"
1120 echo
1121
1122 echo "Features:"
1123 echo "  wext: $ac_with_wext"
1124 echo "  wifi: $enable_wifi"
1125 echo "  ppp: $enable_ppp"
1126 echo "  modemmanager-1: $with_modem_manager_1"
1127 echo "  concheck: $enable_concheck"
1128 echo "  libteamdctl: $enable_teamdctl"
1129 echo "  nmtui: $build_nmtui"
1130 echo
1131
1132 echo "Configuration plugins (main.plugins=${config_plugins_default})"
1133 echo "  ibft: ${enable_config_plugin_ibft}"
1134 echo "  ifcfg-rh: ${enable_ifcfg_rh}"
1135 echo "  ifupdown: ${enable_ifupdown}"
1136 echo "  ifnet: ${enable_ifnet}"
1137 echo
1138
1139 echo "Handlers for /etc/resolv.conf:"
1140 echo "  resolvconf: ${with_resolvconf}"
1141 echo "  netconfig: ${with_netconfig}"
1142 echo
1143
1144 echo "DHCP clients:"
1145 echo "  dhclient: $with_dhclient"
1146 echo "  dhcpcd: $with_dhcpcd"
1147 echo
1148
1149 echo "Miscellaneous:"
1150 echo "  documentation: $enable_gtk_doc"
1151 echo "  tests: $enable_tests"
1152 echo "  valgrind: $with_valgrind   $with_valgrind_suppressions"
1153 echo "  code coverage: $enable_code_coverage"
1154 echo "  LTO: $enable_lto"
1155 echo