merge: fix build & tests with older tooling
[NetworkManager.git] / configure.ac
1 AC_PREREQ([2.63])
2
3 dnl The NM version number
4 m4_define([nm_major_version], [1])
5 m4_define([nm_minor_version], [1])
6 m4_define([nm_micro_version], [0])
7 m4_define([nm_version],
8           [nm_major_version.nm_minor_version.nm_micro_version])
9 m4_define([nm_git_sha], [m4_esyscmd([ ( [ -d ./.git/ ] && [ "$(readlink -f ./.git/)" = "$(readlink -f "$(git rev-parse --git-dir 2>/dev/null)" 2>/dev/null)" ] && git rev-parse --verify -q HEAD 2>/dev/null ) || true ])])
10
11 AC_INIT([NetworkManager], [nm_version],
12         [http://bugzilla.gnome.org/enter_bug.cgi?product=NetworkManager],
13         [NetworkManager])
14
15 AC_CONFIG_HEADERS([config.h])
16 AC_CONFIG_MACRO_DIR([m4])
17 AC_CONFIG_AUX_DIR([build-aux])
18 AC_REQUIRE_AUX_FILE([tap-driver.sh])
19
20 AM_INIT_AUTOMAKE(1.12 tar-ustar no-dist-gzip dist-bzip2 -Wno-portability)  dnl NB: Do not [quote] this parameter.
21 AM_MAINTAINER_MODE([enable])
22 AM_SILENT_RULES([yes])
23
24 dnl Define _SYSTEM_EXTENSIONS for various things like strcasestr()
25 AC_USE_SYSTEM_EXTENSIONS
26
27 dnl
28 dnl Require programs
29 dnl
30 AC_PROG_CC
31 AM_PROG_CC_C_O
32
33 # C++ only required if --enable-qt=yes
34 AC_PROG_CXX
35
36 dnl Initialize libtool
37 LT_PREREQ([2.2])
38 LT_INIT([disable-static])
39
40 dnl Version stuff
41 NM_MAJOR_VERSION=nm_major_version
42 NM_MINOR_VERSION=nm_minor_version
43 NM_MICRO_VERSION=nm_micro_version
44 NM_VERSION=nm_version
45 NM_GIT_SHA=nm_git_sha
46 AC_SUBST(NM_MAJOR_VERSION)
47 AC_SUBST(NM_MINOR_VERSION)
48 AC_SUBST(NM_MICRO_VERSION)
49 AC_SUBST(NM_VERSION)
50 AC_DEFINE_UNQUOTED(NM_GIT_SHA,"$NM_GIT_SHA",[git commit id of the original source code version])
51
52 dnl
53 dnl Checks for typedefs, structures, and compiler characteristics.
54 dnl
55 AC_TYPE_PID_T
56
57 dnl
58 dnl translation support
59 dnl
60 IT_PROG_INTLTOOL([0.40.0])
61
62 AM_GNU_GETTEXT([external])
63 AM_GNU_GETTEXT_VERSION([0.17])
64
65 GETTEXT_PACKAGE=NetworkManager
66 AC_SUBST(GETTEXT_PACKAGE)
67 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [Gettext package])
68
69 dnl
70 dnl Make sha1.c happy on big endian systems
71 dnl
72 AC_C_BIGENDIAN
73
74 # Add runstatedir if not specified manually in autoconf < 2.70
75 AS_IF([test -z "$runstatedir"], runstatedir="$localstatedir/run")
76 AC_SUBST(runstatedir)
77
78 # NetworkManager paths
79 AC_SUBST(nmbinary, "$sbindir/$PACKAGE", [NetworkManager binary executable])
80 AC_SUBST(nmconfdir, "$sysconfdir/$PACKAGE", [NetworkManager configuration directory])
81 AC_SUBST(nmdatadir, "$datadir/$PACKAGE", [NetworkManager shared data directory])
82 AC_SUBST(nmstatedir, "$localstatedir/lib/$PACKAGE", [NetworkManager persistent state directory])
83 AC_SUBST(nmrundir, "$runstatedir/$PACKAGE", [NetworkManager runtime state directory])
84
85 # Alternative configuration plugins
86 AC_ARG_ENABLE(config-plugin-ibft, AS_HELP_STRING([--enable-config-plugin-ibft], [enable ibft configuration plugin]))
87 AC_ARG_ENABLE(ifcfg-rh, AS_HELP_STRING([--enable-ifcfg-rh], [enable ifcfg-rh configuration plugin (Fedora/RHEL)]))
88 AC_ARG_ENABLE(ifcfg-suse, AS_HELP_STRING([--enable-ifcfg-suse], [enable ifcfg-suse configuration plugin (SUSE)]))
89 AC_ARG_ENABLE(ifupdown, AS_HELP_STRING([--enable-ifupdown], [enable ifupdown configuration plugin (Debian/Ubuntu)]))
90 AC_ARG_ENABLE(ifnet, AS_HELP_STRING([--enable-ifnet], [enable ifnet configuration plugin (Gentoo)]))
91 # Default alternative plugins by distribution
92 AS_IF([test -z "$enable_ifcfg_rh"], AC_CHECK_FILE(/etc/redhat-release, enable_ifcfg_rh=yes))
93 AS_IF([test -z "$enable_ifcfg_rh"], AC_CHECK_FILE(/etc/fedora-release, enable_ifcfg_rh=yes))
94 AS_IF([test -z "$enable_ifcfg_rh"], AC_CHECK_FILE(/etc/mandriva-release, enable_ifcfg_rh=yes))
95 AS_IF([test -z "$enable_ifcfg_suse"], AC_CHECK_FILE(/etc/SuSE-release, enable_ifcfg_suse=yes))
96 AS_IF([test -z "$enable_ifupdown"], AC_CHECK_FILE(/etc/debian_version, enable_ifupdown=yes))
97 AS_IF([test -z "$enable_ifnet"], AC_CHECK_FILE(/etc/gentoo-release, enable_ifnet=yes))
98 # Otherwise plugins default to "no"
99 AS_IF([test -z "$enable_ifcfg_rh"], enable_ifcfg_rh=no)
100 AS_IF([test -z "$enable_ifcfg_suse"], enable_ifcfg_suse=no)
101 AS_IF([test -z "$enable_ifupdown"], enable_ifupdown=no)
102 AS_IF([test -z "$enable_ifnet"], enable_ifnet=no)
103 # Enable ibft by default
104 AS_IF([test -z "$enable_config_plugin_ibft"], enable_config_plugin_ibft="yes")
105 # Create automake conditionals
106 AM_CONDITIONAL(CONFIG_PLUGIN_IBFT, test "$enable_config_plugin_ibft" = "yes")
107 AM_CONDITIONAL(CONFIG_PLUGIN_IFCFG_RH, test "$enable_ifcfg_rh" = "yes")
108 AM_CONDITIONAL(CONFIG_PLUGIN_IFCFG_SUSE, test "$enable_ifcfg_suse" = "yes")
109 AM_CONDITIONAL(CONFIG_PLUGIN_IFUPDOWN, test "$enable_ifupdown" = "yes")
110 AM_CONDITIONAL(CONFIG_PLUGIN_IFNET, test "$enable_ifnet" = "yes")
111
112 AC_ARG_WITH(config-plugins-default, AS_HELP_STRING([--with-config-plugins-default=PLUGINS], [Default configuration option for main.plugins setting, used as fallback if the configuration option is unset]), [config_plugins_default="$withval"], [config_plugins_default=""])
113 if test -z "$config_plugins_default" -o "$config_plugins_default" = no; then
114     config_plugins_default=''
115     test "$enable_ifcfg_rh" = "yes"           && config_plugins_default="$config_plugins_default,ifcfg-rh"
116     test "$enable_ifcfg_suse" = "yes"         && config_plugins_default="$config_plugins_default,ifcfg-suse"
117     test "$enable_ifupdown" = "yes"           && config_plugins_default="$config_plugins_default,ifupdown"
118     test "$enable_ifnet" = "yes"              && config_plugins_default="$config_plugins_default,ifnet"
119     test "$enable_config_plugin_ibft" = "yes" && config_plugins_default="$config_plugins_default,ibft"
120     config_plugins_default="${config_plugins_default#,}"
121 fi
122 AC_DEFINE_UNQUOTED(CONFIG_PLUGINS_DEFAULT, "$config_plugins_default", [Default configuration option for main.plugins setting])
123
124 if test "$enable_ifcfg_rh" = "yes"; then
125     DISTRO_NETWORK_SERVICE=network.service
126 fi
127 AC_SUBST(DISTRO_NETWORK_SERVICE)
128
129 # Code coverage
130 GNOME_CODE_COVERAGE
131
132 dnl
133 dnl Distribution version string
134 dnl
135 AC_ARG_WITH(dist-version, AS_HELP_STRING([--with-dist-version=<NM-distribution-version>], [Define the NM''s distribution version string]), ac_distver=$withval, ac_distver="")
136 if ! test x"$ac_distver" = x""; then
137   AC_DEFINE_UNQUOTED(NM_DIST_VERSION, "$ac_distver", [Define the distribution version string])
138 fi
139
140 AC_ARG_ENABLE(wifi, AS_HELP_STRING([--enable-wifi], [enable Wi-Fi support]))
141 if test "${enable_wifi}" != "no"; then
142         enable_wifi='yes'
143         AC_DEFINE(WITH_WIFI, 1, [Define if you have Wi-Fi support])
144 else
145         AC_DEFINE(WITH_WIFI, 0, [Define if you have Wi-Fi support])
146 fi
147 AM_CONDITIONAL(WITH_WIFI, test "${enable_wifi}" = "yes")
148
149 dnl
150 dnl Default to using WEXT but allow it to be disabled
151 dnl
152 AC_ARG_WITH(wext, AS_HELP_STRING([--with-wext=yes], [Enable or disable Linux Wireless Extensions]), ac_with_wext=$withval, ac_with_wext="$enable_wifi")
153 if test "$ac_with_wext" != 'no'; then
154         ac_with_wext='yes'
155 fi
156 if test x"$ac_with_wext" = x"yes"; then
157         if test "$enable_wifi" != "yes"; then
158                 AC_MSG_ERROR(Enabling WEXT support and disabling Wi-Fi makes no sense)
159         fi
160         AC_MSG_CHECKING([Linux kernel WEXT headers])
161         AC_COMPILE_IFELSE(
162                 [AC_LANG_PROGRAM(
163                       [[#ifndef __user
164                         #define __user
165                         #endif
166                         #include <sys/types.h>
167                         #include <linux/types.h>
168                         #include <sys/socket.h>
169                         #include <linux/wireless.h>]],
170                       [[#ifndef IWEVGENIE
171                         #error "not found"
172                         #endif]])],
173                 [ac_have_iwevgenie=yes],
174                 [ac_have_iwevgenie=no])
175         AC_MSG_RESULT($ac_have_iwevgenie)
176         if test "$ac_have_iwevgenie" = no; then
177                AC_MSG_ERROR(Linux kernel development header linux/wireless.h not installed or not functional)
178         fi
179         AC_DEFINE(HAVE_WEXT, 1, [Define if you have Linux Wireless Extensions support])
180 else
181         AC_DEFINE(HAVE_WEXT, 0, [Define if you have Linux Wireless Extensions support])
182 fi
183 AM_CONDITIONAL(WITH_WEXT, test x"${ac_with_wext}" = x"yes")
184
185 AC_MSG_CHECKING([Linux kernel nl80211 headers])
186 AC_COMPILE_IFELSE(
187         [AC_LANG_PROGRAM(
188               [[#ifndef __user
189                 #define __user
190                 #endif
191                 #include <sys/types.h>
192                 #include <linux/types.h>
193                 #include <sys/socket.h>
194                 #include <linux/nl80211.h>]],
195               [[int a = NL80211_RATE_INFO_BITRATE; a++;]])],
196         [ac_have_nl80211=yes],
197         [ac_have_nl80211=no])
198 AC_MSG_RESULT($ac_have_nl80211)
199 if test "$ac_have_nl80211" = no; then
200         AC_MSG_ERROR(Linux kernel development header linux/nl80211.h not installed or not functional)
201 fi
202
203 if test "$with_wifi" = "yes"; then
204         AC_MSG_CHECKING([Linux kernel nl80211 Critical Protocol Start/Stop])
205         AC_COMPILE_IFELSE(
206                 [AC_LANG_PROGRAM(
207                   [[#ifndef __user
208                     #define __user
209                     #endif
210                     #include <sys/types.h>
211                     #include <linux/types.h>
212                     #include <sys/socket.h>
213                     #include <linux/nl80211.h>]],
214                   [[unsigned int a = NL80211_CMD_CRIT_PROTOCOL_START; a++;]])],
215                 [ac_have_nl80211_critproto=yes],
216                 [ac_have_nl80211_critproto=no])
217         AC_MSG_RESULT($ac_have_nl80211_critproto)
218 else
219         ac_have_nl80211_critproto='no'
220 fi
221 if test "$ac_have_nl80211_critproto" = yes; then
222         AC_DEFINE(HAVE_NL80211_CRITICAL_PROTOCOL_CMDS, 1, [Define if nl80211 has critical protocol support])
223 else
224         AC_DEFINE(HAVE_NL80211_CRITICAL_PROTOCOL_CMDS, 0, [Define if nl80211 has critical protocol support])
225 fi
226
227 dnl
228 dnl Check for newer VLAN flags
229 dnl
230 AC_MSG_CHECKING([Linux kernel VLAN_FLAG_LOOSE_BINDING enum value])
231 AC_COMPILE_IFELSE(
232         [AC_LANG_PROGRAM(
233               [[#ifndef __user
234                 #define __user
235                 #endif
236                 #include <sys/types.h>
237                 #include <linux/types.h>
238                 #include <linux/if_vlan.h>]],
239               [[unsigned int a = VLAN_FLAG_LOOSE_BINDING;]])],
240         [ac_have_vlan_flag_loose_binding=yes],
241         [ac_have_vlan_flag_loose_binding=no])
242 AC_MSG_RESULT($ac_have_vlan_flag_loose_binding)
243 if test "$ac_have_vlan_flag_loose_binding" = yes; then
244         AC_DEFINE(HAVE_VLAN_FLAG_LOOSE_BINDING, 1, [Define if you have VLAN_FLAG_LOOSE_BINDING])
245 else
246         AC_DEFINE(HAVE_VLAN_FLAG_LOOSE_BINDING, 0, [Define if you have VLAN_FLAG_LOOSE_BINDING])
247 fi
248
249 dnl
250 dnl Checks for libm - needed for pow()
251 dnl
252 LT_LIB_M
253
254 dnl
255 dnl Checks for libdl - on certain platforms its part of libc
256 dnl
257 AC_CHECK_LIB([dl], [dladdr], LIBDL="-ldl", LIBDL="")
258 AC_SUBST(LIBDL)
259
260 dnl
261 dnl Checks for dbus-glib
262 dnl
263 PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.1 dbus-glib-1 >= 0.94)
264 AC_SUBST(DBUS_CFLAGS)
265 AC_SUBST(DBUS_LIBS)
266
267 AC_CHECK_LIB([dbus-glib-1], [dbus_g_method_invocation_get_g_connection], ac_have_gmi_get_con="1", ac_have_gmi_get_con="0")
268 AC_DEFINE_UNQUOTED(HAVE_DBUS_GLIB_GMI_GET_CONNECTION, $ac_have_gmi_get_con, [Define if you have a dbus-glib with dbus_g_method_invocation_get_g_connection()])
269
270 dnl
271 dnl Only dbus-glib >= 0.100 can use private dbus connections
272 dnl
273 PKG_CHECK_MODULES(DBUS_GLIB_100, [dbus-glib-1 >= 0.100], [have_dbus_glib_100=yes],[have_dbus_glib_100=no])
274 if (test "${have_dbus_glib_100}" = "yes"); then
275         AC_DEFINE(HAVE_DBUS_GLIB_100, 1, [Define if you have dbus-glib >= 0.100])
276 else
277         AC_DEFINE(HAVE_DBUS_GLIB_100, 0, [Define if you have dbus-glib >= 0.100])
278 fi
279 AM_CONDITIONAL(HAVE_DBUS_GLIB_100, test "${have_dbus_glib_100}" = "yes")
280
281 PKG_CHECK_MODULES(GLIB, [gio-unix-2.0 >= 2.37.6 gmodule-2.0],
282         [AC_SUBST(LOG_DRIVER, '$(top_srcdir)/build-aux/tap-driver.sh'),
283          AC_SUBST(AM_TESTS_FD_REDIRECT, '--tap')],
284         [PKG_CHECK_MODULES(GLIB, gio-unix-2.0 >= 2.32 gmodule-2.0)
285          AC_SUBST(LOG_DRIVER, '$(top_srcdir)/build-aux/test-driver')])
286
287 dnl GLIB_VERSION_MIN_REQUIRED should match the version above.
288 dnl GLIB_VERSION_MAX_ALLOWED should be set to the same version;
289 dnl nm-glib-compat.h will cause it to be overridden for the functions
290 dnl we have compat versions of.
291 GLIB_CFLAGS="$GLIB_CFLAGS -DGLIB_VERSION_MIN_REQUIRED=GLIB_VERSION_2_32 -DGLIB_VERSION_MAX_ALLOWED=GLIB_VERSION_2_32"
292
293 AC_SUBST(GLIB_CFLAGS)
294 AC_SUBST(GLIB_LIBS)
295
296 PKG_CHECK_MODULES(GUDEV, gudev-1.0 >= 165)
297 AC_SUBST(GUDEV_CFLAGS)
298 AC_SUBST(GUDEV_LIBS)
299
300 GOBJECT_INTROSPECTION_CHECK([0.9.6])
301
302 # Qt4
303 PKG_CHECK_MODULES(QT, [QtCore >= 4 QtDBus QtNetwork], [have_qt=yes],[have_qt=no])
304 AC_ARG_ENABLE(qt, AS_HELP_STRING([--enable-qt], [enable Qt examples]),
305                      [enable_qt=${enableval}], [enable_qt=${have_qt}])
306 if (test "${enable_qt}" = "yes"); then
307         if test x"$have_qt" = x"no"; then
308                 AC_MSG_ERROR(Qt development headers are required)
309         fi
310         AC_SUBST(QT_CFLAGS)
311         AC_SUBST(QT_LIBS)
312         # Check for moc-qt4 and if not found then moc
313         QT4_BINDIR=`$PKG_CONFIG QtCore --variable moc_location`
314         AC_CHECK_PROGS(MOC, [moc-qt4 moc],, [$QT4_BINDIR:$PATH])
315 fi
316 AM_CONDITIONAL(WITH_QT, test "${enable_qt}" = "yes")
317
318 AC_ARG_WITH(udev-dir, AS_HELP_STRING([--with-udev-dir=DIR], [Absolute path of the udev base directory. Set to 'no' not to install the udev rules]), [], [with_udev_dir="yes"])
319 if (test "$with_udev_dir" != 'no'); then
320         if (test "$with_udev_dir" != 'yes' && printf '%s' "$with_udev_dir" | grep -v -q '^/'); then
321                 AC_MSG_ERROR([--with-udev-dir must be an absolute path or 'yes' or 'no'. Instead it is '$with_udev_dir'])
322         fi
323         if (test "$with_udev_dir" = 'yes'); then
324                 with_udev_dir="/lib/udev"
325         fi
326         UDEV_DIR="$with_udev_dir"
327         AC_SUBST(UDEV_DIR)
328 fi
329 AM_CONDITIONAL(WITH_UDEV_DIR, test "$with_udev_dir" != 'no')
330
331 # systemd unit support
332 AC_ARG_WITH([systemdsystemunitdir], AS_HELP_STRING([--with-systemdsystemunitdir=DIR],
333         [Directory for systemd service files]))
334 # default location
335 AS_IF([test -z "$with_systemdsystemunitdir" && $PKG_CONFIG systemd],
336         with_systemdsystemunitdir="\$(prefix)/lib/systemd/system")
337 AS_IF([test -z "$with_systemdsystemunitdir"], with_systemdsystemunitdir=no)
338 # add conditional and subst
339 AM_CONDITIONAL(HAVE_SYSTEMD, [test "$with_systemdsystemunitdir" != no])
340 if test "$with_systemdsystemunitdir" != no; then
341         AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
342         AC_DEFINE(HAVE_SYSTEMD, 1, [Define if systemd support is available])
343 else
344         AC_DEFINE(HAVE_SYSTEMD, 0, [Define if systemd support is available])
345 fi
346
347 PKG_CHECK_MODULES(SYSTEMD_200, [systemd >= 200], [have_systemd_200=yes],[have_systemd_200=no])
348 AM_CONDITIONAL(HAVE_SYSTEMD_200, test "${have_systemd_200}" = "yes")
349
350 # Session tracking support
351 AC_ARG_WITH(systemd-logind, AS_HELP_STRING([--with-systemd-logind=yes|no],
352         [Support systemd session tracking]))
353 AC_ARG_WITH(consolekit, AS_HELP_STRING([--with-consolekit=yes|no],
354         [Support consolekit session tracking]))
355 AC_ARG_WITH(session-tracking, AS_HELP_STRING([--with-session-tracking=systemd|consolekit|no],
356         [Compatibility option to choose one session tracking module]))
357 # backwards compatibility
358 AS_IF([test "$with_session_tracking" = "ck"], [use_consolekit="yes" use_systemd_logind="no"])
359 AS_IF([test "$with_session_tracking" = "consolekit"], [use_consolekit="yes" use_systemd_logind="no"])
360 AS_IF([test "$with_session_tracking" = "systemd"], [use_consolekit="no" use_systemd_logind="yes"])
361 AS_IF([test "$with_session_tracking" = "no"], [use_consolekit="no" use_systemd_logind="no"])
362 AS_IF([test "$with_session_tracking" = "none"], [use_consolekit="no" use_systemd_logind="no"])
363 # current options
364 AS_IF([test -n "$with_systemd_logind" ], [use_systemd_logind="$with_systemd_logind"])
365 AS_IF([test -n "$with_consolekit" ], [use_consolekit="$with_consolekit"])
366 # defaults
367 AS_IF([test -z "$use_systemd_logind"], [use_systemd_logind="auto"])
368 AS_IF([test -z "$use_consolekit"], [use_consolekit="yes"])
369 # output
370 session_tracking=
371 if test "$use_systemd_logind" = "yes" -o "$use_systemd_logind" = "auto"; then
372     PKG_CHECK_MODULES(SYSTEMD_LOGIN, [libsystemd], [have_systemd_logind=yes], [PKG_CHECK_MODULES(SYSTEMD_LOGIN, [libsystemd-login], [have_systemd_logind=yes], [have_systemd_logind=no])])
373 else
374     have_systemd_logind=no
375 fi
376 if test "$use_systemd_logind" = "yes" -a "$have_systemd_logind" = "no"; then
377     AC_MSG_ERROR([You must have libsystemd installed to build with systemd-logind support.])
378 fi
379 if test "$have_systemd_logind" = "yes"; then
380         AC_SUBST(SYSTEMD_LOGIN_CFLAGS)
381         AC_SUBST(SYSTEMD_LOGIN_LIBS)
382         AC_DEFINE([SESSION_TRACKING_SYSTEMD], 1, [Define to 1 if libsystemd-login is available])
383         session_tracking="$session_tracking, systemd-logind"
384 fi
385 if test "$use_consolekit" = "yes"; then
386         AC_DEFINE([SESSION_TRACKING_CONSOLEKIT], 1, [Define to 1 if ConsoleKit is available])
387         AC_DEFINE([CKDB_PATH], "/var/run/ConsoleKit/database", [Path to ConsoleKit database])
388         session_tracking="$session_tracking, consolekit"
389 fi
390 session_tracking="$(printf '%s' "${session_tracking}" | sed 's/^, //')"
391
392 AC_ARG_WITH(suspend-resume, AS_HELP_STRING([--with-suspend-resume=upower|systemd], [Build NetworkManager with specific suspend/resume support]))
393 if test "z$with_suspend_resume" = "z"; then
394     PKG_CHECK_EXISTS([libsystemd >= 209], [have_systemd_inhibit=yes],
395                      [PKG_CHECK_EXISTS([libsystemd-login >= 183], [have_systemd_inhibit=yes], [have_systemd_inhibit=no])])
396     if test "z${have_systemd_inhibit}" = "zyes"; then
397         # Use systemd if it's new enough
398         with_suspend_resume="systemd"
399     else
400         # Fall back to upower
401         with_suspend_resume="upower"
402     fi
403 fi
404
405 case $with_suspend_resume in
406     upower) ;;
407     systemd)
408         PKG_CHECK_MODULES(SYSTEMD_INHIBIT, [libsystemd >= 209],,
409                           [PKG_CHECK_MODULES(SYSTEMD_INHIBIT, [libsystemd-login >= 183])])
410         ;;
411     *)
412         AC_MSG_ERROR(--with-suspend-resume must be one of [upower, systemd])
413         ;;
414 esac
415 AM_CONDITIONAL(SUSPEND_RESUME_UPOWER, test "x$with_suspend_resume" = "xupower")
416 AM_CONDITIONAL(SUSPEND_RESUME_SYSTEMD, test "x$with_suspend_resume" = "xsystemd")
417
418 # SELinux support
419 AC_ARG_WITH(selinux, AS_HELP_STRING([--with-selinux=yes|no|auto], [Build with SELinux (default: auto)]),,[with_selinux=auto])
420 if test "$with_selinux" = "yes" -o "$with_selinux" = "auto"; then
421     PKG_CHECK_MODULES(SELINUX, libselinux, [have_selinux=yes], [have_selinux=no])
422 else
423     have_selinux=no
424 fi
425 if test "$with_selinux" = "yes" -a "$have_selinux" = "no"; then
426     AC_MSG_ERROR([You must have libselinux installed to build --with-selinux=yes.])
427 fi
428 if test "$have_selinux" = "yes"; then
429     AC_DEFINE(HAVE_SELINUX, 1, [Define if you have SELinux support])
430 else
431     AC_DEFINE(HAVE_SELINUX, 0, [Define if you have SELinux support])
432 fi
433 AM_CONDITIONAL(HAVE_SELINUX, test "${have_selinux}" = "yes")
434
435 # libnl support for the linux platform
436 PKG_CHECK_MODULES(LIBNL, libnl-3.0 >= 3.2.8 libnl-route-3.0 libnl-genl-3.0)
437 AC_SUBST(LIBNL_CFLAGS)
438 AC_SUBST(LIBNL_LIBS)
439
440 AC_CHECK_LIB([nl-route-3], [rtnl_link_inet6_get_addr_gen_mode],
441         ac_have_addr_gen_mode="1",
442         ac_have_addr_gen_mode="0")
443 AC_DEFINE_UNQUOTED(HAVE_LIBNL_INET6_ADDR_GEN_MODE,
444         $ac_have_addr_gen_mode, [Define if libnl has rtnl_link_inet6_get_addr_gen_mode()])
445
446 AC_MSG_CHECKING([Linux kernel IN6_ADDR_GEN_MODE enum])
447 AC_COMPILE_IFELSE(
448         [AC_LANG_PROGRAM(
449               [[#ifndef __user
450                 #define __user
451                 #endif
452                 #include <linux/if_link.h>]],
453               [[int a = IN6_ADDR_GEN_MODE_EUI64; a++;]])],
454         [ac_have_kernel_gen_mode=yes],
455         [ac_have_kernel_gen_mode=no])
456 AC_MSG_RESULT($ac_have_kernel_gen_mode)
457 if test "$ac_have_kernel_gen_mode" = yes; then
458         AC_DEFINE(HAVE_KERNEL_INET6_ADDR_GEN_MODE, 1, [Define if the kernel has IN6_ADDR_GEN_MODE_*])
459 else
460         AC_DEFINE(HAVE_KERNEL_INET6_ADDR_GEN_MODE, 0, [Define if the kernel has IN6_ADDR_GEN_MODE_*])
461 fi
462
463 # IPv6 tokenized identifiers support in libnl
464 AC_CHECK_LIB([nl-route-3], [rtnl_link_inet6_get_token],
465         ac_have_ipv6_token="1",
466         ac_have_ipv6_token="0")
467 AC_DEFINE_UNQUOTED(HAVE_LIBNL_INET6_TOKEN,
468         $ac_have_ipv6_token, [Define if libnl has rtnl_link_inet6_get_token()])
469
470 # uuid library
471 PKG_CHECK_MODULES(UUID, uuid)
472 AC_SUBST(UUID_CFLAGS)
473 AC_SUBST(UUID_LIBS)
474
475 dnl Checks for readline library - used by nmcli
476 AX_LIB_READLINE
477
478 # Teamd control checks
479 PKG_CHECK_MODULES(LIBTEAMDCTL, [libteamdctl >= 1.9], [have_teamdctl=yes],[have_teamdctl=no])
480 AC_ARG_ENABLE(teamdctl, AS_HELP_STRING([--enable-teamdctl], [enable Teamd control support]),
481                      [enable_teamdctl=${enableval}], [enable_teamdctl=${have_teamdctl}])
482 if (test "${enable_teamdctl}" = "yes"); then
483         if test x"$have_teamdctl" = x"no"; then
484                 AC_MSG_ERROR(Teamd control is required)
485         fi
486
487         AC_SUBST(LIBTEAMDCTL_CFLAGS)
488         AC_SUBST(LIBTEAMDCTL_LIBS)
489         # temporary bug workaround
490         LIBTEAMDCTL_CFLAGS=`echo $LIBTEAMDCTL_CFLAGS | sed -e 's:/teamdctl.h::'`
491         AC_DEFINE(WITH_TEAMDCTL, 1, [Define if you have Teamd control support])
492 else
493         AC_DEFINE(WITH_TEAMDCTL, 0, [Define if you have Teamd control support])
494 fi
495 AM_CONDITIONAL(WITH_TEAMDCTL, test "${enable_teamdctl}" = "yes")
496
497 # we usually compile with polkit support. --enable-polkit=yes|no only sets the
498 # default configuration for main.auth-polkit. User can always enable/disable polkit
499 # autorization via config. Only when specifying --enable-polkit=disabled, we do
500 # not compile support. In this case, the user cannot enable polkit authorization via
501 # configuration.
502 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--enable-polkit=yes|no|disabled], [set default value for auth-polkit configuration option. This value can be overwritten by NM configuration. 'disabled' compiles NM without any support]),
503                      [enable_polkit=${enableval}], [enable_polkit=yes])
504 if (test "${enable_polkit}" != "no" -a "${enable_polkit}" != "disabled"); then
505         enable_polkit=yes
506         AC_DEFINE(NM_CONFIG_DEFAULT_AUTH_POLKIT, TRUE, [The default value of the auth-polkit configuration option])
507         NM_CONFIG_DEFAULT_AUTH_POLKIT_TEXT='true'
508 else
509         AC_DEFINE(NM_CONFIG_DEFAULT_AUTH_POLKIT, FALSE, [The default value of the auth-polkit configuration option])
510         NM_CONFIG_DEFAULT_AUTH_POLKIT_TEXT='false'
511 fi
512 if (test "${enable_polkit}" != "disabled"); then
513         AC_DEFINE(WITH_POLKIT, 1, [whether to compile polkit support])
514 else
515         AC_DEFINE(WITH_POLKIT, 0, [whether to compile polkit support])
516 fi
517 AC_SUBST(NM_CONFIG_DEFAULT_AUTH_POLKIT_TEXT)
518
519 PKG_CHECK_MODULES(POLKIT, [polkit-agent-1 >= 0.97], [have_pk_agent=yes],[have_pk_agent=no])
520 AC_ARG_ENABLE(polkit-agent, AS_HELP_STRING([--enable-polkit-agent], [enable polkit agent for clients]),
521                      [enable_polkit_agent=${enableval}], [enable_polkit_agent=${have_pk_agent}])
522 if (test "${enable_polkit_agent}" = "yes"); then
523         if test x"$have_pk_agent" = x"no"; then
524                 AC_MSG_ERROR(Polkit agent is required)
525         fi
526
527         AC_SUBST(POLKIT_CFLAGS)
528         AC_SUBST(POLKIT_LIBS)
529         AC_DEFINE(WITH_POLKIT_AGENT, 1, [Define if you have polkit agent])
530 else
531         AC_DEFINE(WITH_POLKIT_AGENT, 0, [Define if you have polkit agent])
532 fi
533 AM_CONDITIONAL(WITH_POLKIT_AGENT, test "${enable_polkit_agent}" = "yes")
534
535 AC_ARG_ENABLE(modify-system,
536               AS_HELP_STRING([--enable-modify-system], [Allow users to modify system connections]))
537 if test "${enable_modify_system}" = "yes"; then
538         NM_MODIFY_SYSTEM_POLICY="yes"
539 else
540         NM_MODIFY_SYSTEM_POLICY="auth_admin_keep"
541 fi
542 AC_SUBST(NM_MODIFY_SYSTEM_POLICY)
543
544 AC_ARG_WITH(crypto, AS_HELP_STRING([--with-crypto=nss|gnutls], [Cryptography library to use for certificate and key operations]),ac_crypto=$withval, ac_crypto=nss)
545
546 with_nss=no
547 with_gnutls=no
548 if test x"$ac_crypto" = xnss; then
549   PKG_CHECK_MODULES(NSS, [nss >= 3.11])
550
551   # Work around a pkg-config bug (fdo #29801) where exists != usable
552   FOO=`$PKG_CONFIG --cflags --libs nss`
553   if test x"$?" != "x0"; then
554     AC_MSG_ERROR([No usable NSS found])
555   fi
556
557   AC_SUBST(NSS_CFLAGS)
558   AC_SUBST(NSS_LIBS)
559   AC_DEFINE(HAVE_NSS, 1, [Define if you have NSS])
560   with_nss=yes
561 elif test x"$ac_crypto" = xgnutls; then
562   PKG_CHECK_MODULES(GNUTLS, [gnutls >= 2.12])
563   AC_DEFINE(HAVE_GNUTLS, 1, [Define if you have libgnutls])
564   AC_SUBST(GNUTLS_CFLAGS)
565   AC_SUBST(GNUTLS_LIBS)
566   with_gnutls=yes
567 else
568   AC_MSG_ERROR([Please choose either 'nss' or 'gnutls' for certificate and crypto operations])
569 fi
570 AM_CONDITIONAL(WITH_NSS, test x"$with_nss" != xno)
571 AM_CONDITIONAL(WITH_GNUTLS, test x"$with_gnutls" != xno)
572
573 # Shouldn't ever trigger this, but just in case...
574 if test x"$ac_nss" = xno -a x"$ac_gnutls" = xno; then
575   AC_MSG_ERROR([Could not find required development headers and libraries for '$ac_crypto'])
576 fi
577
578 GLIB_MAKEFILE='$(top_srcdir)/Makefile.glib'
579 AC_SUBST(GLIB_MAKEFILE)
580 GLIB_GENMARSHAL=`pkg-config --variable=glib_genmarshal glib-2.0`
581 AC_SUBST(GLIB_GENMARSHAL)
582 GLIB_MKENUMS=`pkg-config --variable=glib_mkenums glib-2.0`
583 AC_SUBST(GLIB_MKENUMS)
584
585 AC_ARG_WITH(dbus-sys-dir, AS_HELP_STRING([--with-dbus-sys-dir=DIR], [where D-BUS system.d directory is]))
586
587 if test -n "$with_dbus_sys_dir" ; then
588     DBUS_SYS_DIR="$with_dbus_sys_dir"
589 else
590     DBUS_SYS_DIR="${sysconfdir}/dbus-1/system.d"
591 fi
592 AC_SUBST(DBUS_SYS_DIR)
593
594 # pppd
595 AC_ARG_ENABLE(ppp, AS_HELP_STRING([--enable-ppp], [enable PPP/PPPoE support]),
596                      [enable_ppp=${enableval}], [enable_ppp=yes])
597 if (test "${enable_ppp}" = "yes"); then
598         AC_CHECK_HEADERS(pppd/pppd.h,,
599                 AC_MSG_ERROR("couldn't find pppd.h. pppd development headers are required."))
600
601         AC_DEFINE(WITH_PPP, 1, [Define if you have PPP support])
602 else
603         AC_DEFINE(WITH_PPP, 0, [Define if you have PPP support])
604 fi
605 AM_CONDITIONAL(WITH_PPP, test "${enable_ppp}" = "yes")
606
607 AC_ARG_WITH([pppd-plugin-dir], AS_HELP_STRING([--with-pppd-plugin-dir=DIR], [path to the pppd plugins directory]))
608
609 if test -n "$with_pppd_plugin_dir" ; then
610         PPPD_PLUGIN_DIR="$with_pppd_plugin_dir"
611 else
612         PPPD_PLUGIN_DIR="${libdir}/pppd/2.4.5"
613 fi
614 AC_SUBST(PPPD_PLUGIN_DIR)
615
616 AC_ARG_WITH(pppd, AS_HELP_STRING([--with-pppd=/path/to/pppd], [path to pppd binary]))
617 if test "x${with_pppd}" = x; then
618   AC_PATH_PROG(PPPD_PATH, pppd, [], $PATH:/sbin:/usr/sbin)
619 else
620   PPPD_PATH="$with_pppd"
621 fi
622 AC_DEFINE_UNQUOTED(PPPD_PATH, "$PPPD_PATH", [Define to path of pppd binary])
623 AC_SUBST(PPPD_PATH)
624
625 # ModemManager1 with libmm-glib
626 AC_ARG_WITH(modem-manager-1, AS_HELP_STRING([--with-modem-manager-1], [Enable new ModemManager1 interface support]),,[with_modem_manager_1=auto])
627 if (test "${with_modem_manager_1}" != "no"); then
628     PKG_CHECK_MODULES(MM_GLIB,
629                       [mm-glib >= 0.7.991],
630                       [have_libmm_glib=yes],
631                       [have_libmm_glib=no])
632     AC_SUBST(MM_GLIB_CFLAGS)
633     AC_SUBST(MM_GLIB_LIBS)
634
635     if (test "${have_libmm_glib}" = "no"); then
636         if (test "${with_modem_manager_1}" = "yes"); then
637             AC_MSG_ERROR([Couldn't find libmm-glib])
638         else
639             with_modem_manager_1="no"
640         fi
641     else
642         with_modem_manager_1="yes"
643     fi
644 fi
645
646 if (test "${with_modem_manager_1}" = "yes"); then
647     AC_DEFINE(WITH_MODEM_MANAGER_1, 1, [Define if you have ModemManager1 support])
648 else
649         AC_DEFINE(WITH_MODEM_MANAGER_1, 0, [Define if you have ModemManager1 support])
650 fi
651 AM_CONDITIONAL(WITH_MODEM_MANAGER_1, test "${with_modem_manager_1}" = "yes")
652
653 # Bluez5 DUN support
654 PKG_CHECK_MODULES(BLUEZ5, [bluez >= 5], [have_bluez5=yes],[have_bluez5=no])
655 AC_ARG_ENABLE(bluez5-dun, AS_HELP_STRING([--enable-bluez5-dun], [enable Bluez5 DUN support]),
656                 [enable_bluez5_dun=${enableval}], [enable_bluez5_dun=${have_bluez5}])
657 if (test "${enable_bluez5_dun}" = "yes"); then
658         if test x"$have_bluez5" = x"no"; then
659                 AC_MSG_ERROR(Bluez 5.x development headers are required)
660         fi
661         AC_DEFINE(WITH_BLUEZ5_DUN, 1, [Define if you have Bluez 5 libraries])
662 else
663         AC_DEFINE(WITH_BLUEZ5_DUN, 0, [Define if you have Bluez 5 libraries])
664 fi
665 AM_CONDITIONAL(WITH_BLUEZ5_DUN, test "${enable_bluez5_dun}" = "yes")
666
667 # DHCP client support
668 AC_ARG_WITH([dhclient], AS_HELP_STRING([--with-dhclient=yes|no|path], [Enable dhclient 4.x support]))
669 AC_ARG_WITH([dhcpcd], AS_HELP_STRING([--with-dhcpcd=yes|no|path], [Enable dhcpcd 4.x support]))
670 # Default to "yes"
671 AS_IF([test -z "$with_dhclient"], with_dhclient=yes)
672 AS_IF([test -z "$with_dhcpcd"], with_dhcpcd=yes)
673 # Search and check the executables
674 if test "$with_dhclient" = "yes"; then
675         AC_PATH_PROGS(with_dhclient, dhclient, no, /sbin:/usr/sbin:/usr/local/sbin)
676         if test "$with_dhclient" != "no"; then
677                 if ! $with_dhclient --version 2>&1 | grep -q "^isc-dhclient-4\."; then
678                         AC_MSG_WARN([Cannot use dhclient, version 4.x is required])
679                         with_dhclient=no
680                 fi
681         fi
682 fi
683 if test "$with_dhcpcd" = "yes"; then
684         AC_PATH_PROGS(with_dhcpcd, dhcpcd, no, /sbin:/usr/sbin:/usr/local/sbin)
685         if test "$with_dhcpcd" != "no"; then
686                 if ! $with_dhcpcd --version 2>&1 | grep -q "^dhcpcd [[456789]]\."; then
687                         AC_MSG_WARN([Cannot use dhcpcd, version 4.x or higher is required])
688                         with_dhcpcd=no
689                 elif $with_dhcpcd --version 2>&1 | grep -q "^dhcpcd [[6789]]\."; then
690                         AC_DEFINE(DHCPCD_SUPPORTS_IPV6, 1, [Define if dhcpcd supports IPv6 (6.x+)])
691                 fi
692         fi
693 fi
694 # Fallback
695 if test "$with_dhclient" = "no" -a "$with_dhcpcd" = "no"; then
696         AC_MSG_WARN([Could not find a suitable DHCP client, falling back to dhclient])
697         with_dhclient=/sbin/dhclient
698 fi
699 # Add substitutions
700 if test "$with_dhclient" != "no"; then
701         AC_DEFINE(WITH_DHCLIENT, TRUE, [Define if you have dhclient])
702         AC_SUBST(DHCLIENT_PATH, $with_dhclient)
703 else
704         AC_DEFINE(WITH_DHCLIENT, FALSE, [Define if you have dhclient])
705 fi
706 if test "$with_dhcpcd" != "no"; then
707         AC_DEFINE(WITH_DHCPCD, TRUE, [Define if you have dhcpcd])
708         AC_SUBST(DHCPCD_PATH, $with_dhcpcd)
709 else
710         AC_DEFINE(WITH_DHCPCD, FALSE, [Define if you have dhcpcd])
711 fi
712
713 # resolvconf and netconfig support
714 AC_ARG_WITH(resolvconf, AS_HELP_STRING([--with-resolvconf=yes|no|path], [Enable resolvconf support]))
715 AC_ARG_WITH(netconfig, AS_HELP_STRING([--with-netconfig=yes|no], [Enable SUSE netconfig support]))
716 # Use netconfig by default on SUSE
717 AS_IF([test -z "$with_netconfig"], AC_CHECK_FILE(/etc/SuSE-release, with_netconfig=yes))
718 # Otherwise default to "no"
719 AS_IF([test -z "$with_resolvconf"], with_resolvconf=no)
720 AS_IF([test -z "$with_netconfig"], with_netconfig=no)
721 # Find resolvconf and netconfig
722 if test "$with_resolvconf" = "yes"; then
723         AC_PATH_PROGS(with_resolvconf, resolvconf, no, /sbin:/usr/sbin:/usr/local/sbin)
724 fi
725 if test "$with_netconfig" = "yes"; then
726         AC_PATH_PROGS(with_netconfig, netconfig, no, /sbin:/usr/sbin:/usr/local/sbin)
727 fi
728 # Define resolvconf and netconfig paths
729 if test "$with_resolvconf" != "no"; then
730         AC_DEFINE_UNQUOTED(RESOLVCONF_PATH, "$with_resolvconf", [Path to resolvconf])
731 fi
732 if test "$with_netconfig" != "no"; then
733         AC_DEFINE_UNQUOTED(NETCONFIG_PATH, "$with_netconfig", [Path to netconfig])
734 fi
735
736 # iptables path
737 AC_ARG_WITH(iptables, AS_HELP_STRING([--with-iptables=/path/to/iptables], [path to iptables]))
738 if test "x${with_iptables}" = x; then
739   AC_PATH_PROG(IPTABLES_PATH, iptables, [], $PATH:/sbin:/usr/sbin)
740   if ! test -x "$IPTABLES_PATH"; then
741         AC_MSG_ERROR(iptables was not installed.)
742   fi
743 else
744   IPTABLES_PATH="$with_iptables"
745 fi
746 AC_DEFINE_UNQUOTED(IPTABLES_PATH, "$IPTABLES_PATH", [Define to path of iptables binary])
747 AC_SUBST(IPTABLES_PATH)
748
749 # dnsmasq path
750 AC_ARG_WITH(dnsmasq, AS_HELP_STRING([--with-dnsmasq=/path/to/dnsmasq], [path to dnsmasq]))
751 if test "x${with_dnsmasq}" = x; then
752   AC_PATH_PROG(DNSMASQ_PATH, dnsmasq, [], $PATH:/sbin:/usr/sbin)
753 else
754   DNSMASQ_PATH="$with_dnsmasq"
755 fi
756 AC_DEFINE_UNQUOTED(DNSMASQ_PATH, "$DNSMASQ_PATH", [Define to path of dnsmasq binary])
757 AC_SUBST(DNSMASQ_PATH)
758
759 # system CA certificates path
760 AC_ARG_WITH(system-ca-path, AS_HELP_STRING([--with-system-ca-path=/path/to/ssl/certs], [path to system CA certificates])) 
761 if test "x${with_system_ca_path}" = x; then
762   SYSTEM_CA_PATH=/etc/ssl/certs
763 else
764   SYSTEM_CA_PATH="$with_system_ca_path"
765 fi
766 AC_DEFINE_UNQUOTED(SYSTEM_CA_PATH, "$SYSTEM_CA_PATH", [Define to path to system CA certificates])
767 AC_SUBST(SYSTEM_CA_PATH)
768
769 AC_ARG_WITH(kernel-firmware-dir, AS_HELP_STRING([--with-kernel-firmware-dir=DIR], [where kernel firmware directory is (default is /lib/firmware)]))
770
771 if test -n "$with_kernel_firmware_dir" ; then
772     KERNEL_FIRMWARE_DIR="$with_kernel_firmware_dir"
773 else
774     KERNEL_FIRMWARE_DIR="/lib/firmware"
775 fi
776 AC_DEFINE_UNQUOTED(KERNEL_FIRMWARE_DIR, "$KERNEL_FIRMWARE_DIR", [Define to path of the kernel firmware directory])
777 AC_SUBST(KERNEL_FIRMWARE_DIR)
778
779 PKG_CHECK_MODULES(LIBSOUP, [libsoup-2.4 >= 2.26], [have_libsoup=yes],[have_libsoup=no])
780 AC_ARG_WITH(libsoup, AS_HELP_STRING([--with-libsoup=yes|no], [Link against libsoup]), [], [with_libsoup=${have_libsoup}])
781 if test "$with_libsoup" != "no"; then
782         if test "$have_libsoup" != "yes"; then
783                 AC_MSG_ERROR(libsoup library not found)
784         fi
785         with_libsoup='yes'
786         AC_DEFINE(WITH_LIBSOUP, 1, [Define if you have libsoup])
787 else
788         AC_DEFINE(WITH_LIBSOUP, 0, [Define if you have libsoup])
789 fi
790 AM_CONDITIONAL(WITH_LIBSOUP, test "$with_libsoup" != "no")
791
792 AC_ARG_ENABLE(concheck, AS_HELP_STRING([--enable-concheck], [enable connectivity checking support]),
793                      [enable_concheck=${enableval}], [enable_concheck=${with_libsoup}])
794 if (test "${enable_concheck}" = "yes"); then
795         if test x"$with_libsoup" = x"no"; then
796                 AC_MSG_ERROR(Connectivity checking requires libsoup)
797         fi
798         AC_SUBST(LIBSOUP_CFLAGS)
799         AC_SUBST(LIBSOUP_LIBS)
800         AC_DEFINE(WITH_CONCHECK, 1, [Define if you want connectivity checking support])
801 else
802         AC_DEFINE(WITH_CONCHECK, 0, [Define if you want connectivity checking support])
803 fi
804 AM_CONDITIONAL(WITH_CONCHECK, test "${enable_concheck}" = "yes")
805
806 PKG_CHECK_MODULES(LIBNDP, [libndp])
807
808 AC_ARG_WITH(nmtui, AS_HELP_STRING([--with-nmtui=yes|no], [Build nmtui]))
809 if test "$with_nmtui" != no; then
810     PKG_CHECK_MODULES(NEWT, [libnewt >= 0.52.15], [build_nmtui=yes], [build_nmtui=no])
811 else
812     build_nmtui=no
813 fi
814 if test "$with_nmtui" = yes -a "$build_nmtui" = no; then
815     AC_MSG_ERROR([You must have libnewt installed to build nmtui.])
816 fi
817 AM_CONDITIONAL(BUILD_NMTUI, test "$build_nmtui" = yes)
818
819
820 NM_COMPILER_WARNINGS
821
822 AC_ARG_ENABLE(more-asserts,
823               AS_HELP_STRING([--enable-more-asserts], [Enable more assertions for debugging (default: no)]))
824 if test "${enable_more_asserts}" = "yes"; then
825     AC_DEFINE(NM_MORE_ASSERTS, [1], [Define if more asserts are enabled])
826 fi
827
828 AC_ARG_ENABLE(more-logging,
829               AS_HELP_STRING([--enable-more-logging], [Enable more debug logging (default: no)]))
830 if test "${enable_more_logging}" = "yes"; then
831     AC_DEFINE(NM_MORE_LOGGING, [1], [Define if more asserts are enabled])
832 fi
833
834 AC_ARG_ENABLE(lto, AS_HELP_STRING([--enable-lto], [Enable Link Time Optimization for smaller size (default: no)]))
835 if (test "${enable_lto}" = "yes"); then
836     CFLAGS="-flto $CFLAGS"
837 else
838     enable_lto='no'
839 fi
840
841
842 dnl -------------------------
843 dnl Vala bindings
844 dnl -------------------------
845
846 VAPIGEN_CHECK(0.17.1.24)
847
848 # Tests, utilities and documentation
849 AC_ARG_ENABLE(tests, AS_HELP_STRING([--enable-tests=root|yes|no], [Build NetworkManager tests (default: yes)]))
850 AC_ARG_WITH(valgrind, AS_HELP_STRING([--with-valgrind=yes|no|path], [Use valgrind to memory-check the tests (default: no)]))
851 # Fallback to --with-tests
852 AC_ARG_WITH(tests, AS_HELP_STRING([--with-tests], [Build NetworkManager tests (deprecated)]))
853 AS_IF([test -n "$with_tests"], enable_tests="$with_tests")
854 # Default to --enable-tests --with-valgrind=no
855 AS_IF([test -z "$enable_tests"], enable_tests="yes")
856 AS_IF([test -z "$with_valgrind"], with_valgrind="no")
857 # Normalize values
858 AS_IF([test "$enable_tests" != "yes" -a "$enable_tests" != "root"], enable_tests="no")
859 # Search for tools
860 AS_IF([test "$with_valgrind" == "yes"],
861         [AC_PATH_PROGS(with_valgrind, valgrind, no)])
862 # Add conditionals and substitutions
863 AM_CONDITIONAL(ENABLE_TESTS, test "$enable_tests" != "no")
864 AM_CONDITIONAL(REQUIRE_ROOT_TESTS, test "$enable_tests" == "root")
865 AC_ARG_WITH(valgrind-suppressions, AS_HELP_STRING([--with-valgrind-suppressions=path], [Use specific valgrind suppression file]))
866 if test "$with_valgrind" == no; then
867         with_valgrind_suppressions=
868 else
869         if test  "$with_valgrind_suppressions" == ""; then
870                 with_valgrind_suppressions='$(top_srcdir)/valgrind.suppressions'
871         fi
872 fi
873 AS_IF([test "$with_valgrind" != "no"],
874         AC_SUBST(VALGRIND_RULES, 'LOG_COMPILER = "$(top_srcdir)/tools/run-test-valgrind.sh" "$(LIBTOOL)" "$(with_valgrind)" '"$with_valgrind_suppressions"),
875         AC_SUBST(VALGRIND_RULES, []))
876 AM_CONDITIONAL(WITH_VALGRIND, test "${with_valgrind}" != "no")
877
878 GTK_DOC_CHECK(1.0)
879
880 # check for pregenerated manpages to be installed
881 install_pregen_manpages=no
882 if test "$enable_gtk_doc" != "yes" \
883         -a -f man/NetworkManager.conf.5 \
884         -a -f man/nm-settings.5 \
885         -a -f man/nm-settings-keyfile.5 \
886         -a -f man/nm-settings-ifcfg-rh.5 \
887         -a -f man/nmcli-examples.5 \
888         -a -f man/NetworkManager.8; then
889         install_pregen_manpages=yes
890 fi
891 AM_CONDITIONAL(INSTALL_PREGEN_MANPAGES, test "x${install_pregen_manpages}" = "xyes")
892
893 # check if we can build setting property documentation
894 if test -n "$INTROSPECTION_MAKEFILE" -a "$enable_gtk_doc" = "yes"; then
895     # If g-i is installed we know we have python, but we might not have pygobject
896     if python -c 'from gi.repository import GObject' >& /dev/null; then
897         have_pyobject=yes
898     fi
899
900     # gtk-doc depends on perl, but we can check for it anyway
901     AC_PATH_PROG(PERL, perl, no)
902     # check for needed perl modules (use YAML; YAML::XS is better, but may not be so widespread)
903     required_perl_modules="YAML"
904     for module in $required_perl_modules; do
905       AC_MSG_CHECKING([checking for perl module '$module'])
906       if ${PERL} -e 'use '$module 2>/dev/null ; then
907           AC_MSG_RESULT([Ok])
908           have_perl_modules=yes
909       else
910           AC_MSG_RESULT([Failed])
911           AC_MSG_ERROR([You must have Perl modules to build settings plugin docs: $required_perl_modules.])
912       fi
913     done
914
915     if test "$have_pyobject" = "yes" -a "$have_perl_modules" = "yes"; then
916         AC_DEFINE(BUILD_SETTING_DOCS, [1], [Define if you we can build nm-setting-docs.xml, nm-keyfile-docs.xml and nm-ifcfg-rh-docs.xml])
917         build_setting_docs=yes
918     fi
919 fi
920
921 # check for pre-built setting docs
922 if test "$build_setting_docs" != "yes" \
923         -a -f man/nm-settings.xml \
924         -a -f man/nm-settings-keyfile.xml \
925         -a -f man/nm-settings-ifcfg-rh.xml \
926         -a -f docs/api/settings-spec.xml \
927         -a -f clients/cli/settings-docs.c; then
928     AC_DEFINE(HAVE_SETTING_DOCS, [1], [Define if you have pre-built settings docs])
929     have_setting_docs=yes
930 fi
931
932 AM_CONDITIONAL(BUILD_SETTING_DOCS, test "$build_setting_docs" = "yes")
933 AM_CONDITIONAL(SETTING_DOCS_AVAILABLE, test "$build_setting_docs" = "yes" -o "$have_setting_docs" = "yes")
934
935
936 AC_CONFIG_FILES([
937 Makefile
938 include/Makefile
939 src/Makefile
940 src/tests/Makefile
941 src/tests/config/Makefile
942 src/dhcp-manager/Makefile
943 src/dhcp-manager/tests/Makefile
944 src/dnsmasq-manager/tests/Makefile
945 src/supplicant-manager/tests/Makefile
946 src/ppp-manager/Makefile
947 src/settings/plugins/Makefile
948 src/settings/plugins/ifupdown/Makefile
949 src/settings/plugins/ifupdown/tests/Makefile
950 src/settings/plugins/ifnet/Makefile
951 src/settings/plugins/ifnet/tests/Makefile
952 src/settings/plugins/ifcfg-rh/Makefile
953 src/settings/plugins/ifcfg-rh/tests/Makefile
954 src/settings/plugins/ifcfg-rh/tests/network-scripts/Makefile
955 src/settings/plugins/ibft/Makefile
956 src/settings/plugins/ibft/tests/Makefile
957 src/settings/plugins/ifcfg-suse/Makefile
958 src/settings/plugins/keyfile/Makefile
959 src/settings/plugins/keyfile/tests/Makefile
960 src/settings/plugins/keyfile/tests/keyfiles/Makefile
961 src/settings/plugins/example/Makefile
962 src/platform/Makefile
963 src/platform/tests/Makefile
964 src/rdisc/Makefile
965 src/rdisc/tests/Makefile
966 src/devices/adsl/Makefile
967 src/devices/bluetooth/Makefile
968 src/devices/team/Makefile
969 src/devices/wifi/Makefile
970 src/devices/wifi/tests/Makefile
971 src/devices/wwan/Makefile
972 libnm-core/nm-version.h
973 libnm-core/Makefile
974 libnm-core/tests/Makefile
975 libnm/libnm.pc
976 libnm/Makefile
977 libnm/tests/Makefile
978 libnm-util/libnm-util.pc
979 libnm-util/nm-version.h
980 libnm-util/Makefile
981 libnm-util/tests/Makefile
982 libnm-glib/libnm-glib.pc
983 libnm-glib/libnm-glib-vpn.pc
984 libnm-glib/Makefile
985 libnm-glib/tests/Makefile
986 callouts/Makefile
987 callouts/tests/Makefile
988 tools/Makefile
989 clients/Makefile
990 clients/cli/Makefile
991 clients/tui/Makefile
992 clients/tui/newt/Makefile
993 initscript/RedHat/NetworkManager
994 initscript/Debian/NetworkManager
995 initscript/Slackware/rc.networkmanager
996 initscript/SUSE/networkmanager
997 initscript/Arch/networkmanager
998 initscript/Mandriva/networkmanager
999 initscript/linexa/networkmanager
1000 introspection/Makefile
1001 introspection/all.xml
1002 man/Makefile
1003 man/NetworkManager.conf.xml
1004 man/nm-system-settings.conf.5
1005 man/nm-online.1
1006 man/nmcli.1
1007 man/nmtui.1
1008 po/Makefile.in
1009 policy/Makefile
1010 policy/org.freedesktop.NetworkManager.policy.in
1011 data/Makefile
1012 docs/Makefile
1013 docs/api/Makefile
1014 docs/api/version.xml
1015 docs/libnm-glib/Makefile
1016 docs/libnm-glib/version.xml
1017 docs/libnm-util/Makefile
1018 docs/libnm-util/version.xml
1019 docs/libnm/Makefile
1020 docs/libnm/version.xml
1021 NetworkManager.pc
1022 examples/Makefile
1023 examples/shell/Makefile
1024 examples/python/Makefile
1025 examples/python/dbus/Makefile
1026 examples/python/gi/Makefile
1027 examples/ruby/Makefile
1028 examples/lua/Makefile
1029 examples/lua/lgi/Makefile
1030 examples/C/Makefile
1031 examples/C/glib/Makefile
1032 examples/C/qt/Makefile
1033 examples/dispatcher/Makefile
1034 vapi/Makefile
1035 ])
1036 AC_CONFIG_SUBDIRS([libndp])
1037 AC_OUTPUT
1038
1039 # Print build configuration
1040 echo
1041 echo "System paths:"
1042 echo "  prefix: $prefix"
1043 echo "  exec_prefix: $exec_prefix"
1044 echo "  systemdunitdir: $with_systemdsystemunitdir"
1045 echo "  nmbinary: $nmbinary"
1046 echo "  nmconfdir: $nmconfdir"
1047 echo "  nmdatadir: $nmdatadir"
1048 echo "  nmstatedir: $nmstatedir"
1049 echo "  nmrundir: $nmrundir"
1050 echo
1051
1052 echo "Platform:"
1053 echo "  session tracking: $session_tracking"
1054 echo "  suspend/resume: $with_suspend_resume"
1055 if test "${enable_polkit}" = "yes"; then
1056         if test "${enable_modify_system}" = "yes"; then
1057                 echo "  policykit: yes (permissive modify.system) (default=${enable_polkit})"
1058         else
1059                 echo "  policykit: yes (restrictive modify.system) (default=${enable_polkit})"
1060         fi
1061 else
1062         echo  "  policykit: no"
1063 fi
1064 echo "  polkit agent: ${enable_polkit_agent}"
1065 echo "  selinux: $have_selinux"
1066 echo
1067
1068 echo "Features:"
1069 echo "  wext: $ac_with_wext"
1070 echo "  wifi: $enable_wifi"
1071 echo "  ppp: $enable_ppp"
1072 echo "  modemmanager-1: $with_modem_manager_1"
1073 echo "  concheck: $enable_concheck"
1074 echo "  libteamdctl: $enable_teamdctl"
1075 echo "  nmtui: $build_nmtui"
1076 echo
1077
1078 echo "Configuration plugins (main.plugins=${config_plugins_default})"
1079 echo "  ibft: ${enable_config_plugin_ibft}"
1080 echo "  ifcfg-rh: ${enable_ifcfg_rh}"
1081 echo "  ifcfg-suse: ${enable_ifcfg_suse}"
1082 echo "  ifupdown: ${enable_ifupdown}"
1083 echo "  ifnet: ${enable_ifnet}"
1084 echo
1085
1086 echo "Handlers for /etc/resolv.conf:"
1087 echo "  resolvconf: ${with_resolvconf}"
1088 echo "  netconfig: ${with_netconfig}"
1089 echo
1090
1091 echo "DHCP clients:"
1092 echo "  dhclient: $with_dhclient"
1093 echo "  dhcpcd: $with_dhcpcd"
1094 echo
1095
1096 echo "Miscellaneous:"
1097 echo "  documentation: $enable_gtk_doc"
1098 echo "  tests: $enable_tests"
1099 echo "  valgrind: $with_valgrind   $with_valgrind_suppressions"
1100 echo "  code coverage: $enable_code_coverage"
1101 echo "  LTO: $enable_lto"
1102 echo