configure.ac

   1 AC_PREREQ([2.63])
   2
   3 dnl The NM version number
   4 m4_define([nm_major_version], [1])
   5 m4_define([nm_minor_version], [1])
   6 m4_define([nm_micro_version], [0])
   7 m4_define([nm_version],
   8           [nm_major_version.nm_minor_version.nm_micro_version])
   9 m4_define([nm_git_sha], [m4_esyscmd([ ( [ -d ./.git/ ] && [ "$(readlink -f ./.git/)" = "$(readlink -f "$(git rev-parse --git-dir 2>/dev/null)" 2>/dev/null)" ] && git rev-parse --verify -q HEAD 2>/dev/null ) || true ])])
  10
  11 AC_INIT([NetworkManager], [nm_version],
  12         [http://bugzilla.gnome.org/enter_bug.cgi?product=NetworkManager],
  13         [NetworkManager])
  14
  15 AC_CONFIG_HEADERS([config.h])
  16 AC_CONFIG_MACRO_DIR([m4])
  17 AC_CONFIG_AUX_DIR([build-aux])
  18 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  19
  20 AM_INIT_AUTOMAKE(1.12 tar-ustar no-dist-gzip dist-bzip2 -Wno-portability)  dnl NB: Do not [quote] this parameter.
  21 AM_MAINTAINER_MODE([enable])
  22 AM_SILENT_RULES([yes])
  23
  24 dnl Define _SYSTEM_EXTENSIONS for various things like strcasestr()
  25 AC_USE_SYSTEM_EXTENSIONS
  26
  27 dnl
  28 dnl Require programs
  29 dnl
  30 AC_PROG_CC
  31 AM_PROG_CC_C_O
  32
  33 # C++ only required if --enable-qt=yes
  34 AC_PROG_CXX
  35
  36 dnl Initialize libtool
  37 LT_PREREQ([2.2])
  38 LT_INIT([disable-static])
  39
  40 dnl Version stuff
  41 NM_MAJOR_VERSION=nm_major_version
  42 NM_MINOR_VERSION=nm_minor_version
  43 NM_MICRO_VERSION=nm_micro_version
  44 NM_VERSION=nm_version
  45 NM_GIT_SHA=nm_git_sha
  46 AC_SUBST(NM_MAJOR_VERSION)
  47 AC_SUBST(NM_MINOR_VERSION)
  48 AC_SUBST(NM_MICRO_VERSION)
  49 AC_SUBST(NM_VERSION)
  50 AC_DEFINE_UNQUOTED(NM_GIT_SHA,"$NM_GIT_SHA",[git commit id of the original source code version])
  51
  52 dnl
  53 dnl Checks for typedefs, structures, and compiler characteristics.
  54 dnl
  55 AC_TYPE_PID_T
  56
  57 dnl
  58 dnl translation support
  59 dnl
  60 IT_PROG_INTLTOOL([0.40.0])
  61
  62 AM_GNU_GETTEXT([external])
  63 AM_GNU_GETTEXT_VERSION([0.17])
  64
  65 GETTEXT_PACKAGE=NetworkManager
  66 AC_SUBST(GETTEXT_PACKAGE)
  67 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [Gettext package])
  68
  69 dnl
  70 dnl Make sha1.c happy on big endian systems
  71 dnl
  72 AC_C_BIGENDIAN
  73
  74 # Add runstatedir if not specified manually in autoconf < 2.70
  75 AS_IF([test -z "$runstatedir"], runstatedir="$localstatedir/run")
  76 AC_SUBST(runstatedir)
  77
  78 # NetworkManager paths
  79 AC_SUBST(nmbinary, "$sbindir/$PACKAGE", [NetworkManager binary executable])
  80 AC_SUBST(nmconfdir, "$sysconfdir/$PACKAGE", [NetworkManager configuration directory])
  81 AC_SUBST(nmlibdir, "$prefix/lib/$PACKAGE", [NetworkManager library directory])
  82 AC_SUBST(nmdatadir, "$datadir/$PACKAGE", [NetworkManager shared data directory])
  83 AC_SUBST(nmstatedir, "$localstatedir/lib/$PACKAGE", [NetworkManager persistent state directory])
  84 AC_SUBST(nmrundir, "$runstatedir/$PACKAGE", [NetworkManager runtime state directory])
  85
  86 # Alternative configuration plugins
  87 AC_ARG_ENABLE(config-plugin-ibft, AS_HELP_STRING([--enable-config-plugin-ibft], [enable ibft configuration plugin]))
  88 AC_ARG_ENABLE(ifcfg-rh, AS_HELP_STRING([--enable-ifcfg-rh], [enable ifcfg-rh configuration plugin (Fedora/RHEL)]))
  89 AC_ARG_ENABLE(ifcfg-suse, AS_HELP_STRING([--enable-ifcfg-suse], [enable ifcfg-suse configuration plugin (SUSE) (deprecated)]))
  90 AC_ARG_ENABLE(ifupdown, AS_HELP_STRING([--enable-ifupdown], [enable ifupdown configuration plugin (Debian/Ubuntu)]))
  91 AC_ARG_ENABLE(ifnet, AS_HELP_STRING([--enable-ifnet], [enable ifnet configuration plugin (Gentoo)]))
  92 # Default alternative plugins by distribution
  93 AS_IF([test -z "$enable_ifcfg_rh"], AC_CHECK_FILE(/etc/redhat-release, enable_ifcfg_rh=yes))
  94 AS_IF([test -z "$enable_ifcfg_rh"], AC_CHECK_FILE(/etc/fedora-release, enable_ifcfg_rh=yes))
  95 AS_IF([test -z "$enable_ifcfg_rh"], AC_CHECK_FILE(/etc/mandriva-release, enable_ifcfg_rh=yes))
  96 AS_IF([test -z "$enable_ifcfg_suse"], AC_CHECK_FILE(/etc/SuSE-release, enable_ifcfg_suse=yes))
  97 AS_IF([test -z "$enable_ifupdown"], AC_CHECK_FILE(/etc/debian_version, enable_ifupdown=yes))
  98 AS_IF([test -z "$enable_ifnet"], AC_CHECK_FILE(/etc/gentoo-release, enable_ifnet=yes))
  99 # Otherwise plugins default to "no"
 100 AS_IF([test -z "$enable_ifcfg_rh"], enable_ifcfg_rh=no)
 101 AS_IF([test -z "$enable_ifcfg_suse"], enable_ifcfg_suse=no)
 102 AS_IF([test -z "$enable_ifupdown"], enable_ifupdown=no)
 103 AS_IF([test -z "$enable_ifnet"], enable_ifnet=no)
 104 # Enable ibft by default
 105 AS_IF([test -z "$enable_config_plugin_ibft"], enable_config_plugin_ibft="yes")
 106 # Create automake conditionals
 107 AM_CONDITIONAL(CONFIG_PLUGIN_IBFT, test "$enable_config_plugin_ibft" = "yes")
 108 AM_CONDITIONAL(CONFIG_PLUGIN_IFCFG_RH, test "$enable_ifcfg_rh" = "yes")
 109 AM_CONDITIONAL(CONFIG_PLUGIN_IFUPDOWN, test "$enable_ifupdown" = "yes")
 110 AM_CONDITIONAL(CONFIG_PLUGIN_IFNET, test "$enable_ifnet" = "yes")
 111
 112 AC_ARG_WITH(config-plugins-default, AS_HELP_STRING([--with-config-plugins-default=PLUGINS], [Default configuration option for main.plugins setting, used as fallback if the configuration option is unset]), [config_plugins_default="$withval"], [config_plugins_default=""])
 113 if test -z "$config_plugins_default" -o "$config_plugins_default" = no; then
 114     config_plugins_default=''
 115     test "$enable_ifcfg_rh" = "yes"           && config_plugins_default="$config_plugins_default,ifcfg-rh"
 116     test "$enable_ifupdown" = "yes"           && config_plugins_default="$config_plugins_default,ifupdown"
 117     test "$enable_ifnet" = "yes"              && config_plugins_default="$config_plugins_default,ifnet"
 118     test "$enable_config_plugin_ibft" = "yes" && config_plugins_default="$config_plugins_default,ibft"
 119     config_plugins_default="${config_plugins_default#,}"
 120 fi
 121
 122 test "$enable_ifcfg_rh" = "yes"           && distro_plugins="$distro_plugins,ifcfg-rh"
 123 test "$enable_ifcfg_suse" = "yes"         && distro_plugins="$distro_plugins,ifcfg-suse"
 124 test "$enable_ifupdown" = "yes"           && distro_plugins="$distro_plugins,ifupdown"
 125 test "$enable_ifnet" = "yes"              && distro_plugins="$distro_plugins,ifnet"
 126 distro_plugins="${distro_plugins#,}"
 127
 128 AC_DEFINE_UNQUOTED(CONFIG_PLUGINS_DEFAULT, "$config_plugins_default", [Default configuration option for main.plugins setting])
 129 if test "${enable_config_plugin_ibft}" = yes; then
 130         AC_DEFINE(WITH_SETTINGS_PLUGIN_IBFT, 1, [Whether compilation of ibft setting plugin is enabled])
 131 else
 132         AC_DEFINE(WITH_SETTINGS_PLUGIN_IBFT, 0, [Whether compilation of ibft setting plugin is enabled])
 133 fi
 134
 135 if test "$enable_ifcfg_rh" = "yes"; then
 136     DISTRO_NETWORK_SERVICE=network.service
 137 fi
 138 AC_SUBST(DISTRO_NETWORK_SERVICE)
 139
 140 # Code coverage
 141 GNOME_CODE_COVERAGE
 142
 143 dnl
 144 dnl Distribution version string
 145 dnl
 146 AC_ARG_WITH(dist-version, AS_HELP_STRING([--with-dist-version=<NM-distribution-version>], [Define the NM''s distribution version string]), ac_distver=$withval, ac_distver="")
 147 if ! test x"$ac_distver" = x""; then
 148   AC_DEFINE_UNQUOTED(NM_DIST_VERSION, "$ac_distver", [Define the distribution version string])
 149 fi
 150
 151 AC_ARG_ENABLE(wifi, AS_HELP_STRING([--enable-wifi], [enable Wi-Fi support]))
 152 if test "${enable_wifi}" != "no"; then
 153         enable_wifi='yes'
 154         AC_DEFINE(WITH_WIFI, 1, [Define if you have Wi-Fi support])
 155 else
 156         AC_DEFINE(WITH_WIFI, 0, [Define if you have Wi-Fi support])
 157 fi
 158 AM_CONDITIONAL(WITH_WIFI, test "${enable_wifi}" = "yes")
 159
 160 dnl
 161 dnl Default to using WEXT but allow it to be disabled
 162 dnl
 163 AC_ARG_WITH(wext, AS_HELP_STRING([--with-wext=yes], [Enable or disable Linux Wireless Extensions]), ac_with_wext=$withval, ac_with_wext="$enable_wifi")
 164 if test "$ac_with_wext" != 'no'; then
 165         ac_with_wext='yes'
 166 fi
 167 if test x"$ac_with_wext" = x"yes"; then
 168         if test "$enable_wifi" != "yes"; then
 169                 AC_MSG_ERROR(Enabling WEXT support and disabling Wi-Fi makes no sense)
 170         fi
 171         AC_MSG_CHECKING([Linux kernel WEXT headers])
 172         AC_COMPILE_IFELSE(
 173                 [AC_LANG_PROGRAM(
 174                       [[#ifndef __user
 175                         #define __user
 176                         #endif
 177                         #include <sys/types.h>
 178                         #include <linux/types.h>
 179                         #include <sys/socket.h>
 180                         #include <linux/wireless.h>]],
 181                       [[#ifndef IWEVGENIE
 182                         #error "not found"
 183                         #endif]])],
 184                 [ac_have_iwevgenie=yes],
 185                 [ac_have_iwevgenie=no])
 186         AC_MSG_RESULT($ac_have_iwevgenie)
 187         if test "$ac_have_iwevgenie" = no; then
 188                AC_MSG_ERROR(Linux kernel development header linux/wireless.h not installed or not functional)
 189         fi
 190         AC_DEFINE(HAVE_WEXT, 1, [Define if you have Linux Wireless Extensions support])
 191 else
 192         AC_DEFINE(HAVE_WEXT, 0, [Define if you have Linux Wireless Extensions support])
 193 fi
 194 AM_CONDITIONAL(WITH_WEXT, test x"${ac_with_wext}" = x"yes")
 195
 196 AC_MSG_CHECKING([Linux kernel nl80211 headers])
 197 AC_COMPILE_IFELSE(
 198         [AC_LANG_PROGRAM(
 199               [[#ifndef __user
 200                 #define __user
 201                 #endif
 202                 #include <sys/types.h>
 203                 #include <linux/types.h>
 204                 #include <sys/socket.h>
 205                 #include <linux/nl80211.h>]],
 206               [[int a = NL80211_RATE_INFO_BITRATE; a++;]])],
 207         [ac_have_nl80211=yes],
 208         [ac_have_nl80211=no])
 209 AC_MSG_RESULT($ac_have_nl80211)
 210 if test "$ac_have_nl80211" = no; then
 211         AC_MSG_ERROR(Linux kernel development header linux/nl80211.h not installed or not functional)
 212 fi
 213
 214 if test "$with_wifi" = "yes"; then
 215         AC_MSG_CHECKING([Linux kernel nl80211 Critical Protocol Start/Stop])
 216         AC_COMPILE_IFELSE(
 217                 [AC_LANG_PROGRAM(
 218                   [[#ifndef __user
 219                     #define __user
 220                     #endif
 221                     #include <sys/types.h>
 222                     #include <linux/types.h>
 223                     #include <sys/socket.h>
 224                     #include <linux/nl80211.h>]],
 225                   [[unsigned int a = NL80211_CMD_CRIT_PROTOCOL_START; a++;]])],
 226                 [ac_have_nl80211_critproto=yes],
 227                 [ac_have_nl80211_critproto=no])
 228         AC_MSG_RESULT($ac_have_nl80211_critproto)
 229 else
 230         ac_have_nl80211_critproto='no'
 231 fi
 232 if test "$ac_have_nl80211_critproto" = yes; then
 233         AC_DEFINE(HAVE_NL80211_CRITICAL_PROTOCOL_CMDS, 1, [Define if nl80211 has critical protocol support])
 234 else
 235         AC_DEFINE(HAVE_NL80211_CRITICAL_PROTOCOL_CMDS, 0, [Define if nl80211 has critical protocol support])
 236 fi
 237
 238 dnl
 239 dnl Check for newer VLAN flags
 240 dnl
 241 AC_MSG_CHECKING([Linux kernel VLAN_FLAG_LOOSE_BINDING enum value])
 242 AC_COMPILE_IFELSE(
 243         [AC_LANG_PROGRAM(
 244               [[#ifndef __user
 245                 #define __user
 246                 #endif
 247                 #include <sys/types.h>
 248                 #include <linux/types.h>
 249                 #include <linux/if_vlan.h>]],
 250               [[unsigned int a = VLAN_FLAG_LOOSE_BINDING;]])],
 251         [ac_have_vlan_flag_loose_binding=yes],
 252         [ac_have_vlan_flag_loose_binding=no])
 253 AC_MSG_RESULT($ac_have_vlan_flag_loose_binding)
 254 if test "$ac_have_vlan_flag_loose_binding" = yes; then
 255         AC_DEFINE(HAVE_VLAN_FLAG_LOOSE_BINDING, 1, [Define if you have VLAN_FLAG_LOOSE_BINDING])
 256 else
 257         AC_DEFINE(HAVE_VLAN_FLAG_LOOSE_BINDING, 0, [Define if you have VLAN_FLAG_LOOSE_BINDING])
 258 fi
 259
 260 dnl
 261 dnl Checks for libm - needed for pow()
 262 dnl
 263 LT_LIB_M
 264
 265 dnl
 266 dnl Checks for libdl - on certain platforms its part of libc
 267 dnl
 268 AC_CHECK_LIB([dl], [dladdr], LIBDL="-ldl", LIBDL="")
 269 AC_SUBST(LIBDL)
 270
 271 dnl
 272 dnl Checks for dbus-glib
 273 dnl
 274 PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.1 dbus-glib-1 >= 0.94)
 275
 276 AC_CHECK_LIB([dbus-glib-1], [dbus_g_method_invocation_get_g_connection], ac_have_gmi_get_con="1", ac_have_gmi_get_con="0")
 277 AC_DEFINE_UNQUOTED(HAVE_DBUS_GLIB_GMI_GET_CONNECTION, $ac_have_gmi_get_con, [Define if you have a dbus-glib with dbus_g_method_invocation_get_g_connection()])
 278
 279 dnl
 280 dnl Only dbus-glib >= 0.100 can use private dbus connections
 281 dnl
 282 PKG_CHECK_MODULES(DBUS_GLIB_100, [dbus-glib-1 >= 0.100], [have_dbus_glib_100=yes],[have_dbus_glib_100=no])
 283 if (test "${have_dbus_glib_100}" = "yes"); then
 284         AC_DEFINE(HAVE_DBUS_GLIB_100, 1, [Define if you have dbus-glib >= 0.100])
 285 else
 286         AC_DEFINE(HAVE_DBUS_GLIB_100, 0, [Define if you have dbus-glib >= 0.100])
 287 fi
 288 AM_CONDITIONAL(HAVE_DBUS_GLIB_100, test "${have_dbus_glib_100}" = "yes")
 289
 290 PKG_CHECK_MODULES(GLIB, [gio-unix-2.0 >= 2.37.6 gmodule-2.0],
 291         [AC_SUBST(LOG_DRIVER, '$(top_srcdir)/build-aux/tap-driver.sh'),
 292          AC_SUBST(AM_TESTS_FD_REDIRECT, '--tap')],
 293         [PKG_CHECK_MODULES(GLIB, gio-unix-2.0 >= 2.32 gmodule-2.0)
 294          AC_SUBST(LOG_DRIVER, '$(top_srcdir)/build-aux/test-driver')])
 295
 296 dnl GLIB_VERSION_MIN_REQUIRED should match the version above.
 297 dnl GLIB_VERSION_MAX_ALLOWED should be set to the same version;
 298 dnl nm-glib.h will cause it to be overridden for the functions
 299 dnl we have compat versions of.
 300 GLIB_CFLAGS="$GLIB_CFLAGS -DGLIB_VERSION_MIN_REQUIRED=GLIB_VERSION_2_32 -DGLIB_VERSION_MAX_ALLOWED=GLIB_VERSION_2_32"
 301
 302 AC_SUBST(GLIB_CFLAGS)
 303 AC_SUBST(GLIB_LIBS)
 304
 305 PKG_CHECK_MODULES(GUDEV, gudev-1.0 >= 165)
 306
 307 GOBJECT_INTROSPECTION_CHECK([0.9.6])
 308
 309 # Qt4
 310 PKG_CHECK_MODULES(QT, [QtCore >= 4 QtDBus QtNetwork], [have_qt=yes],[have_qt=no])
 311 AC_ARG_ENABLE(qt, AS_HELP_STRING([--enable-qt], [enable Qt examples]),
 312                      [enable_qt=${enableval}], [enable_qt=${have_qt}])
 313 if (test "${enable_qt}" = "yes"); then
 314         if test x"$have_qt" = x"no"; then
 315                 AC_MSG_ERROR(Qt development headers are required)
 316         fi
 317         # Check for moc-qt4 and if not found then moc
 318         QT4_BINDIR=`$PKG_CONFIG QtCore --variable moc_location`
 319         AC_CHECK_PROGS(MOC, [moc-qt4 moc],, [$QT4_BINDIR:$PATH])
 320 fi
 321 AM_CONDITIONAL(WITH_QT, test "${enable_qt}" = "yes")
 322
 323 AC_ARG_WITH(udev-dir, AS_HELP_STRING([--with-udev-dir=DIR], [Absolute path of the udev base directory. Set to 'no' not to install the udev rules]), [], [with_udev_dir="yes"])
 324 if (test "$with_udev_dir" != 'no'); then
 325         if (test "$with_udev_dir" != 'yes' && printf '%s' "$with_udev_dir" | grep -v -q '^/'); then
 326                 AC_MSG_ERROR([--with-udev-dir must be an absolute path or 'yes' or 'no'. Instead it is '$with_udev_dir'])
 327         fi
 328         if (test "$with_udev_dir" = 'yes'); then
 329                 with_udev_dir="/lib/udev"
 330         fi
 331         UDEV_DIR="$with_udev_dir"
 332         AC_SUBST(UDEV_DIR)
 333 fi
 334 AM_CONDITIONAL(WITH_UDEV_DIR, test "$with_udev_dir" != 'no')
 335
 336 # systemd unit support
 337 AC_ARG_WITH([systemdsystemunitdir], AS_HELP_STRING([--with-systemdsystemunitdir=DIR],
 338         [Directory for systemd service files]))
 339 # default location
 340 AS_IF([test -z "$with_systemdsystemunitdir" && $PKG_CONFIG systemd],
 341         with_systemdsystemunitdir="\$(prefix)/lib/systemd/system")
 342 AS_IF([test -z "$with_systemdsystemunitdir"], with_systemdsystemunitdir=no)
 343 # add conditional and subst
 344 AM_CONDITIONAL(HAVE_SYSTEMD, [test "$with_systemdsystemunitdir" != no])
 345 if test "$with_systemdsystemunitdir" != no; then
 346         AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
 347         AC_DEFINE(HAVE_SYSTEMD, 1, [Define if systemd support is available])
 348 else
 349         AC_DEFINE(HAVE_SYSTEMD, 0, [Define if systemd support is available])
 350 fi
 351
 352 PKG_CHECK_MODULES(SYSTEMD_200, [systemd >= 200], [have_systemd_200=yes],[have_systemd_200=no])
 353 AM_CONDITIONAL(HAVE_SYSTEMD_200, test "${have_systemd_200}" = "yes")
 354
 355 # Hostname persist mode
 356 AC_ARG_WITH(hostname-persist, AS_HELP_STRING([--with-hostname-persist=default|suse|gentoo],
 357         [Hostname persist method]))
 358
 359 AS_IF([test "$with_hostname_persist" = "suse"], hostname_persist=suse)
 360 AS_IF([test "$with_hostname_persist" = "gentoo"], hostname_persist=gentoo)
 361 AS_IF([test "$with_hostname_persist" = "default"], hostname_persist=default)
 362 # if the method was not explicitly set, try to guess it from the enabled plugins
 363 AS_IF([test -z "$hostname_persist" -a "$distro_plugins" = "ifcfg-suse"], hostname_persist=suse)
 364 AS_IF([test -z "$hostname_persist" -a "$distro_plugins" = "ifnet"], hostname_persist=gentoo)
 365 AS_IF([test -z "$hostname_persist"], hostname_persist=default)
 366
 367 if test "$hostname_persist" = suse; then
 368         AC_DEFINE(HOSTNAME_PERSIST_SUSE, 1, [Enable SuSE hostname persist method])
 369 elif test "$hostname_persist" = gentoo; then
 370         AC_DEFINE(HOSTNAME_PERSIST_GENTOO, 1, [Enable Gentoo hostname persist method])
 371 fi
 372
 373 AC_ARG_WITH(systemd-journal, AS_HELP_STRING([--with-systemd-journal=yes|no], [Use systemd journal for logging]))
 374 have_systemd_journal=no
 375 if test "$with_systemd_journal" != "no"; then
 376         PKG_CHECK_MODULES(SYSTEMD_JOURNAL,
 377                           [libsystemd >= 209],
 378                           [have_systemd_journal=yes],
 379                           [PKG_CHECK_MODULES(SYSTEMD_JOURNAL,
 380                                              [libsystemd-journal],
 381                                              [have_systemd_journal=yes],
 382                                              [have_systemd_journal=no])])
 383         if test "$have_systemd_journal" != "yes"; then
 384                 if test "$with_systemd_journal" = "yes"; then
 385                         AC_MSG_ERROR([Missing systemd-journald support])
 386                 fi
 387         fi
 388 fi
 389 if test "$have_systemd_journal" = "yes"; then
 390         AC_DEFINE([SYSTEMD_JOURNAL], 1, [Define to 1 if libsystemd-journald is available])
 391 else
 392         AC_DEFINE([SYSTEMD_JOURNAL], 0, [Define to 1 if libsystemd-journald is available])
 393 fi
 394
 395 AC_ARG_WITH(config-logging-backend-default, AS_HELP_STRING([--with-logging-backend-default=backend], [Default value for logging.backend]), nm_config_logging_backend_default="$withval", nm_config_logging_backend_default="")
 396 if test "$nm_config_logging_backend_default" != 'debug' \
 397      -a "$nm_config_logging_backend_default" != 'syslog' \
 398      -a "$nm_config_logging_backend_default" != 'journal' \
 399      -a "$nm_config_logging_backend_default" != 'journal-syslog-style'; then
 400         # unknown backend. Reset to default. Silently accept the invalid value to
 401         # be future proof.
 402         nm_config_logging_backend_default=''
 403 fi
 404 if test "$nm_config_logging_backend_default" = ""; then
 405         if test "$have_systemd_journal" = "yes"; then
 406                 nm_config_logging_backend_default='journal-syslog-style'
 407         else
 408                 nm_config_logging_backend_default='syslog'
 409         fi
 410 fi
 411 AC_DEFINE_UNQUOTED(NM_CONFIG_LOGGING_BACKEND_DEFAULT, "$nm_config_logging_backend_default", [Default configuration option for logging.backend])
 412 NM_CONFIG_LOGGING_BACKEND_DEFAULT_TEXT="$nm_config_logging_backend_default"
 413 AC_SUBST(NM_CONFIG_LOGGING_BACKEND_DEFAULT_TEXT)
 414
 415 # Session tracking support
 416 AC_ARG_WITH(systemd-logind, AS_HELP_STRING([--with-systemd-logind=yes|no],
 417         [Support systemd session tracking]))
 418 AC_ARG_WITH(consolekit, AS_HELP_STRING([--with-consolekit=yes|no],
 419         [Support consolekit session tracking]))
 420 AC_ARG_WITH(session-tracking, AS_HELP_STRING([--with-session-tracking=systemd|consolekit|no],
 421         [Compatibility option to choose one session tracking module]))
 422 # backwards compatibility
 423 AS_IF([test "$with_session_tracking" = "ck"], [use_consolekit="yes" use_systemd_logind="no"])
 424 AS_IF([test "$with_session_tracking" = "consolekit"], [use_consolekit="yes" use_systemd_logind="no"])
 425 AS_IF([test "$with_session_tracking" = "systemd"], [use_consolekit="no" use_systemd_logind="yes"])
 426 AS_IF([test "$with_session_tracking" = "no"], [use_consolekit="no" use_systemd_logind="no"])
 427 AS_IF([test "$with_session_tracking" = "none"], [use_consolekit="no" use_systemd_logind="no"])
 428 # current options
 429 AS_IF([test -n "$with_systemd_logind" ], [use_systemd_logind="$with_systemd_logind"])
 430 AS_IF([test -n "$with_consolekit" ], [use_consolekit="$with_consolekit"])
 431 # defaults
 432 AS_IF([test -z "$use_systemd_logind"], [use_systemd_logind="auto"])
 433 AS_IF([test -z "$use_consolekit"], [use_consolekit="yes"])
 434 # output
 435 session_tracking=
 436 if test "$use_systemd_logind" = "yes" -o "$use_systemd_logind" = "auto"; then
 437     PKG_CHECK_MODULES(SYSTEMD_LOGIN, [libsystemd], [have_systemd_logind=yes], [PKG_CHECK_MODULES(SYSTEMD_LOGIN, [libsystemd-login], [have_systemd_logind=yes], [have_systemd_logind=no])])
 438 else
 439     have_systemd_logind=no
 440 fi
 441 if test "$use_systemd_logind" = "yes" -a "$have_systemd_logind" = "no"; then
 442     AC_MSG_ERROR([You must have libsystemd installed to build with systemd-logind support.])
 443 fi
 444 if test "$have_systemd_logind" = "yes"; then
 445         AC_DEFINE([SESSION_TRACKING_SYSTEMD], 1, [Define to 1 if libsystemd-login is available])
 446         session_tracking="$session_tracking, systemd-logind"
 447 fi
 448 if test "$use_consolekit" = "yes"; then
 449         AC_DEFINE([SESSION_TRACKING_CONSOLEKIT], 1, [Define to 1 if ConsoleKit is available])
 450         AC_DEFINE([CKDB_PATH], "/var/run/ConsoleKit/database", [Path to ConsoleKit database])
 451         session_tracking="$session_tracking, consolekit"
 452 fi
 453 session_tracking="$(printf '%s' "${session_tracking}" | sed 's/^, //')"
 454
 455 AC_ARG_WITH(suspend-resume, AS_HELP_STRING([--with-suspend-resume=upower|systemd], [Build NetworkManager with specific suspend/resume support]))
 456 if test "z$with_suspend_resume" = "z"; then
 457     PKG_CHECK_EXISTS([libsystemd >= 209], [have_systemd_inhibit=yes],
 458                      [PKG_CHECK_EXISTS([libsystemd-login >= 183], [have_systemd_inhibit=yes], [have_systemd_inhibit=no])])
 459     if test "z${have_systemd_inhibit}" = "zyes"; then
 460         # Use systemd if it's new enough
 461         with_suspend_resume="systemd"
 462     else
 463         # Fall back to upower
 464         with_suspend_resume="upower"
 465     fi
 466 fi
 467
 468 case $with_suspend_resume in
 469     upower) ;;
 470     systemd)
 471         PKG_CHECK_MODULES(SYSTEMD_INHIBIT, [libsystemd >= 209],,
 472                           [PKG_CHECK_MODULES(SYSTEMD_INHIBIT, [libsystemd-login >= 183])])
 473         ;;
 474     *)
 475         AC_MSG_ERROR(--with-suspend-resume must be one of [upower, systemd])
 476         ;;
 477 esac
 478 AM_CONDITIONAL(SUSPEND_RESUME_UPOWER, test "x$with_suspend_resume" = "xupower")
 479 AM_CONDITIONAL(SUSPEND_RESUME_SYSTEMD, test "x$with_suspend_resume" = "xsystemd")
 480
 481 # SELinux support
 482 AC_ARG_WITH(selinux, AS_HELP_STRING([--with-selinux=yes|no|auto], [Build with SELinux (default: auto)]),,[with_selinux=auto])
 483 if test "$with_selinux" = "yes" -o "$with_selinux" = "auto"; then
 484     PKG_CHECK_MODULES(SELINUX, libselinux, [have_selinux=yes], [have_selinux=no])
 485 else
 486     have_selinux=no
 487 fi
 488 if test "$with_selinux" = "yes" -a "$have_selinux" = "no"; then
 489     AC_MSG_ERROR([You must have libselinux installed to build --with-selinux=yes.])
 490 fi
 491 if test "$have_selinux" = "yes"; then
 492     AC_DEFINE(HAVE_SELINUX, 1, [Define if you have SELinux support])
 493 else
 494     AC_DEFINE(HAVE_SELINUX, 0, [Define if you have SELinux support])
 495 fi
 496
 497 # libaudit support
 498 AC_ARG_WITH(libaudit, AS_HELP_STRING([--with-libaudit=yes|yes-disabled-by-default|no|auto], [Build with audit daemon support (default: auto). yes-disabled-by-default enables support, but disables it unless explicitly configured via NetworkManager.conf]),,[with_libaudit=auto])
 499 if test "$with_libaudit" = "yes" -o "$with_libaudit" = "yes-disabled-by-default" -o "$with_libaudit" = "auto"; then
 500     PKG_CHECK_MODULES(LIBAUDIT, audit, [have_libaudit=yes], [have_libaudit=no])
 501     if test "$with_libaudit" != "auto" -a "$have_libaudit" = "no"; then
 502         AC_MSG_ERROR([You must have libaudit installed to build --with-libaudit=$with_libaudit.])
 503     fi
 504 else
 505     have_libaudit=no
 506 fi
 507 if test "$have_libaudit" = "yes"; then
 508     AC_DEFINE(HAVE_LIBAUDIT, 1, [Define if you have libaudit support])
 509         if test "$with_libaudit" = "yes-disabled-by-default"; then
 510                 AC_DEFINE(NM_CONFIG_DEFAULT_LOGGING_AUDIT, FALSE, [The default value of the logging.audit configuration option])
 511                 NM_CONFIG_DEFAULT_LOGGING_AUDIT_TEXT='false'
 512         else
 513                 AC_DEFINE(NM_CONFIG_DEFAULT_LOGGING_AUDIT, TRUE,  [The default value of the logging.audit configuration option])
 514                 NM_CONFIG_DEFAULT_LOGGING_AUDIT_TEXT='true'
 515         fi
 516 else
 517     AC_DEFINE(HAVE_LIBAUDIT, 0, [Define if you have libaudit support])
 518         AC_DEFINE(NM_CONFIG_DEFAULT_LOGGING_AUDIT, FALSE, [The default value of the logging.audit configuration option])
 519     NM_CONFIG_DEFAULT_LOGGING_AUDIT_TEXT='false'
 520 fi
 521 AC_SUBST(NM_CONFIG_DEFAULT_LOGGING_AUDIT_TEXT)
 522
 523 # libnl support for the linux platform
 524 PKG_CHECK_MODULES(LIBNL, libnl-3.0 >= 3.2.8 libnl-route-3.0 libnl-genl-3.0)
 525
 526 AC_CHECK_LIB([nl-route-3], [rtnl_link_inet6_get_addr_gen_mode],
 527         ac_have_addr_gen_mode="1",
 528         ac_have_addr_gen_mode="0")
 529 AC_DEFINE_UNQUOTED(HAVE_LIBNL_INET6_ADDR_GEN_MODE,
 530         $ac_have_addr_gen_mode, [Define if libnl has rtnl_link_inet6_get_addr_gen_mode()])
 531
 532 AC_MSG_CHECKING([Linux kernel IN6_ADDR_GEN_MODE enum])
 533 AC_COMPILE_IFELSE(
 534         [AC_LANG_PROGRAM(
 535               [[#ifndef __user
 536                 #define __user
 537                 #endif
 538                 #include <linux/if_link.h>]],
 539               [[int a = IN6_ADDR_GEN_MODE_EUI64; a++;]])],
 540         [ac_have_kernel_gen_mode=yes],
 541         [ac_have_kernel_gen_mode=no])
 542 AC_MSG_RESULT($ac_have_kernel_gen_mode)
 543 if test "$ac_have_kernel_gen_mode" = yes; then
 544         AC_DEFINE(HAVE_KERNEL_INET6_ADDR_GEN_MODE, 1, [Define if the kernel has IN6_ADDR_GEN_MODE_*])
 545 else
 546         AC_DEFINE(HAVE_KERNEL_INET6_ADDR_GEN_MODE, 0, [Define if the kernel has IN6_ADDR_GEN_MODE_*])
 547 fi
 548
 549 # IPv6 tokenized identifiers support in libnl
 550 AC_CHECK_LIB([nl-route-3], [rtnl_link_inet6_get_token],
 551         ac_have_ipv6_token="1",
 552         ac_have_ipv6_token="0")
 553 AC_DEFINE_UNQUOTED(HAVE_LIBNL_INET6_TOKEN,
 554         $ac_have_ipv6_token, [Define if libnl has rtnl_link_inet6_get_token()])
 555
 556 # uuid library
 557 PKG_CHECK_MODULES(UUID, uuid)
 558
 559 dnl Checks for readline library - used by nmcli
 560 AX_LIB_READLINE
 561
 562 # Teamd control checks
 563 PKG_CHECK_MODULES(LIBTEAMDCTL, [libteamdctl >= 1.9], [have_teamdctl=yes],[have_teamdctl=no])
 564 AC_ARG_ENABLE(teamdctl, AS_HELP_STRING([--enable-teamdctl], [enable Teamd control support]),
 565                      [enable_teamdctl=${enableval}], [enable_teamdctl=${have_teamdctl}])
 566 if (test "${enable_teamdctl}" = "yes"); then
 567         if test x"$have_teamdctl" = x"no"; then
 568                 AC_MSG_ERROR(Teamd control is required)
 569         fi
 570         # temporary bug workaround
 571         LIBTEAMDCTL_CFLAGS=`echo $LIBTEAMDCTL_CFLAGS | sed -e 's:/teamdctl.h::'`
 572         AC_DEFINE(WITH_TEAMDCTL, 1, [Define if you have Teamd control support])
 573 else
 574         AC_DEFINE(WITH_TEAMDCTL, 0, [Define if you have Teamd control support])
 575 fi
 576 AM_CONDITIONAL(WITH_TEAMDCTL, test "${enable_teamdctl}" = "yes")
 577
 578 # we usually compile with polkit support. --enable-polkit=yes|no only sets the
 579 # default configuration for main.auth-polkit. User can always enable/disable polkit
 580 # autorization via config. Only when specifying --enable-polkit=disabled, we do
 581 # not compile support. In this case, the user cannot enable polkit authorization via
 582 # configuration.
 583 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--enable-polkit=yes|no|disabled], [set default value for auth-polkit configuration option. This value can be overwritten by NM configuration. 'disabled' compiles NM without any support]),
 584                      [enable_polkit=${enableval}], [enable_polkit=yes])
 585 if (test "${enable_polkit}" != "no" -a "${enable_polkit}" != "disabled"); then
 586         enable_polkit=yes
 587         AC_DEFINE(NM_CONFIG_DEFAULT_AUTH_POLKIT, TRUE, [The default value of the auth-polkit configuration option])
 588         NM_CONFIG_DEFAULT_AUTH_POLKIT_TEXT='true'
 589 else
 590         AC_DEFINE(NM_CONFIG_DEFAULT_AUTH_POLKIT, FALSE, [The default value of the auth-polkit configuration option])
 591         NM_CONFIG_DEFAULT_AUTH_POLKIT_TEXT='false'
 592 fi
 593 if (test "${enable_polkit}" != "disabled"); then
 594         AC_DEFINE(WITH_POLKIT, 1, [whether to compile polkit support])
 595 else
 596         AC_DEFINE(WITH_POLKIT, 0, [whether to compile polkit support])
 597 fi
 598 AC_SUBST(NM_CONFIG_DEFAULT_AUTH_POLKIT_TEXT)
 599
 600 PKG_CHECK_MODULES(POLKIT, [polkit-agent-1 >= 0.97], [have_pk_agent=yes],[have_pk_agent=no])
 601 AC_ARG_ENABLE(polkit-agent, AS_HELP_STRING([--enable-polkit-agent], [enable polkit agent for clients]),
 602                      [enable_polkit_agent=${enableval}], [enable_polkit_agent=${have_pk_agent}])
 603 if (test "${enable_polkit_agent}" = "yes"); then
 604         if test x"$have_pk_agent" = x"no"; then
 605                 AC_MSG_ERROR(Polkit agent is required)
 606         fi
 607         AC_DEFINE(WITH_POLKIT_AGENT, 1, [Define if you have polkit agent])
 608 else
 609         AC_DEFINE(WITH_POLKIT_AGENT, 0, [Define if you have polkit agent])
 610 fi
 611 AM_CONDITIONAL(WITH_POLKIT_AGENT, test "${enable_polkit_agent}" = "yes")
 612
 613 AC_ARG_ENABLE(modify-system,
 614               AS_HELP_STRING([--enable-modify-system], [Allow users to modify system connections]))
 615 if test "${enable_modify_system}" = "yes"; then
 616         NM_MODIFY_SYSTEM_POLICY="yes"
 617 else
 618         NM_MODIFY_SYSTEM_POLICY="auth_admin_keep"
 619 fi
 620 AC_SUBST(NM_MODIFY_SYSTEM_POLICY)
 621
 622 AC_ARG_WITH(crypto, AS_HELP_STRING([--with-crypto=nss|gnutls], [Cryptography library to use for certificate and key operations]),ac_crypto=$withval, ac_crypto=nss)
 623
 624 with_nss=no
 625 with_gnutls=no
 626 if test x"$ac_crypto" = xnss; then
 627   PKG_CHECK_MODULES(NSS, [nss >= 3.11])
 628
 629   # Work around a pkg-config bug (fdo #29801) where exists != usable
 630   FOO=`$PKG_CONFIG --cflags --libs nss`
 631   if test x"$?" != "x0"; then
 632     AC_MSG_ERROR([No usable NSS found])
 633   fi
 634
 635   AC_DEFINE(HAVE_NSS, 1, [Define if you have NSS])
 636   with_nss=yes
 637 elif test x"$ac_crypto" = xgnutls; then
 638   PKG_CHECK_MODULES(GNUTLS, [gnutls >= 2.12])
 639   AC_DEFINE(HAVE_GNUTLS, 1, [Define if you have libgnutls])
 640   with_gnutls=yes
 641 else
 642   AC_MSG_ERROR([Please choose either 'nss' or 'gnutls' for certificate and crypto operations])
 643 fi
 644 AM_CONDITIONAL(WITH_NSS, test x"$with_nss" != xno)
 645 AM_CONDITIONAL(WITH_GNUTLS, test x"$with_gnutls" != xno)
 646
 647 # Shouldn't ever trigger this, but just in case...
 648 if test x"$ac_nss" = xno -a x"$ac_gnutls" = xno; then
 649   AC_MSG_ERROR([Could not find required development headers and libraries for '$ac_crypto'])
 650 fi
 651
 652 GLIB_MAKEFILE='$(top_srcdir)/Makefile.glib'
 653 AC_SUBST(GLIB_MAKEFILE)
 654 GLIB_GENMARSHAL=`pkg-config --variable=glib_genmarshal glib-2.0`
 655 AC_SUBST(GLIB_GENMARSHAL)
 656 GLIB_MKENUMS=`pkg-config --variable=glib_mkenums glib-2.0`
 657 AC_SUBST(GLIB_MKENUMS)
 658
 659 AC_ARG_WITH(dbus-sys-dir, AS_HELP_STRING([--with-dbus-sys-dir=DIR], [where D-BUS system.d directory is]))
 660
 661 if test -n "$with_dbus_sys_dir" ; then
 662     DBUS_SYS_DIR="$with_dbus_sys_dir"
 663 else
 664     DBUS_SYS_DIR="${sysconfdir}/dbus-1/system.d"
 665 fi
 666 AC_SUBST(DBUS_SYS_DIR)
 667
 668 # pppd
 669 AC_ARG_ENABLE(ppp, AS_HELP_STRING([--enable-ppp], [enable PPP/PPPoE support]),
 670                      [enable_ppp=${enableval}], [enable_ppp=yes])
 671 if (test "${enable_ppp}" = "yes"); then
 672         AC_CHECK_HEADERS(pppd/pppd.h,,
 673                 AC_MSG_ERROR("couldn't find pppd.h. pppd development headers are required."))
 674
 675         AC_DEFINE(WITH_PPP, 1, [Define if you have PPP support])
 676 else
 677         AC_DEFINE(WITH_PPP, 0, [Define if you have PPP support])
 678 fi
 679 AM_CONDITIONAL(WITH_PPP, test "${enable_ppp}" = "yes")
 680
 681 AC_ARG_WITH([pppd-plugin-dir], AS_HELP_STRING([--with-pppd-plugin-dir=DIR], [path to the pppd plugins directory]))
 682
 683 if test -n "$with_pppd_plugin_dir" ; then
 684         PPPD_PLUGIN_DIR="$with_pppd_plugin_dir"
 685 else
 686         PPPD_PLUGIN_DIR="${libdir}/pppd/2.4.5"
 687 fi
 688 AC_SUBST(PPPD_PLUGIN_DIR)
 689
 690 AC_ARG_WITH(pppd, AS_HELP_STRING([--with-pppd=/path/to/pppd], [path to pppd binary]))
 691 if test "x${with_pppd}" = x; then
 692   AC_PATH_PROG(PPPD_PATH, pppd, [], $PATH:/sbin:/usr/sbin)
 693 else
 694   PPPD_PATH="$with_pppd"
 695 fi
 696 AC_DEFINE_UNQUOTED(PPPD_PATH, "$PPPD_PATH", [Define to path of pppd binary])
 697 AC_SUBST(PPPD_PATH)
 698
 699 # ModemManager1 with libmm-glib
 700 AC_ARG_WITH(modem-manager-1, AS_HELP_STRING([--with-modem-manager-1], [Enable new ModemManager1 interface support]),,[with_modem_manager_1=auto])
 701 if (test "${with_modem_manager_1}" != "no"); then
 702     PKG_CHECK_MODULES(MM_GLIB,
 703                       [mm-glib >= 0.7.991],
 704                       [have_libmm_glib=yes],
 705                       [have_libmm_glib=no])
 706
 707     if (test "${have_libmm_glib}" = "no"); then
 708         if (test "${with_modem_manager_1}" = "yes"); then
 709             AC_MSG_ERROR([Couldn't find libmm-glib])
 710         else
 711             with_modem_manager_1="no"
 712         fi
 713     else
 714         with_modem_manager_1="yes"
 715     fi
 716 fi
 717
 718 if (test "${with_modem_manager_1}" = "yes"); then
 719     AC_DEFINE(WITH_MODEM_MANAGER_1, 1, [Define if you have ModemManager1 support])
 720 else
 721         AC_DEFINE(WITH_MODEM_MANAGER_1, 0, [Define if you have ModemManager1 support])
 722 fi
 723 AM_CONDITIONAL(WITH_MODEM_MANAGER_1, test "${with_modem_manager_1}" = "yes")
 724
 725 # Bluez5 DUN support
 726 PKG_CHECK_MODULES(BLUEZ5, [bluez >= 5], [have_bluez5=yes],[have_bluez5=no])
 727 AC_ARG_ENABLE(bluez5-dun, AS_HELP_STRING([--enable-bluez5-dun], [enable Bluez5 DUN support]),
 728                 [enable_bluez5_dun=${enableval}], [enable_bluez5_dun=${have_bluez5}])
 729 if (test "${enable_bluez5_dun}" = "yes"); then
 730         if test x"$have_bluez5" = x"no"; then
 731                 AC_MSG_ERROR(Bluez 5.x development headers are required)
 732         fi
 733         AC_DEFINE(WITH_BLUEZ5_DUN, 1, [Define if you have Bluez 5 libraries])
 734 else
 735         AC_DEFINE(WITH_BLUEZ5_DUN, 0, [Define if you have Bluez 5 libraries])
 736 fi
 737 AM_CONDITIONAL(WITH_BLUEZ5_DUN, test "${enable_bluez5_dun}" = "yes")
 738
 739 # DHCP client support
 740 AC_ARG_WITH([dhclient], AS_HELP_STRING([--with-dhclient=yes|no|path], [Enable dhclient 4.x support]))
 741 AC_ARG_WITH([dhcpcd], AS_HELP_STRING([--with-dhcpcd=yes|no|path], [Enable dhcpcd 4.x support]))
 742 # Default to "yes"
 743 AS_IF([test -z "$with_dhclient"], with_dhclient=yes)
 744 AS_IF([test -z "$with_dhcpcd"], with_dhcpcd=yes)
 745 # Search and check the executables
 746 if test "$with_dhclient" = "yes"; then
 747         AC_PATH_PROGS(with_dhclient, dhclient, no, /sbin:/usr/sbin:/usr/local/sbin)
 748         if test "$with_dhclient" != "no"; then
 749                 if ! $with_dhclient --version 2>&1 | grep -q "^isc-dhclient-4\."; then
 750                         AC_MSG_WARN([Cannot use dhclient, version 4.x is required])
 751                         with_dhclient=no
 752                 fi
 753         fi
 754 fi
 755 if test "$with_dhcpcd" = "yes"; then
 756         AC_PATH_PROGS(with_dhcpcd, dhcpcd, no, /sbin:/usr/sbin:/usr/local/sbin)
 757         if test "$with_dhcpcd" != "no"; then
 758                 if ! $with_dhcpcd --version 2>&1 | grep -q "^dhcpcd [[456789]]\."; then
 759                         AC_MSG_WARN([Cannot use dhcpcd, version 4.x or higher is required])
 760                         with_dhcpcd=no
 761                 elif $with_dhcpcd --version 2>&1 | grep -q "^dhcpcd [[6789]]\."; then
 762                         AC_DEFINE(DHCPCD_SUPPORTS_IPV6, 1, [Define if dhcpcd supports IPv6 (6.x+)])
 763                 fi
 764         fi
 765 fi
 766 # Fallback
 767 if test "$with_dhclient" = "no" -a "$with_dhcpcd" = "no"; then
 768         AC_MSG_WARN([Could not find a suitable DHCP client, falling back to dhclient])
 769         with_dhclient=/sbin/dhclient
 770 fi
 771 # Add substitutions
 772 if test "$with_dhclient" != "no"; then
 773         AC_DEFINE(WITH_DHCLIENT, TRUE, [Define if you have dhclient])
 774         AC_SUBST(DHCLIENT_PATH, $with_dhclient)
 775 else
 776         AC_DEFINE(WITH_DHCLIENT, FALSE, [Define if you have dhclient])
 777 fi
 778 if test "$with_dhcpcd" != "no"; then
 779         AC_DEFINE(WITH_DHCPCD, TRUE, [Define if you have dhcpcd])
 780         AC_SUBST(DHCPCD_PATH, $with_dhcpcd)
 781 else
 782         AC_DEFINE(WITH_DHCPCD, FALSE, [Define if you have dhcpcd])
 783 fi
 784
 785 # resolvconf and netconfig support
 786 AC_ARG_WITH(resolvconf, AS_HELP_STRING([--with-resolvconf=yes|no|path], [Enable resolvconf support]))
 787 AC_ARG_WITH(netconfig, AS_HELP_STRING([--with-netconfig=yes|no], [Enable SUSE netconfig support]))
 788 # Use netconfig by default on SUSE
 789 AS_IF([test -z "$with_netconfig"], AC_CHECK_FILE(/etc/SuSE-release, with_netconfig=yes))
 790 # Otherwise default to "no"
 791 AS_IF([test -z "$with_resolvconf"], with_resolvconf=no)
 792 AS_IF([test -z "$with_netconfig"], with_netconfig=no)
 793 # Find resolvconf and netconfig
 794 if test "$with_resolvconf" = "yes"; then
 795         AC_PATH_PROGS(with_resolvconf, resolvconf, no, /sbin:/usr/sbin:/usr/local/sbin)
 796 fi
 797 if test "$with_netconfig" = "yes"; then
 798         AC_PATH_PROGS(with_netconfig, netconfig, no, /sbin:/usr/sbin:/usr/local/sbin)
 799 fi
 800 # Define resolvconf and netconfig paths
 801 if test "$with_resolvconf" != "no"; then
 802         AC_DEFINE_UNQUOTED(RESOLVCONF_PATH, "$with_resolvconf", [Path to resolvconf])
 803 fi
 804 if test "$with_netconfig" != "no"; then
 805         AC_DEFINE_UNQUOTED(NETCONFIG_PATH, "$with_netconfig", [Path to netconfig])
 806 fi
 807
 808 # iptables path
 809 AC_ARG_WITH(iptables, AS_HELP_STRING([--with-iptables=/path/to/iptables], [path to iptables]))
 810 if test "x${with_iptables}" = x; then
 811   AC_PATH_PROG(IPTABLES_PATH, iptables, [], $PATH:/sbin:/usr/sbin)
 812   if ! test -x "$IPTABLES_PATH"; then
 813         AC_MSG_ERROR(iptables was not installed.)
 814   fi
 815 else
 816   IPTABLES_PATH="$with_iptables"
 817 fi
 818 AC_DEFINE_UNQUOTED(IPTABLES_PATH, "$IPTABLES_PATH", [Define to path of iptables binary])
 819 AC_SUBST(IPTABLES_PATH)
 820
 821 # dnsmasq path
 822 AC_ARG_WITH(dnsmasq, AS_HELP_STRING([--with-dnsmasq=/path/to/dnsmasq], [path to dnsmasq]))
 823 if test "x${with_dnsmasq}" = x; then
 824   AC_PATH_PROG(DNSMASQ_PATH, dnsmasq, [], $PATH:/sbin:/usr/sbin)
 825 else
 826   DNSMASQ_PATH="$with_dnsmasq"
 827 fi
 828 AC_DEFINE_UNQUOTED(DNSMASQ_PATH, "$DNSMASQ_PATH", [Define to path of dnsmasq binary])
 829 AC_SUBST(DNSMASQ_PATH)
 830
 831 # system CA certificates path
 832 AC_ARG_WITH(system-ca-path, AS_HELP_STRING([--with-system-ca-path=/path/to/ssl/certs], [path to system CA certificates]))
 833 if test "x${with_system_ca_path}" = x; then
 834   SYSTEM_CA_PATH=/etc/ssl/certs
 835 else
 836   SYSTEM_CA_PATH="$with_system_ca_path"
 837 fi
 838 AC_DEFINE_UNQUOTED(SYSTEM_CA_PATH, "$SYSTEM_CA_PATH", [Define to path to system CA certificates])
 839 AC_SUBST(SYSTEM_CA_PATH)
 840
 841 AC_ARG_WITH(kernel-firmware-dir, AS_HELP_STRING([--with-kernel-firmware-dir=DIR], [where kernel firmware directory is (default is /lib/firmware)]))
 842
 843 if test -n "$with_kernel_firmware_dir" ; then
 844     KERNEL_FIRMWARE_DIR="$with_kernel_firmware_dir"
 845 else
 846     KERNEL_FIRMWARE_DIR="/lib/firmware"
 847 fi
 848 AC_DEFINE_UNQUOTED(KERNEL_FIRMWARE_DIR, "$KERNEL_FIRMWARE_DIR", [Define to path of the kernel firmware directory])
 849 AC_SUBST(KERNEL_FIRMWARE_DIR)
 850
 851 PKG_CHECK_MODULES(LIBSOUP, [libsoup-2.4 >= 2.26], [have_libsoup=yes],[have_libsoup=no])
 852 AC_ARG_WITH(libsoup, AS_HELP_STRING([--with-libsoup=yes|no], [Link against libsoup]), [], [with_libsoup=${have_libsoup}])
 853 if test "$with_libsoup" != "no"; then
 854         if test "$have_libsoup" != "yes"; then
 855                 AC_MSG_ERROR(libsoup library not found)
 856         fi
 857         with_libsoup='yes'
 858         AC_DEFINE(WITH_LIBSOUP, 1, [Define if you have libsoup])
 859 else
 860         AC_DEFINE(WITH_LIBSOUP, 0, [Define if you have libsoup])
 861 fi
 862 AM_CONDITIONAL(WITH_LIBSOUP, test "$with_libsoup" != "no")
 863
 864 AC_ARG_ENABLE(concheck, AS_HELP_STRING([--enable-concheck], [enable connectivity checking support]),
 865                      [enable_concheck=${enableval}], [enable_concheck=${with_libsoup}])
 866 if (test "${enable_concheck}" = "yes"); then
 867         if test x"$with_libsoup" = x"no"; then
 868                 AC_MSG_ERROR(Connectivity checking requires libsoup)
 869         fi
 870         AC_DEFINE(WITH_CONCHECK, 1, [Define if you want connectivity checking support])
 871 else
 872         AC_DEFINE(WITH_CONCHECK, 0, [Define if you want connectivity checking support])
 873 fi
 874 AM_CONDITIONAL(WITH_CONCHECK, test "${enable_concheck}" = "yes")
 875
 876 PKG_CHECK_MODULES(LIBNDP, [libndp])
 877
 878 AC_ARG_WITH(nmtui, AS_HELP_STRING([--with-nmtui=yes|no], [Build nmtui]))
 879 if test "$with_nmtui" != no; then
 880     PKG_CHECK_MODULES(NEWT, [libnewt >= 0.52.15], [build_nmtui=yes], [build_nmtui=no])
 881 else
 882     build_nmtui=no
 883 fi
 884 if test "$with_nmtui" = yes -a "$build_nmtui" = no; then
 885     AC_MSG_ERROR([You must have libnewt installed to build nmtui.])
 886 fi
 887 AM_CONDITIONAL(BUILD_NMTUI, test "$build_nmtui" = yes)
 888
 889
 890 NM_COMPILER_WARNINGS
 891
 892 AC_ARG_ENABLE(more-asserts,
 893               AS_HELP_STRING([--enable-more-asserts], [Enable more assertions for debugging (default: no)]))
 894 if test "${enable_more_asserts}" = "yes"; then
 895     AC_DEFINE(NM_MORE_ASSERTS, [1], [Define if more asserts are enabled])
 896 fi
 897
 898 AC_ARG_ENABLE(more-logging,
 899               AS_HELP_STRING([--enable-more-logging], [Enable more debug logging (default: no)]))
 900 if test "${enable_more_logging}" = "yes"; then
 901     AC_DEFINE(NM_MORE_LOGGING, [1], [Define if more debug logging is enabled])
 902 fi
 903
 904 AC_ARG_ENABLE(lto, AS_HELP_STRING([--enable-lto], [Enable Link Time Optimization for smaller size (default: no)]))
 905 if (test "${enable_lto}" = "yes"); then
 906     CFLAGS="-flto $CFLAGS"
 907 else
 908     enable_lto='no'
 909 fi
 910
 911
 912 dnl -------------------------
 913 dnl Vala bindings
 914 dnl -------------------------
 915
 916 VAPIGEN_CHECK(0.17.1.24)
 917
 918 # Tests, utilities and documentation
 919 AC_ARG_ENABLE(tests, AS_HELP_STRING([--enable-tests=root|yes|no], [Build NetworkManager tests (default: yes)]))
 920 AC_ARG_WITH(valgrind, AS_HELP_STRING([--with-valgrind=yes|no|path], [Use valgrind to memory-check the tests (default: no)]))
 921 # Fallback to --with-tests
 922 AC_ARG_WITH(tests, AS_HELP_STRING([--with-tests], [Build NetworkManager tests (deprecated)]))
 923 AS_IF([test -n "$with_tests"], enable_tests="$with_tests")
 924 # Default to --enable-tests --with-valgrind=no
 925 AS_IF([test -z "$enable_tests"], enable_tests="yes")
 926 AS_IF([test -z "$with_valgrind"], with_valgrind="no")
 927 # Normalize values
 928 AS_IF([test "$enable_tests" != "yes" -a "$enable_tests" != "root"], enable_tests="no")
 929 # Search for tools
 930 AS_IF([test "$with_valgrind" == "yes"],
 931         [AC_PATH_PROGS(with_valgrind, valgrind, no)])
 932 # Add conditionals and substitutions
 933 AM_CONDITIONAL(ENABLE_TESTS, test "$enable_tests" != "no")
 934 AM_CONDITIONAL(REQUIRE_ROOT_TESTS, test "$enable_tests" == "root")
 935 AC_ARG_WITH(valgrind-suppressions, AS_HELP_STRING([--with-valgrind-suppressions=path], [Use specific valgrind suppression file]))
 936 if test "$with_valgrind" == no; then
 937         with_valgrind_suppressions=
 938 else
 939         if test  "$with_valgrind_suppressions" == ""; then
 940                 with_valgrind_suppressions='$(top_srcdir)/valgrind.suppressions'
 941         fi
 942 fi
 943 AS_IF([test "$with_valgrind" != "no"],
 944         AC_SUBST(VALGRIND_RULES, 'LOG_COMPILER = "$(top_srcdir)/tools/run-test-valgrind.sh" "$(LIBTOOL)" "$(with_valgrind)" '"$with_valgrind_suppressions"),
 945         AC_SUBST(VALGRIND_RULES, []))
 946 AM_CONDITIONAL(WITH_VALGRIND, test "${with_valgrind}" != "no")
 947
 948 GTK_DOC_CHECK(1.0)
 949
 950 # check for pregenerated manpages to be installed
 951 install_pregen_manpages=no
 952 if test "$enable_gtk_doc" != "yes" \
 953         -a -f man/NetworkManager.conf.5 \
 954         -a -f man/nm-settings.5 \
 955         -a -f man/nm-settings-keyfile.5 \
 956         -a -f man/nm-settings-ifcfg-rh.5 \
 957         -a -f man/nmcli-examples.5 \
 958         -a -f man/NetworkManager.8; then
 959         install_pregen_manpages=yes
 960 fi
 961 AM_CONDITIONAL(INSTALL_PREGEN_MANPAGES, test "x${install_pregen_manpages}" = "xyes")
 962
 963 # check if we can build setting property documentation
 964 if test -n "$INTROSPECTION_MAKEFILE" -a "$enable_gtk_doc" = "yes"; then
 965     # If g-i is installed we know we have python, but we might not have pygobject
 966     if python -c 'from gi.repository import GObject' >& /dev/null; then
 967         have_pyobject=yes
 968     fi
 969
 970     # gtk-doc depends on perl, but we can check for it anyway
 971     AC_PATH_PROG(PERL, perl, no)
 972     # check for needed perl modules (use YAML; YAML::XS is better, but may not be so widespread)
 973     required_perl_modules="YAML"
 974     for module in $required_perl_modules; do
 975       AC_MSG_CHECKING([checking for perl module '$module'])
 976       if ${PERL} -e 'use '$module 2>/dev/null ; then
 977           AC_MSG_RESULT([Ok])
 978           have_perl_modules=yes
 979       else
 980           AC_MSG_RESULT([Failed])
 981           AC_MSG_ERROR([You must have Perl modules to build settings plugin docs: $required_perl_modules.])
 982       fi
 983     done
 984
 985     if test "$have_pyobject" = "yes" -a "$have_perl_modules" = "yes"; then
 986         AC_DEFINE(BUILD_SETTING_DOCS, [1], [Define if you we can build nm-setting-docs.xml, nm-keyfile-docs.xml and nm-ifcfg-rh-docs.xml])
 987         build_setting_docs=yes
 988     fi
 989 fi
 990
 991 # check for pre-built setting docs
 992 if test "$build_setting_docs" != "yes" \
 993         -a -f man/nm-settings.xml \
 994         -a -f man/nm-settings-keyfile.xml \
 995         -a -f man/nm-settings-ifcfg-rh.xml \
 996         -a -f docs/api/settings-spec.xml \
 997         -a -f clients/cli/settings-docs.c; then
 998     AC_DEFINE(HAVE_SETTING_DOCS, [1], [Define if you have pre-built settings docs])
 999     have_setting_docs=yes
1000 fi
1001
1002 AM_CONDITIONAL(BUILD_SETTING_DOCS, test "$build_setting_docs" = "yes")
1003 AM_CONDITIONAL(SETTING_DOCS_AVAILABLE, test "$build_setting_docs" = "yes" -o "$have_setting_docs" = "yes")
1004
1005
1006 AC_CONFIG_FILES([
1007 Makefile
1008 include/Makefile
1009 src/Makefile
1010 src/tests/Makefile
1011 src/tests/config/Makefile
1012 src/dhcp-manager/Makefile
1013 src/dhcp-manager/tests/Makefile
1014 src/dnsmasq-manager/tests/Makefile
1015 src/supplicant-manager/tests/Makefile
1016 src/ppp-manager/Makefile
1017 src/settings/plugins/Makefile
1018 src/settings/plugins/ifupdown/Makefile
1019 src/settings/plugins/ifupdown/tests/Makefile
1020 src/settings/plugins/ifnet/Makefile
1021 src/settings/plugins/ifnet/tests/Makefile
1022 src/settings/plugins/ifcfg-rh/Makefile
1023 src/settings/plugins/ifcfg-rh/tests/Makefile
1024 src/settings/plugins/ifcfg-rh/tests/network-scripts/Makefile
1025 src/settings/plugins/ibft/Makefile
1026 src/settings/plugins/ibft/tests/Makefile
1027 src/settings/plugins/keyfile/Makefile
1028 src/settings/plugins/keyfile/tests/Makefile
1029 src/settings/plugins/keyfile/tests/keyfiles/Makefile
1030 src/platform/Makefile
1031 src/platform/tests/Makefile
1032 src/rdisc/Makefile
1033 src/rdisc/tests/Makefile
1034 src/devices/adsl/Makefile
1035 src/devices/bluetooth/Makefile
1036 src/devices/team/Makefile
1037 src/devices/wifi/Makefile
1038 src/devices/wifi/tests/Makefile
1039 src/devices/wwan/Makefile
1040 libnm-core/nm-version.h
1041 libnm-core/Makefile
1042 libnm-core/tests/Makefile
1043 libnm/libnm.pc
1044 libnm/Makefile
1045 libnm/tests/Makefile
1046 libnm-util/libnm-util.pc
1047 libnm-util/nm-version.h
1048 libnm-util/Makefile
1049 libnm-util/tests/Makefile
1050 libnm-glib/libnm-glib.pc
1051 libnm-glib/libnm-glib-vpn.pc
1052 libnm-glib/Makefile
1053 libnm-glib/tests/Makefile
1054 callouts/Makefile
1055 callouts/tests/Makefile
1056 tools/Makefile
1057 clients/Makefile
1058 clients/cli/Makefile
1059 clients/tui/Makefile
1060 clients/tui/newt/Makefile
1061 initscript/RedHat/NetworkManager
1062 initscript/Debian/NetworkManager
1063 initscript/Slackware/rc.networkmanager
1064 initscript/SUSE/networkmanager
1065 initscript/Arch/networkmanager
1066 initscript/Mandriva/networkmanager
1067 initscript/linexa/networkmanager
1068 introspection/Makefile
1069 introspection/all.xml
1070 man/Makefile
1071 man/NetworkManager.conf.xml
1072 man/nm-system-settings.conf.5
1073 man/nm-online.1
1074 man/nmcli.1
1075 man/nmtui.1
1076 po/Makefile.in
1077 policy/Makefile
1078 policy/org.freedesktop.NetworkManager.policy.in
1079 data/Makefile
1080 docs/Makefile
1081 docs/api/Makefile
1082 docs/api/version.xml
1083 docs/libnm-glib/Makefile
1084 docs/libnm-glib/version.xml
1085 docs/libnm-util/Makefile
1086 docs/libnm-util/version.xml
1087 docs/libnm/Makefile
1088 docs/libnm/version.xml
1089 NetworkManager.pc
1090 examples/Makefile
1091 examples/shell/Makefile
1092 examples/python/Makefile
1093 examples/python/dbus/Makefile
1094 examples/python/gi/Makefile
1095 examples/ruby/Makefile
1096 examples/lua/Makefile
1097 examples/lua/lgi/Makefile
1098 examples/C/Makefile
1099 examples/C/glib/Makefile
1100 examples/C/qt/Makefile
1101 examples/dispatcher/Makefile
1102 vapi/Makefile
1103 ])
1104 AC_CONFIG_SUBDIRS([libndp])
1105 AC_OUTPUT
1106
1107 # Print build configuration
1108 echo
1109 echo "System paths:"
1110 echo "  prefix: $prefix"
1111 echo "  exec_prefix: $exec_prefix"
1112 echo "  systemdunitdir: $with_systemdsystemunitdir"
1113 echo "  nmbinary: $nmbinary"
1114 echo "  nmconfdir: $nmconfdir"
1115 echo "  nmlibdir: $nmlibdir"
1116 echo "  nmdatadir: $nmdatadir"
1117 echo "  nmstatedir: $nmstatedir"
1118 echo "  nmrundir: $nmrundir"
1119 echo
1120
1121 echo "Platform:"
1122 echo "  session tracking: $session_tracking"
1123 echo "  suspend/resume: $with_suspend_resume"
1124 if test "${enable_polkit}" = "yes"; then
1125         if test "${enable_modify_system}" = "yes"; then
1126                 echo "  policykit: yes (permissive modify.system) (default: main.auth-polkit=${enable_polkit})"
1127         else
1128                 echo "  policykit: yes (restrictive modify.system) (default: main.auth-polkit=${enable_polkit})"
1129         fi
1130 else
1131         echo  "  policykit: no"
1132 fi
1133 echo "  polkit agent: ${enable_polkit_agent}"
1134 echo "  selinux: $have_selinux"
1135 echo "  systemd-journald: $have_systemd_journal (default: logging.backend=${nm_config_logging_backend_default})"
1136 echo "  hostname persist: ${hostname_persist}"
1137 echo "  libaudit: $have_libaudit (default: logging.audit=${NM_CONFIG_DEFAULT_LOGGING_AUDIT_TEXT})"
1138 echo
1139
1140 echo "Features:"
1141 echo "  wext: $ac_with_wext"
1142 echo "  wifi: $enable_wifi"
1143 echo "  ppp: $enable_ppp"
1144 echo "  modemmanager-1: $with_modem_manager_1"
1145 echo "  concheck: $enable_concheck"
1146 echo "  libteamdctl: $enable_teamdctl"
1147 echo "  nmtui: $build_nmtui"
1148 echo
1149
1150 echo "Configuration plugins (main.plugins=${config_plugins_default})"
1151 echo "  ibft: ${enable_config_plugin_ibft}"
1152 echo "  ifcfg-rh: ${enable_ifcfg_rh}"
1153 echo "  ifupdown: ${enable_ifupdown}"
1154 echo "  ifnet: ${enable_ifnet}"
1155 echo
1156
1157 echo "Handlers for /etc/resolv.conf:"
1158 echo "  resolvconf: ${with_resolvconf}"
1159 echo "  netconfig: ${with_netconfig}"
1160 echo
1161
1162 echo "DHCP clients:"
1163 echo "  dhclient: $with_dhclient"
1164 echo "  dhcpcd: $with_dhcpcd"
1165 echo
1166
1167 echo "Miscellaneous:"
1168 echo "  documentation: $enable_gtk_doc"
1169 echo "  tests: $enable_tests"
1170 echo "  valgrind: $with_valgrind   $with_valgrind_suppressions"
1171 echo "  code coverage: $enable_code_coverage"
1172 echo "  LTO: $enable_lto"
1173 echo