configure.ac

   1 AC_PREREQ([2.63])
   2
   3 dnl The NM version number
   4 m4_define([nm_major_version], [1])
   5 m4_define([nm_minor_version], [1])
   6 m4_define([nm_micro_version], [0])
   7 m4_define([nm_version],
   8           [nm_major_version.nm_minor_version.nm_micro_version])
   9 m4_define([nm_git_sha], [m4_esyscmd([ ( [ -d ./.git/ ] && [ "$(readlink -f ./.git/)" = "$(readlink -f "$(git rev-parse --git-dir 2>/dev/null)" 2>/dev/null)" ] && git rev-parse --verify -q HEAD 2>/dev/null ) || true ])])
  10
  11 AC_INIT([NetworkManager], [nm_version],
  12         [http://bugzilla.gnome.org/enter_bug.cgi?product=NetworkManager],
  13         [NetworkManager])
  14
  15 AC_CONFIG_HEADERS([config.h])
  16 AC_CONFIG_MACRO_DIR([m4])
  17 AC_CONFIG_AUX_DIR([build-aux])
  18 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  19
  20 AM_INIT_AUTOMAKE(1.12 tar-ustar no-dist-gzip dist-bzip2 -Wno-portability)  dnl NB: Do not [quote] this parameter.
  21 AM_MAINTAINER_MODE([enable])
  22 AM_SILENT_RULES([yes])
  23
  24 dnl Define _SYSTEM_EXTENSIONS for various things like strcasestr()
  25 AC_USE_SYSTEM_EXTENSIONS
  26
  27 dnl
  28 dnl Require programs
  29 dnl
  30 AC_PROG_CC
  31 AM_PROG_CC_C_O
  32
  33 # C++ only required if --enable-qt=yes
  34 AC_PROG_CXX
  35
  36 dnl Initialize libtool
  37 LT_PREREQ([2.2])
  38 LT_INIT([disable-static])
  39
  40 dnl Version stuff
  41 NM_MAJOR_VERSION=nm_major_version
  42 NM_MINOR_VERSION=nm_minor_version
  43 NM_MICRO_VERSION=nm_micro_version
  44 NM_VERSION=nm_version
  45 NM_GIT_SHA=nm_git_sha
  46 AC_SUBST(NM_MAJOR_VERSION)
  47 AC_SUBST(NM_MINOR_VERSION)
  48 AC_SUBST(NM_MICRO_VERSION)
  49 AC_SUBST(NM_VERSION)
  50 AC_DEFINE_UNQUOTED(NM_GIT_SHA,"$NM_GIT_SHA",[git commit id of the original source code version])
  51
  52 dnl
  53 dnl Checks for typedefs, structures, and compiler characteristics.
  54 dnl
  55 AC_TYPE_PID_T
  56
  57 dnl
  58 dnl translation support
  59 dnl
  60 IT_PROG_INTLTOOL([0.40.0])
  61
  62 AM_GNU_GETTEXT([external])
  63 AM_GNU_GETTEXT_VERSION([0.17])
  64
  65 GETTEXT_PACKAGE=NetworkManager
  66 AC_SUBST(GETTEXT_PACKAGE)
  67 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [Gettext package])
  68
  69 dnl
  70 dnl Make sha1.c happy on big endian systems
  71 dnl
  72 AC_C_BIGENDIAN
  73
  74 # Add runstatedir if not specified manually in autoconf < 2.70
  75 AS_IF([test -z "$runstatedir"], runstatedir="$localstatedir/run")
  76 AC_SUBST(runstatedir)
  77
  78 # NetworkManager paths
  79 AC_SUBST(nmbinary, "$sbindir/$PACKAGE", [NetworkManager binary executable])
  80 AC_SUBST(nmconfdir, "$sysconfdir/$PACKAGE", [NetworkManager configuration directory])
  81 AC_SUBST(nmdatadir, "$datadir/$PACKAGE", [NetworkManager shared data directory])
  82 AC_SUBST(nmstatedir, "$localstatedir/lib/$PACKAGE", [NetworkManager persistent state directory])
  83 AC_SUBST(nmrundir, "$runstatedir/$PACKAGE", [NetworkManager runtime state directory])
  84
  85 # Alternative configuration plugins
  86 AC_ARG_ENABLE(config-plugin-ibft, AS_HELP_STRING([--enable-config-plugin-ibft], [enable ibft configuration plugin]))
  87 AC_ARG_ENABLE(ifcfg-rh, AS_HELP_STRING([--enable-ifcfg-rh], [enable ifcfg-rh configuration plugin (Fedora/RHEL)]))
  88 AC_ARG_ENABLE(ifcfg-suse, AS_HELP_STRING([--enable-ifcfg-suse], [enable ifcfg-suse configuration plugin (SUSE) (deprecated)]))
  89 AC_ARG_ENABLE(ifupdown, AS_HELP_STRING([--enable-ifupdown], [enable ifupdown configuration plugin (Debian/Ubuntu)]))
  90 AC_ARG_ENABLE(ifnet, AS_HELP_STRING([--enable-ifnet], [enable ifnet configuration plugin (Gentoo)]))
  91 # Default alternative plugins by distribution
  92 AS_IF([test -z "$enable_ifcfg_rh"], AC_CHECK_FILE(/etc/redhat-release, enable_ifcfg_rh=yes))
  93 AS_IF([test -z "$enable_ifcfg_rh"], AC_CHECK_FILE(/etc/fedora-release, enable_ifcfg_rh=yes))
  94 AS_IF([test -z "$enable_ifcfg_rh"], AC_CHECK_FILE(/etc/mandriva-release, enable_ifcfg_rh=yes))
  95 AS_IF([test -z "$enable_ifcfg_suse"], AC_CHECK_FILE(/etc/SuSE-release, enable_ifcfg_suse=yes))
  96 AS_IF([test -z "$enable_ifupdown"], AC_CHECK_FILE(/etc/debian_version, enable_ifupdown=yes))
  97 AS_IF([test -z "$enable_ifnet"], AC_CHECK_FILE(/etc/gentoo-release, enable_ifnet=yes))
  98 # Otherwise plugins default to "no"
  99 AS_IF([test -z "$enable_ifcfg_rh"], enable_ifcfg_rh=no)
 100 AS_IF([test -z "$enable_ifcfg_suse"], enable_ifcfg_suse=no)
 101 AS_IF([test -z "$enable_ifupdown"], enable_ifupdown=no)
 102 AS_IF([test -z "$enable_ifnet"], enable_ifnet=no)
 103 # Enable ibft by default
 104 AS_IF([test -z "$enable_config_plugin_ibft"], enable_config_plugin_ibft="yes")
 105 # Create automake conditionals
 106 AM_CONDITIONAL(CONFIG_PLUGIN_IBFT, test "$enable_config_plugin_ibft" = "yes")
 107 AM_CONDITIONAL(CONFIG_PLUGIN_IFCFG_RH, test "$enable_ifcfg_rh" = "yes")
 108 AM_CONDITIONAL(CONFIG_PLUGIN_IFUPDOWN, test "$enable_ifupdown" = "yes")
 109 AM_CONDITIONAL(CONFIG_PLUGIN_IFNET, test "$enable_ifnet" = "yes")
 110
 111 AC_ARG_WITH(config-plugins-default, AS_HELP_STRING([--with-config-plugins-default=PLUGINS], [Default configuration option for main.plugins setting, used as fallback if the configuration option is unset]), [config_plugins_default="$withval"], [config_plugins_default=""])
 112 if test -z "$config_plugins_default" -o "$config_plugins_default" = no; then
 113     config_plugins_default=''
 114     test "$enable_ifcfg_rh" = "yes"           && config_plugins_default="$config_plugins_default,ifcfg-rh"
 115     test "$enable_ifupdown" = "yes"           && config_plugins_default="$config_plugins_default,ifupdown"
 116     test "$enable_ifnet" = "yes"              && config_plugins_default="$config_plugins_default,ifnet"
 117     test "$enable_config_plugin_ibft" = "yes" && config_plugins_default="$config_plugins_default,ibft"
 118     config_plugins_default="${config_plugins_default#,}"
 119 fi
 120
 121 test "$enable_ifcfg_rh" = "yes"           && distro_plugins="$distro_plugins,ifcfg-rh"
 122 test "$enable_ifcfg_suse" = "yes"         && distro_plugins="$distro_plugins,ifcfg-suse"
 123 test "$enable_ifupdown" = "yes"           && distro_plugins="$distro_plugins,ifupdown"
 124 test "$enable_ifnet" = "yes"              && distro_plugins="$distro_plugins,ifnet"
 125 distro_plugins="${distro_plugins#,}"
 126
 127 AC_DEFINE_UNQUOTED(CONFIG_PLUGINS_DEFAULT, "$config_plugins_default", [Default configuration option for main.plugins setting])
 128
 129 if test "$enable_ifcfg_rh" = "yes"; then
 130     DISTRO_NETWORK_SERVICE=network.service
 131 fi
 132 AC_SUBST(DISTRO_NETWORK_SERVICE)
 133
 134 # Code coverage
 135 GNOME_CODE_COVERAGE
 136
 137 dnl
 138 dnl Distribution version string
 139 dnl
 140 AC_ARG_WITH(dist-version, AS_HELP_STRING([--with-dist-version=<NM-distribution-version>], [Define the NM''s distribution version string]), ac_distver=$withval, ac_distver="")
 141 if ! test x"$ac_distver" = x""; then
 142   AC_DEFINE_UNQUOTED(NM_DIST_VERSION, "$ac_distver", [Define the distribution version string])
 143 fi
 144
 145 AC_ARG_ENABLE(wifi, AS_HELP_STRING([--enable-wifi], [enable Wi-Fi support]))
 146 if test "${enable_wifi}" != "no"; then
 147         enable_wifi='yes'
 148         AC_DEFINE(WITH_WIFI, 1, [Define if you have Wi-Fi support])
 149 else
 150         AC_DEFINE(WITH_WIFI, 0, [Define if you have Wi-Fi support])
 151 fi
 152 AM_CONDITIONAL(WITH_WIFI, test "${enable_wifi}" = "yes")
 153
 154 dnl
 155 dnl Default to using WEXT but allow it to be disabled
 156 dnl
 157 AC_ARG_WITH(wext, AS_HELP_STRING([--with-wext=yes], [Enable or disable Linux Wireless Extensions]), ac_with_wext=$withval, ac_with_wext="$enable_wifi")
 158 if test "$ac_with_wext" != 'no'; then
 159         ac_with_wext='yes'
 160 fi
 161 if test x"$ac_with_wext" = x"yes"; then
 162         if test "$enable_wifi" != "yes"; then
 163                 AC_MSG_ERROR(Enabling WEXT support and disabling Wi-Fi makes no sense)
 164         fi
 165         AC_MSG_CHECKING([Linux kernel WEXT headers])
 166         AC_COMPILE_IFELSE(
 167                 [AC_LANG_PROGRAM(
 168                       [[#ifndef __user
 169                         #define __user
 170                         #endif
 171                         #include <sys/types.h>
 172                         #include <linux/types.h>
 173                         #include <sys/socket.h>
 174                         #include <linux/wireless.h>]],
 175                       [[#ifndef IWEVGENIE
 176                         #error "not found"
 177                         #endif]])],
 178                 [ac_have_iwevgenie=yes],
 179                 [ac_have_iwevgenie=no])
 180         AC_MSG_RESULT($ac_have_iwevgenie)
 181         if test "$ac_have_iwevgenie" = no; then
 182                AC_MSG_ERROR(Linux kernel development header linux/wireless.h not installed or not functional)
 183         fi
 184         AC_DEFINE(HAVE_WEXT, 1, [Define if you have Linux Wireless Extensions support])
 185 else
 186         AC_DEFINE(HAVE_WEXT, 0, [Define if you have Linux Wireless Extensions support])
 187 fi
 188 AM_CONDITIONAL(WITH_WEXT, test x"${ac_with_wext}" = x"yes")
 189
 190 AC_MSG_CHECKING([Linux kernel nl80211 headers])
 191 AC_COMPILE_IFELSE(
 192         [AC_LANG_PROGRAM(
 193               [[#ifndef __user
 194                 #define __user
 195                 #endif
 196                 #include <sys/types.h>
 197                 #include <linux/types.h>
 198                 #include <sys/socket.h>
 199                 #include <linux/nl80211.h>]],
 200               [[int a = NL80211_RATE_INFO_BITRATE; a++;]])],
 201         [ac_have_nl80211=yes],
 202         [ac_have_nl80211=no])
 203 AC_MSG_RESULT($ac_have_nl80211)
 204 if test "$ac_have_nl80211" = no; then
 205         AC_MSG_ERROR(Linux kernel development header linux/nl80211.h not installed or not functional)
 206 fi
 207
 208 if test "$with_wifi" = "yes"; then
 209         AC_MSG_CHECKING([Linux kernel nl80211 Critical Protocol Start/Stop])
 210         AC_COMPILE_IFELSE(
 211                 [AC_LANG_PROGRAM(
 212                   [[#ifndef __user
 213                     #define __user
 214                     #endif
 215                     #include <sys/types.h>
 216                     #include <linux/types.h>
 217                     #include <sys/socket.h>
 218                     #include <linux/nl80211.h>]],
 219                   [[unsigned int a = NL80211_CMD_CRIT_PROTOCOL_START; a++;]])],
 220                 [ac_have_nl80211_critproto=yes],
 221                 [ac_have_nl80211_critproto=no])
 222         AC_MSG_RESULT($ac_have_nl80211_critproto)
 223 else
 224         ac_have_nl80211_critproto='no'
 225 fi
 226 if test "$ac_have_nl80211_critproto" = yes; then
 227         AC_DEFINE(HAVE_NL80211_CRITICAL_PROTOCOL_CMDS, 1, [Define if nl80211 has critical protocol support])
 228 else
 229         AC_DEFINE(HAVE_NL80211_CRITICAL_PROTOCOL_CMDS, 0, [Define if nl80211 has critical protocol support])
 230 fi
 231
 232 dnl
 233 dnl Check for newer VLAN flags
 234 dnl
 235 AC_MSG_CHECKING([Linux kernel VLAN_FLAG_LOOSE_BINDING enum value])
 236 AC_COMPILE_IFELSE(
 237         [AC_LANG_PROGRAM(
 238               [[#ifndef __user
 239                 #define __user
 240                 #endif
 241                 #include <sys/types.h>
 242                 #include <linux/types.h>
 243                 #include <linux/if_vlan.h>]],
 244               [[unsigned int a = VLAN_FLAG_LOOSE_BINDING;]])],
 245         [ac_have_vlan_flag_loose_binding=yes],
 246         [ac_have_vlan_flag_loose_binding=no])
 247 AC_MSG_RESULT($ac_have_vlan_flag_loose_binding)
 248 if test "$ac_have_vlan_flag_loose_binding" = yes; then
 249         AC_DEFINE(HAVE_VLAN_FLAG_LOOSE_BINDING, 1, [Define if you have VLAN_FLAG_LOOSE_BINDING])
 250 else
 251         AC_DEFINE(HAVE_VLAN_FLAG_LOOSE_BINDING, 0, [Define if you have VLAN_FLAG_LOOSE_BINDING])
 252 fi
 253
 254 dnl
 255 dnl Checks for libm - needed for pow()
 256 dnl
 257 LT_LIB_M
 258
 259 dnl
 260 dnl Checks for libdl - on certain platforms its part of libc
 261 dnl
 262 AC_CHECK_LIB([dl], [dladdr], LIBDL="-ldl", LIBDL="")
 263 AC_SUBST(LIBDL)
 264
 265 dnl
 266 dnl Checks for dbus-glib
 267 dnl
 268 PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.1 dbus-glib-1 >= 0.94)
 269 AC_SUBST(DBUS_CFLAGS)
 270 AC_SUBST(DBUS_LIBS)
 271
 272 AC_CHECK_LIB([dbus-glib-1], [dbus_g_method_invocation_get_g_connection], ac_have_gmi_get_con="1", ac_have_gmi_get_con="0")
 273 AC_DEFINE_UNQUOTED(HAVE_DBUS_GLIB_GMI_GET_CONNECTION, $ac_have_gmi_get_con, [Define if you have a dbus-glib with dbus_g_method_invocation_get_g_connection()])
 274
 275 dnl
 276 dnl Only dbus-glib >= 0.100 can use private dbus connections
 277 dnl
 278 PKG_CHECK_MODULES(DBUS_GLIB_100, [dbus-glib-1 >= 0.100], [have_dbus_glib_100=yes],[have_dbus_glib_100=no])
 279 if (test "${have_dbus_glib_100}" = "yes"); then
 280         AC_DEFINE(HAVE_DBUS_GLIB_100, 1, [Define if you have dbus-glib >= 0.100])
 281 else
 282         AC_DEFINE(HAVE_DBUS_GLIB_100, 0, [Define if you have dbus-glib >= 0.100])
 283 fi
 284 AM_CONDITIONAL(HAVE_DBUS_GLIB_100, test "${have_dbus_glib_100}" = "yes")
 285
 286 PKG_CHECK_MODULES(GLIB, [gio-unix-2.0 >= 2.37.6 gmodule-2.0],
 287         [AC_SUBST(LOG_DRIVER, '$(top_srcdir)/build-aux/tap-driver.sh'),
 288          AC_SUBST(AM_TESTS_FD_REDIRECT, '--tap')],
 289         [PKG_CHECK_MODULES(GLIB, gio-unix-2.0 >= 2.32 gmodule-2.0)
 290          AC_SUBST(LOG_DRIVER, '$(top_srcdir)/build-aux/test-driver')])
 291
 292 dnl GLIB_VERSION_MIN_REQUIRED should match the version above.
 293 dnl GLIB_VERSION_MAX_ALLOWED should be set to the same version;
 294 dnl nm-glib-compat.h will cause it to be overridden for the functions
 295 dnl we have compat versions of.
 296 GLIB_CFLAGS="$GLIB_CFLAGS -DGLIB_VERSION_MIN_REQUIRED=GLIB_VERSION_2_32 -DGLIB_VERSION_MAX_ALLOWED=GLIB_VERSION_2_32"
 297
 298 AC_SUBST(GLIB_CFLAGS)
 299 AC_SUBST(GLIB_LIBS)
 300
 301 PKG_CHECK_MODULES(GUDEV, gudev-1.0 >= 165)
 302 AC_SUBST(GUDEV_CFLAGS)
 303 AC_SUBST(GUDEV_LIBS)
 304
 305 GOBJECT_INTROSPECTION_CHECK([0.9.6])
 306
 307 # Qt4
 308 PKG_CHECK_MODULES(QT, [QtCore >= 4 QtDBus QtNetwork], [have_qt=yes],[have_qt=no])
 309 AC_ARG_ENABLE(qt, AS_HELP_STRING([--enable-qt], [enable Qt examples]),
 310                      [enable_qt=${enableval}], [enable_qt=${have_qt}])
 311 if (test "${enable_qt}" = "yes"); then
 312         if test x"$have_qt" = x"no"; then
 313                 AC_MSG_ERROR(Qt development headers are required)
 314         fi
 315         AC_SUBST(QT_CFLAGS)
 316         AC_SUBST(QT_LIBS)
 317         # Check for moc-qt4 and if not found then moc
 318         QT4_BINDIR=`$PKG_CONFIG QtCore --variable moc_location`
 319         AC_CHECK_PROGS(MOC, [moc-qt4 moc],, [$QT4_BINDIR:$PATH])
 320 fi
 321 AM_CONDITIONAL(WITH_QT, test "${enable_qt}" = "yes")
 322
 323 AC_ARG_WITH(udev-dir, AS_HELP_STRING([--with-udev-dir=DIR], [Absolute path of the udev base directory. Set to 'no' not to install the udev rules]), [], [with_udev_dir="yes"])
 324 if (test "$with_udev_dir" != 'no'); then
 325         if (test "$with_udev_dir" != 'yes' && printf '%s' "$with_udev_dir" | grep -v -q '^/'); then
 326                 AC_MSG_ERROR([--with-udev-dir must be an absolute path or 'yes' or 'no'. Instead it is '$with_udev_dir'])
 327         fi
 328         if (test "$with_udev_dir" = 'yes'); then
 329                 with_udev_dir="/lib/udev"
 330         fi
 331         UDEV_DIR="$with_udev_dir"
 332         AC_SUBST(UDEV_DIR)
 333 fi
 334 AM_CONDITIONAL(WITH_UDEV_DIR, test "$with_udev_dir" != 'no')
 335
 336 # systemd unit support
 337 AC_ARG_WITH([systemdsystemunitdir], AS_HELP_STRING([--with-systemdsystemunitdir=DIR],
 338         [Directory for systemd service files]))
 339 # default location
 340 AS_IF([test -z "$with_systemdsystemunitdir" && $PKG_CONFIG systemd],
 341         with_systemdsystemunitdir="\$(prefix)/lib/systemd/system")
 342 AS_IF([test -z "$with_systemdsystemunitdir"], with_systemdsystemunitdir=no)
 343 # add conditional and subst
 344 AM_CONDITIONAL(HAVE_SYSTEMD, [test "$with_systemdsystemunitdir" != no])
 345 if test "$with_systemdsystemunitdir" != no; then
 346         AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
 347         AC_DEFINE(HAVE_SYSTEMD, 1, [Define if systemd support is available])
 348 else
 349         AC_DEFINE(HAVE_SYSTEMD, 0, [Define if systemd support is available])
 350 fi
 351
 352 PKG_CHECK_MODULES(SYSTEMD_200, [systemd >= 200], [have_systemd_200=yes],[have_systemd_200=no])
 353 AM_CONDITIONAL(HAVE_SYSTEMD_200, test "${have_systemd_200}" = "yes")
 354
 355 # Hostname persist mode
 356 AC_ARG_WITH(hostname-persist, AS_HELP_STRING([--with-hostname-persist=default|suse|gentoo],
 357         [Hostname persist method]))
 358
 359 AS_IF([test "$with_hostname_persist" = "suse"], hostname_persist=suse)
 360 AS_IF([test "$with_hostname_persist" = "gentoo"], hostname_persist=gentoo)
 361 AS_IF([test "$with_hostname_persist" = "default"], hostname_persist=default)
 362 # if the method was not explicitly set, try to guess it from the enabled plugins
 363 AS_IF([test -z "$hostname_persist" -a "$distro_plugins" = "ifcfg-suse"], hostname_persist=suse)
 364 AS_IF([test -z "$hostname_persist" -a "$distro_plugins" = "ifnet"], hostname_persist=gentoo)
 365 AS_IF([test -z "$hostname_persist"], hostname_persist=default)
 366
 367 if test "$hostname_persist" = suse; then
 368         AC_DEFINE(HOSTNAME_PERSIST_SUSE, 1, [Enable SuSE hostname persist method])
 369 elif test "$hostname_persist" = gentoo; then
 370         AC_DEFINE(HOSTNAME_PERSIST_GENTOO, 1, [Enable Gentoo hostname persist method])
 371 fi
 372
 373 # Session tracking support
 374 AC_ARG_WITH(systemd-logind, AS_HELP_STRING([--with-systemd-logind=yes|no],
 375         [Support systemd session tracking]))
 376 AC_ARG_WITH(consolekit, AS_HELP_STRING([--with-consolekit=yes|no],
 377         [Support consolekit session tracking]))
 378 AC_ARG_WITH(session-tracking, AS_HELP_STRING([--with-session-tracking=systemd|consolekit|no],
 379         [Compatibility option to choose one session tracking module]))
 380 # backwards compatibility
 381 AS_IF([test "$with_session_tracking" = "ck"], [use_consolekit="yes" use_systemd_logind="no"])
 382 AS_IF([test "$with_session_tracking" = "consolekit"], [use_consolekit="yes" use_systemd_logind="no"])
 383 AS_IF([test "$with_session_tracking" = "systemd"], [use_consolekit="no" use_systemd_logind="yes"])
 384 AS_IF([test "$with_session_tracking" = "no"], [use_consolekit="no" use_systemd_logind="no"])
 385 AS_IF([test "$with_session_tracking" = "none"], [use_consolekit="no" use_systemd_logind="no"])
 386 # current options
 387 AS_IF([test -n "$with_systemd_logind" ], [use_systemd_logind="$with_systemd_logind"])
 388 AS_IF([test -n "$with_consolekit" ], [use_consolekit="$with_consolekit"])
 389 # defaults
 390 AS_IF([test -z "$use_systemd_logind"], [use_systemd_logind="auto"])
 391 AS_IF([test -z "$use_consolekit"], [use_consolekit="yes"])
 392 # output
 393 session_tracking=
 394 if test "$use_systemd_logind" = "yes" -o "$use_systemd_logind" = "auto"; then
 395     PKG_CHECK_MODULES(SYSTEMD_LOGIN, [libsystemd], [have_systemd_logind=yes], [PKG_CHECK_MODULES(SYSTEMD_LOGIN, [libsystemd-login], [have_systemd_logind=yes], [have_systemd_logind=no])])
 396 else
 397     have_systemd_logind=no
 398 fi
 399 if test "$use_systemd_logind" = "yes" -a "$have_systemd_logind" = "no"; then
 400     AC_MSG_ERROR([You must have libsystemd installed to build with systemd-logind support.])
 401 fi
 402 if test "$have_systemd_logind" = "yes"; then
 403         AC_SUBST(SYSTEMD_LOGIN_CFLAGS)
 404         AC_SUBST(SYSTEMD_LOGIN_LIBS)
 405         AC_DEFINE([SESSION_TRACKING_SYSTEMD], 1, [Define to 1 if libsystemd-login is available])
 406         session_tracking="$session_tracking, systemd-logind"
 407 fi
 408 if test "$use_consolekit" = "yes"; then
 409         AC_DEFINE([SESSION_TRACKING_CONSOLEKIT], 1, [Define to 1 if ConsoleKit is available])
 410         AC_DEFINE([CKDB_PATH], "/var/run/ConsoleKit/database", [Path to ConsoleKit database])
 411         session_tracking="$session_tracking, consolekit"
 412 fi
 413 session_tracking="$(printf '%s' "${session_tracking}" | sed 's/^, //')"
 414
 415 AC_ARG_WITH(suspend-resume, AS_HELP_STRING([--with-suspend-resume=upower|systemd], [Build NetworkManager with specific suspend/resume support]))
 416 if test "z$with_suspend_resume" = "z"; then
 417     PKG_CHECK_EXISTS([libsystemd >= 209], [have_systemd_inhibit=yes],
 418                      [PKG_CHECK_EXISTS([libsystemd-login >= 183], [have_systemd_inhibit=yes], [have_systemd_inhibit=no])])
 419     if test "z${have_systemd_inhibit}" = "zyes"; then
 420         # Use systemd if it's new enough
 421         with_suspend_resume="systemd"
 422     else
 423         # Fall back to upower
 424         with_suspend_resume="upower"
 425     fi
 426 fi
 427
 428 case $with_suspend_resume in
 429     upower) ;;
 430     systemd)
 431         PKG_CHECK_MODULES(SYSTEMD_INHIBIT, [libsystemd >= 209],,
 432                           [PKG_CHECK_MODULES(SYSTEMD_INHIBIT, [libsystemd-login >= 183])])
 433         ;;
 434     *)
 435         AC_MSG_ERROR(--with-suspend-resume must be one of [upower, systemd])
 436         ;;
 437 esac
 438 AM_CONDITIONAL(SUSPEND_RESUME_UPOWER, test "x$with_suspend_resume" = "xupower")
 439 AM_CONDITIONAL(SUSPEND_RESUME_SYSTEMD, test "x$with_suspend_resume" = "xsystemd")
 440
 441 # SELinux support
 442 AC_ARG_WITH(selinux, AS_HELP_STRING([--with-selinux=yes|no|auto], [Build with SELinux (default: auto)]),,[with_selinux=auto])
 443 if test "$with_selinux" = "yes" -o "$with_selinux" = "auto"; then
 444     PKG_CHECK_MODULES(SELINUX, libselinux, [have_selinux=yes], [have_selinux=no])
 445 else
 446     have_selinux=no
 447 fi
 448 if test "$with_selinux" = "yes" -a "$have_selinux" = "no"; then
 449     AC_MSG_ERROR([You must have libselinux installed to build --with-selinux=yes.])
 450 fi
 451 if test "$have_selinux" = "yes"; then
 452     AC_DEFINE(HAVE_SELINUX, 1, [Define if you have SELinux support])
 453 else
 454     AC_DEFINE(HAVE_SELINUX, 0, [Define if you have SELinux support])
 455 fi
 456 AM_CONDITIONAL(HAVE_SELINUX, test "${have_selinux}" = "yes")
 457
 458 # libnl support for the linux platform
 459 PKG_CHECK_MODULES(LIBNL, libnl-3.0 >= 3.2.8 libnl-route-3.0 libnl-genl-3.0)
 460 AC_SUBST(LIBNL_CFLAGS)
 461 AC_SUBST(LIBNL_LIBS)
 462
 463 AC_CHECK_LIB([nl-route-3], [rtnl_link_inet6_get_addr_gen_mode],
 464         ac_have_addr_gen_mode="1",
 465         ac_have_addr_gen_mode="0")
 466 AC_DEFINE_UNQUOTED(HAVE_LIBNL_INET6_ADDR_GEN_MODE,
 467         $ac_have_addr_gen_mode, [Define if libnl has rtnl_link_inet6_get_addr_gen_mode()])
 468
 469 AC_MSG_CHECKING([Linux kernel IN6_ADDR_GEN_MODE enum])
 470 AC_COMPILE_IFELSE(
 471         [AC_LANG_PROGRAM(
 472               [[#ifndef __user
 473                 #define __user
 474                 #endif
 475                 #include <linux/if_link.h>]],
 476               [[int a = IN6_ADDR_GEN_MODE_EUI64; a++;]])],
 477         [ac_have_kernel_gen_mode=yes],
 478         [ac_have_kernel_gen_mode=no])
 479 AC_MSG_RESULT($ac_have_kernel_gen_mode)
 480 if test "$ac_have_kernel_gen_mode" = yes; then
 481         AC_DEFINE(HAVE_KERNEL_INET6_ADDR_GEN_MODE, 1, [Define if the kernel has IN6_ADDR_GEN_MODE_*])
 482 else
 483         AC_DEFINE(HAVE_KERNEL_INET6_ADDR_GEN_MODE, 0, [Define if the kernel has IN6_ADDR_GEN_MODE_*])
 484 fi
 485
 486 # IPv6 tokenized identifiers support in libnl
 487 AC_CHECK_LIB([nl-route-3], [rtnl_link_inet6_get_token],
 488         ac_have_ipv6_token="1",
 489         ac_have_ipv6_token="0")
 490 AC_DEFINE_UNQUOTED(HAVE_LIBNL_INET6_TOKEN,
 491         $ac_have_ipv6_token, [Define if libnl has rtnl_link_inet6_get_token()])
 492
 493 # uuid library
 494 PKG_CHECK_MODULES(UUID, uuid)
 495 AC_SUBST(UUID_CFLAGS)
 496 AC_SUBST(UUID_LIBS)
 497
 498 dnl Checks for readline library - used by nmcli
 499 AX_LIB_READLINE
 500
 501 # Teamd control checks
 502 PKG_CHECK_MODULES(LIBTEAMDCTL, [libteamdctl >= 1.9], [have_teamdctl=yes],[have_teamdctl=no])
 503 AC_ARG_ENABLE(teamdctl, AS_HELP_STRING([--enable-teamdctl], [enable Teamd control support]),
 504                      [enable_teamdctl=${enableval}], [enable_teamdctl=${have_teamdctl}])
 505 if (test "${enable_teamdctl}" = "yes"); then
 506         if test x"$have_teamdctl" = x"no"; then
 507                 AC_MSG_ERROR(Teamd control is required)
 508         fi
 509
 510         AC_SUBST(LIBTEAMDCTL_CFLAGS)
 511         AC_SUBST(LIBTEAMDCTL_LIBS)
 512         # temporary bug workaround
 513         LIBTEAMDCTL_CFLAGS=`echo $LIBTEAMDCTL_CFLAGS | sed -e 's:/teamdctl.h::'`
 514         AC_DEFINE(WITH_TEAMDCTL, 1, [Define if you have Teamd control support])
 515 else
 516         AC_DEFINE(WITH_TEAMDCTL, 0, [Define if you have Teamd control support])
 517 fi
 518 AM_CONDITIONAL(WITH_TEAMDCTL, test "${enable_teamdctl}" = "yes")
 519
 520 # we usually compile with polkit support. --enable-polkit=yes|no only sets the
 521 # default configuration for main.auth-polkit. User can always enable/disable polkit
 522 # autorization via config. Only when specifying --enable-polkit=disabled, we do
 523 # not compile support. In this case, the user cannot enable polkit authorization via
 524 # configuration.
 525 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--enable-polkit=yes|no|disabled], [set default value for auth-polkit configuration option. This value can be overwritten by NM configuration. 'disabled' compiles NM without any support]),
 526                      [enable_polkit=${enableval}], [enable_polkit=yes])
 527 if (test "${enable_polkit}" != "no" -a "${enable_polkit}" != "disabled"); then
 528         enable_polkit=yes
 529         AC_DEFINE(NM_CONFIG_DEFAULT_AUTH_POLKIT, TRUE, [The default value of the auth-polkit configuration option])
 530         NM_CONFIG_DEFAULT_AUTH_POLKIT_TEXT='true'
 531 else
 532         AC_DEFINE(NM_CONFIG_DEFAULT_AUTH_POLKIT, FALSE, [The default value of the auth-polkit configuration option])
 533         NM_CONFIG_DEFAULT_AUTH_POLKIT_TEXT='false'
 534 fi
 535 if (test "${enable_polkit}" != "disabled"); then
 536         AC_DEFINE(WITH_POLKIT, 1, [whether to compile polkit support])
 537 else
 538         AC_DEFINE(WITH_POLKIT, 0, [whether to compile polkit support])
 539 fi
 540 AC_SUBST(NM_CONFIG_DEFAULT_AUTH_POLKIT_TEXT)
 541
 542 PKG_CHECK_MODULES(POLKIT, [polkit-agent-1 >= 0.97], [have_pk_agent=yes],[have_pk_agent=no])
 543 AC_ARG_ENABLE(polkit-agent, AS_HELP_STRING([--enable-polkit-agent], [enable polkit agent for clients]),
 544                      [enable_polkit_agent=${enableval}], [enable_polkit_agent=${have_pk_agent}])
 545 if (test "${enable_polkit_agent}" = "yes"); then
 546         if test x"$have_pk_agent" = x"no"; then
 547                 AC_MSG_ERROR(Polkit agent is required)
 548         fi
 549
 550         AC_SUBST(POLKIT_CFLAGS)
 551         AC_SUBST(POLKIT_LIBS)
 552         AC_DEFINE(WITH_POLKIT_AGENT, 1, [Define if you have polkit agent])
 553 else
 554         AC_DEFINE(WITH_POLKIT_AGENT, 0, [Define if you have polkit agent])
 555 fi
 556 AM_CONDITIONAL(WITH_POLKIT_AGENT, test "${enable_polkit_agent}" = "yes")
 557
 558 AC_ARG_ENABLE(modify-system,
 559               AS_HELP_STRING([--enable-modify-system], [Allow users to modify system connections]))
 560 if test "${enable_modify_system}" = "yes"; then
 561         NM_MODIFY_SYSTEM_POLICY="yes"
 562 else
 563         NM_MODIFY_SYSTEM_POLICY="auth_admin_keep"
 564 fi
 565 AC_SUBST(NM_MODIFY_SYSTEM_POLICY)
 566
 567 AC_ARG_WITH(crypto, AS_HELP_STRING([--with-crypto=nss|gnutls], [Cryptography library to use for certificate and key operations]),ac_crypto=$withval, ac_crypto=nss)
 568
 569 with_nss=no
 570 with_gnutls=no
 571 if test x"$ac_crypto" = xnss; then
 572   PKG_CHECK_MODULES(NSS, [nss >= 3.11])
 573
 574   # Work around a pkg-config bug (fdo #29801) where exists != usable
 575   FOO=`$PKG_CONFIG --cflags --libs nss`
 576   if test x"$?" != "x0"; then
 577     AC_MSG_ERROR([No usable NSS found])
 578   fi
 579
 580   AC_SUBST(NSS_CFLAGS)
 581   AC_SUBST(NSS_LIBS)
 582   AC_DEFINE(HAVE_NSS, 1, [Define if you have NSS])
 583   with_nss=yes
 584 elif test x"$ac_crypto" = xgnutls; then
 585   PKG_CHECK_MODULES(GNUTLS, [gnutls >= 2.12])
 586   AC_DEFINE(HAVE_GNUTLS, 1, [Define if you have libgnutls])
 587   AC_SUBST(GNUTLS_CFLAGS)
 588   AC_SUBST(GNUTLS_LIBS)
 589   with_gnutls=yes
 590 else
 591   AC_MSG_ERROR([Please choose either 'nss' or 'gnutls' for certificate and crypto operations])
 592 fi
 593 AM_CONDITIONAL(WITH_NSS, test x"$with_nss" != xno)
 594 AM_CONDITIONAL(WITH_GNUTLS, test x"$with_gnutls" != xno)
 595
 596 # Shouldn't ever trigger this, but just in case...
 597 if test x"$ac_nss" = xno -a x"$ac_gnutls" = xno; then
 598   AC_MSG_ERROR([Could not find required development headers and libraries for '$ac_crypto'])
 599 fi
 600
 601 GLIB_MAKEFILE='$(top_srcdir)/Makefile.glib'
 602 AC_SUBST(GLIB_MAKEFILE)
 603 GLIB_GENMARSHAL=`pkg-config --variable=glib_genmarshal glib-2.0`
 604 AC_SUBST(GLIB_GENMARSHAL)
 605 GLIB_MKENUMS=`pkg-config --variable=glib_mkenums glib-2.0`
 606 AC_SUBST(GLIB_MKENUMS)
 607
 608 AC_ARG_WITH(dbus-sys-dir, AS_HELP_STRING([--with-dbus-sys-dir=DIR], [where D-BUS system.d directory is]))
 609
 610 if test -n "$with_dbus_sys_dir" ; then
 611     DBUS_SYS_DIR="$with_dbus_sys_dir"
 612 else
 613     DBUS_SYS_DIR="${sysconfdir}/dbus-1/system.d"
 614 fi
 615 AC_SUBST(DBUS_SYS_DIR)
 616
 617 # pppd
 618 AC_ARG_ENABLE(ppp, AS_HELP_STRING([--enable-ppp], [enable PPP/PPPoE support]),
 619                      [enable_ppp=${enableval}], [enable_ppp=yes])
 620 if (test "${enable_ppp}" = "yes"); then
 621         AC_CHECK_HEADERS(pppd/pppd.h,,
 622                 AC_MSG_ERROR("couldn't find pppd.h. pppd development headers are required."))
 623
 624         AC_DEFINE(WITH_PPP, 1, [Define if you have PPP support])
 625 else
 626         AC_DEFINE(WITH_PPP, 0, [Define if you have PPP support])
 627 fi
 628 AM_CONDITIONAL(WITH_PPP, test "${enable_ppp}" = "yes")
 629
 630 AC_ARG_WITH([pppd-plugin-dir], AS_HELP_STRING([--with-pppd-plugin-dir=DIR], [path to the pppd plugins directory]))
 631
 632 if test -n "$with_pppd_plugin_dir" ; then
 633         PPPD_PLUGIN_DIR="$with_pppd_plugin_dir"
 634 else
 635         PPPD_PLUGIN_DIR="${libdir}/pppd/2.4.5"
 636 fi
 637 AC_SUBST(PPPD_PLUGIN_DIR)
 638
 639 AC_ARG_WITH(pppd, AS_HELP_STRING([--with-pppd=/path/to/pppd], [path to pppd binary]))
 640 if test "x${with_pppd}" = x; then
 641   AC_PATH_PROG(PPPD_PATH, pppd, [], $PATH:/sbin:/usr/sbin)
 642 else
 643   PPPD_PATH="$with_pppd"
 644 fi
 645 AC_DEFINE_UNQUOTED(PPPD_PATH, "$PPPD_PATH", [Define to path of pppd binary])
 646 AC_SUBST(PPPD_PATH)
 647
 648 # ModemManager1 with libmm-glib
 649 AC_ARG_WITH(modem-manager-1, AS_HELP_STRING([--with-modem-manager-1], [Enable new ModemManager1 interface support]),,[with_modem_manager_1=auto])
 650 if (test "${with_modem_manager_1}" != "no"); then
 651     PKG_CHECK_MODULES(MM_GLIB,
 652                       [mm-glib >= 0.7.991],
 653                       [have_libmm_glib=yes],
 654                       [have_libmm_glib=no])
 655     AC_SUBST(MM_GLIB_CFLAGS)
 656     AC_SUBST(MM_GLIB_LIBS)
 657
 658     if (test "${have_libmm_glib}" = "no"); then
 659         if (test "${with_modem_manager_1}" = "yes"); then
 660             AC_MSG_ERROR([Couldn't find libmm-glib])
 661         else
 662             with_modem_manager_1="no"
 663         fi
 664     else
 665         with_modem_manager_1="yes"
 666     fi
 667 fi
 668
 669 if (test "${with_modem_manager_1}" = "yes"); then
 670     AC_DEFINE(WITH_MODEM_MANAGER_1, 1, [Define if you have ModemManager1 support])
 671 else
 672         AC_DEFINE(WITH_MODEM_MANAGER_1, 0, [Define if you have ModemManager1 support])
 673 fi
 674 AM_CONDITIONAL(WITH_MODEM_MANAGER_1, test "${with_modem_manager_1}" = "yes")
 675
 676 # Bluez5 DUN support
 677 PKG_CHECK_MODULES(BLUEZ5, [bluez >= 5], [have_bluez5=yes],[have_bluez5=no])
 678 AC_ARG_ENABLE(bluez5-dun, AS_HELP_STRING([--enable-bluez5-dun], [enable Bluez5 DUN support]),
 679                 [enable_bluez5_dun=${enableval}], [enable_bluez5_dun=${have_bluez5}])
 680 if (test "${enable_bluez5_dun}" = "yes"); then
 681         if test x"$have_bluez5" = x"no"; then
 682                 AC_MSG_ERROR(Bluez 5.x development headers are required)
 683         fi
 684         AC_DEFINE(WITH_BLUEZ5_DUN, 1, [Define if you have Bluez 5 libraries])
 685 else
 686         AC_DEFINE(WITH_BLUEZ5_DUN, 0, [Define if you have Bluez 5 libraries])
 687 fi
 688 AM_CONDITIONAL(WITH_BLUEZ5_DUN, test "${enable_bluez5_dun}" = "yes")
 689
 690 # DHCP client support
 691 AC_ARG_WITH([dhclient], AS_HELP_STRING([--with-dhclient=yes|no|path], [Enable dhclient 4.x support]))
 692 AC_ARG_WITH([dhcpcd], AS_HELP_STRING([--with-dhcpcd=yes|no|path], [Enable dhcpcd 4.x support]))
 693 # Default to "yes"
 694 AS_IF([test -z "$with_dhclient"], with_dhclient=yes)
 695 AS_IF([test -z "$with_dhcpcd"], with_dhcpcd=yes)
 696 # Search and check the executables
 697 if test "$with_dhclient" = "yes"; then
 698         AC_PATH_PROGS(with_dhclient, dhclient, no, /sbin:/usr/sbin:/usr/local/sbin)
 699         if test "$with_dhclient" != "no"; then
 700                 if ! $with_dhclient --version 2>&1 | grep -q "^isc-dhclient-4\."; then
 701                         AC_MSG_WARN([Cannot use dhclient, version 4.x is required])
 702                         with_dhclient=no
 703                 fi
 704         fi
 705 fi
 706 if test "$with_dhcpcd" = "yes"; then
 707         AC_PATH_PROGS(with_dhcpcd, dhcpcd, no, /sbin:/usr/sbin:/usr/local/sbin)
 708         if test "$with_dhcpcd" != "no"; then
 709                 if ! $with_dhcpcd --version 2>&1 | grep -q "^dhcpcd [[456789]]\."; then
 710                         AC_MSG_WARN([Cannot use dhcpcd, version 4.x or higher is required])
 711                         with_dhcpcd=no
 712                 elif $with_dhcpcd --version 2>&1 | grep -q "^dhcpcd [[6789]]\."; then
 713                         AC_DEFINE(DHCPCD_SUPPORTS_IPV6, 1, [Define if dhcpcd supports IPv6 (6.x+)])
 714                 fi
 715         fi
 716 fi
 717 # Fallback
 718 if test "$with_dhclient" = "no" -a "$with_dhcpcd" = "no"; then
 719         AC_MSG_WARN([Could not find a suitable DHCP client, falling back to dhclient])
 720         with_dhclient=/sbin/dhclient
 721 fi
 722 # Add substitutions
 723 if test "$with_dhclient" != "no"; then
 724         AC_DEFINE(WITH_DHCLIENT, TRUE, [Define if you have dhclient])
 725         AC_SUBST(DHCLIENT_PATH, $with_dhclient)
 726 else
 727         AC_DEFINE(WITH_DHCLIENT, FALSE, [Define if you have dhclient])
 728 fi
 729 if test "$with_dhcpcd" != "no"; then
 730         AC_DEFINE(WITH_DHCPCD, TRUE, [Define if you have dhcpcd])
 731         AC_SUBST(DHCPCD_PATH, $with_dhcpcd)
 732 else
 733         AC_DEFINE(WITH_DHCPCD, FALSE, [Define if you have dhcpcd])
 734 fi
 735
 736 # resolvconf and netconfig support
 737 AC_ARG_WITH(resolvconf, AS_HELP_STRING([--with-resolvconf=yes|no|path], [Enable resolvconf support]))
 738 AC_ARG_WITH(netconfig, AS_HELP_STRING([--with-netconfig=yes|no], [Enable SUSE netconfig support]))
 739 # Use netconfig by default on SUSE
 740 AS_IF([test -z "$with_netconfig"], AC_CHECK_FILE(/etc/SuSE-release, with_netconfig=yes))
 741 # Otherwise default to "no"
 742 AS_IF([test -z "$with_resolvconf"], with_resolvconf=no)
 743 AS_IF([test -z "$with_netconfig"], with_netconfig=no)
 744 # Find resolvconf and netconfig
 745 if test "$with_resolvconf" = "yes"; then
 746         AC_PATH_PROGS(with_resolvconf, resolvconf, no, /sbin:/usr/sbin:/usr/local/sbin)
 747 fi
 748 if test "$with_netconfig" = "yes"; then
 749         AC_PATH_PROGS(with_netconfig, netconfig, no, /sbin:/usr/sbin:/usr/local/sbin)
 750 fi
 751 # Define resolvconf and netconfig paths
 752 if test "$with_resolvconf" != "no"; then
 753         AC_DEFINE_UNQUOTED(RESOLVCONF_PATH, "$with_resolvconf", [Path to resolvconf])
 754 fi
 755 if test "$with_netconfig" != "no"; then
 756         AC_DEFINE_UNQUOTED(NETCONFIG_PATH, "$with_netconfig", [Path to netconfig])
 757 fi
 758
 759 # iptables path
 760 AC_ARG_WITH(iptables, AS_HELP_STRING([--with-iptables=/path/to/iptables], [path to iptables]))
 761 if test "x${with_iptables}" = x; then
 762   AC_PATH_PROG(IPTABLES_PATH, iptables, [], $PATH:/sbin:/usr/sbin)
 763   if ! test -x "$IPTABLES_PATH"; then
 764         AC_MSG_ERROR(iptables was not installed.)
 765   fi
 766 else
 767   IPTABLES_PATH="$with_iptables"
 768 fi
 769 AC_DEFINE_UNQUOTED(IPTABLES_PATH, "$IPTABLES_PATH", [Define to path of iptables binary])
 770 AC_SUBST(IPTABLES_PATH)
 771
 772 # dnsmasq path
 773 AC_ARG_WITH(dnsmasq, AS_HELP_STRING([--with-dnsmasq=/path/to/dnsmasq], [path to dnsmasq]))
 774 if test "x${with_dnsmasq}" = x; then
 775   AC_PATH_PROG(DNSMASQ_PATH, dnsmasq, [], $PATH:/sbin:/usr/sbin)
 776 else
 777   DNSMASQ_PATH="$with_dnsmasq"
 778 fi
 779 AC_DEFINE_UNQUOTED(DNSMASQ_PATH, "$DNSMASQ_PATH", [Define to path of dnsmasq binary])
 780 AC_SUBST(DNSMASQ_PATH)
 781
 782 # system CA certificates path
 783 AC_ARG_WITH(system-ca-path, AS_HELP_STRING([--with-system-ca-path=/path/to/ssl/certs], [path to system CA certificates]))
 784 if test "x${with_system_ca_path}" = x; then
 785   SYSTEM_CA_PATH=/etc/ssl/certs
 786 else
 787   SYSTEM_CA_PATH="$with_system_ca_path"
 788 fi
 789 AC_DEFINE_UNQUOTED(SYSTEM_CA_PATH, "$SYSTEM_CA_PATH", [Define to path to system CA certificates])
 790 AC_SUBST(SYSTEM_CA_PATH)
 791
 792 AC_ARG_WITH(kernel-firmware-dir, AS_HELP_STRING([--with-kernel-firmware-dir=DIR], [where kernel firmware directory is (default is /lib/firmware)]))
 793
 794 if test -n "$with_kernel_firmware_dir" ; then
 795     KERNEL_FIRMWARE_DIR="$with_kernel_firmware_dir"
 796 else
 797     KERNEL_FIRMWARE_DIR="/lib/firmware"
 798 fi
 799 AC_DEFINE_UNQUOTED(KERNEL_FIRMWARE_DIR, "$KERNEL_FIRMWARE_DIR", [Define to path of the kernel firmware directory])
 800 AC_SUBST(KERNEL_FIRMWARE_DIR)
 801
 802 PKG_CHECK_MODULES(LIBSOUP, [libsoup-2.4 >= 2.26], [have_libsoup=yes],[have_libsoup=no])
 803 AC_ARG_WITH(libsoup, AS_HELP_STRING([--with-libsoup=yes|no], [Link against libsoup]), [], [with_libsoup=${have_libsoup}])
 804 if test "$with_libsoup" != "no"; then
 805         if test "$have_libsoup" != "yes"; then
 806                 AC_MSG_ERROR(libsoup library not found)
 807         fi
 808         with_libsoup='yes'
 809         AC_DEFINE(WITH_LIBSOUP, 1, [Define if you have libsoup])
 810 else
 811         AC_DEFINE(WITH_LIBSOUP, 0, [Define if you have libsoup])
 812 fi
 813 AM_CONDITIONAL(WITH_LIBSOUP, test "$with_libsoup" != "no")
 814
 815 AC_ARG_ENABLE(concheck, AS_HELP_STRING([--enable-concheck], [enable connectivity checking support]),
 816                      [enable_concheck=${enableval}], [enable_concheck=${with_libsoup}])
 817 if (test "${enable_concheck}" = "yes"); then
 818         if test x"$with_libsoup" = x"no"; then
 819                 AC_MSG_ERROR(Connectivity checking requires libsoup)
 820         fi
 821         AC_SUBST(LIBSOUP_CFLAGS)
 822         AC_SUBST(LIBSOUP_LIBS)
 823         AC_DEFINE(WITH_CONCHECK, 1, [Define if you want connectivity checking support])
 824 else
 825         AC_DEFINE(WITH_CONCHECK, 0, [Define if you want connectivity checking support])
 826 fi
 827 AM_CONDITIONAL(WITH_CONCHECK, test "${enable_concheck}" = "yes")
 828
 829 PKG_CHECK_MODULES(LIBNDP, [libndp])
 830
 831 AC_ARG_WITH(nmtui, AS_HELP_STRING([--with-nmtui=yes|no], [Build nmtui]))
 832 if test "$with_nmtui" != no; then
 833     PKG_CHECK_MODULES(NEWT, [libnewt >= 0.52.15], [build_nmtui=yes], [build_nmtui=no])
 834 else
 835     build_nmtui=no
 836 fi
 837 if test "$with_nmtui" = yes -a "$build_nmtui" = no; then
 838     AC_MSG_ERROR([You must have libnewt installed to build nmtui.])
 839 fi
 840 AM_CONDITIONAL(BUILD_NMTUI, test "$build_nmtui" = yes)
 841
 842
 843 NM_COMPILER_WARNINGS
 844
 845 AC_ARG_ENABLE(more-asserts,
 846               AS_HELP_STRING([--enable-more-asserts], [Enable more assertions for debugging (default: no)]))
 847 if test "${enable_more_asserts}" = "yes"; then
 848     AC_DEFINE(NM_MORE_ASSERTS, [1], [Define if more asserts are enabled])
 849 fi
 850
 851 AC_ARG_ENABLE(more-logging,
 852               AS_HELP_STRING([--enable-more-logging], [Enable more debug logging (default: no)]))
 853 if test "${enable_more_logging}" = "yes"; then
 854     AC_DEFINE(NM_MORE_LOGGING, [1], [Define if more asserts are enabled])
 855 fi
 856
 857 AC_ARG_ENABLE(lto, AS_HELP_STRING([--enable-lto], [Enable Link Time Optimization for smaller size (default: no)]))
 858 if (test "${enable_lto}" = "yes"); then
 859     CFLAGS="-flto $CFLAGS"
 860 else
 861     enable_lto='no'
 862 fi
 863
 864
 865 dnl -------------------------
 866 dnl Vala bindings
 867 dnl -------------------------
 868
 869 VAPIGEN_CHECK(0.17.1.24)
 870
 871 # Tests, utilities and documentation
 872 AC_ARG_ENABLE(tests, AS_HELP_STRING([--enable-tests=root|yes|no], [Build NetworkManager tests (default: yes)]))
 873 AC_ARG_WITH(valgrind, AS_HELP_STRING([--with-valgrind=yes|no|path], [Use valgrind to memory-check the tests (default: no)]))
 874 # Fallback to --with-tests
 875 AC_ARG_WITH(tests, AS_HELP_STRING([--with-tests], [Build NetworkManager tests (deprecated)]))
 876 AS_IF([test -n "$with_tests"], enable_tests="$with_tests")
 877 # Default to --enable-tests --with-valgrind=no
 878 AS_IF([test -z "$enable_tests"], enable_tests="yes")
 879 AS_IF([test -z "$with_valgrind"], with_valgrind="no")
 880 # Normalize values
 881 AS_IF([test "$enable_tests" != "yes" -a "$enable_tests" != "root"], enable_tests="no")
 882 # Search for tools
 883 AS_IF([test "$with_valgrind" == "yes"],
 884         [AC_PATH_PROGS(with_valgrind, valgrind, no)])
 885 # Add conditionals and substitutions
 886 AM_CONDITIONAL(ENABLE_TESTS, test "$enable_tests" != "no")
 887 AM_CONDITIONAL(REQUIRE_ROOT_TESTS, test "$enable_tests" == "root")
 888 AC_ARG_WITH(valgrind-suppressions, AS_HELP_STRING([--with-valgrind-suppressions=path], [Use specific valgrind suppression file]))
 889 if test "$with_valgrind" == no; then
 890         with_valgrind_suppressions=
 891 else
 892         if test  "$with_valgrind_suppressions" == ""; then
 893                 with_valgrind_suppressions='$(top_srcdir)/valgrind.suppressions'
 894         fi
 895 fi
 896 AS_IF([test "$with_valgrind" != "no"],
 897         AC_SUBST(VALGRIND_RULES, 'LOG_COMPILER = "$(top_srcdir)/tools/run-test-valgrind.sh" "$(LIBTOOL)" "$(with_valgrind)" '"$with_valgrind_suppressions"),
 898         AC_SUBST(VALGRIND_RULES, []))
 899 AM_CONDITIONAL(WITH_VALGRIND, test "${with_valgrind}" != "no")
 900
 901 GTK_DOC_CHECK(1.0)
 902
 903 # check for pregenerated manpages to be installed
 904 install_pregen_manpages=no
 905 if test "$enable_gtk_doc" != "yes" \
 906         -a -f man/NetworkManager.conf.5 \
 907         -a -f man/nm-settings.5 \
 908         -a -f man/nm-settings-keyfile.5 \
 909         -a -f man/nm-settings-ifcfg-rh.5 \
 910         -a -f man/nmcli-examples.5 \
 911         -a -f man/NetworkManager.8; then
 912         install_pregen_manpages=yes
 913 fi
 914 AM_CONDITIONAL(INSTALL_PREGEN_MANPAGES, test "x${install_pregen_manpages}" = "xyes")
 915
 916 # check if we can build setting property documentation
 917 if test -n "$INTROSPECTION_MAKEFILE" -a "$enable_gtk_doc" = "yes"; then
 918     # If g-i is installed we know we have python, but we might not have pygobject
 919     if python -c 'from gi.repository import GObject' >& /dev/null; then
 920         have_pyobject=yes
 921     fi
 922
 923     # gtk-doc depends on perl, but we can check for it anyway
 924     AC_PATH_PROG(PERL, perl, no)
 925     # check for needed perl modules (use YAML; YAML::XS is better, but may not be so widespread)
 926     required_perl_modules="YAML"
 927     for module in $required_perl_modules; do
 928       AC_MSG_CHECKING([checking for perl module '$module'])
 929       if ${PERL} -e 'use '$module 2>/dev/null ; then
 930           AC_MSG_RESULT([Ok])
 931           have_perl_modules=yes
 932       else
 933           AC_MSG_RESULT([Failed])
 934           AC_MSG_ERROR([You must have Perl modules to build settings plugin docs: $required_perl_modules.])
 935       fi
 936     done
 937
 938     if test "$have_pyobject" = "yes" -a "$have_perl_modules" = "yes"; then
 939         AC_DEFINE(BUILD_SETTING_DOCS, [1], [Define if you we can build nm-setting-docs.xml, nm-keyfile-docs.xml and nm-ifcfg-rh-docs.xml])
 940         build_setting_docs=yes
 941     fi
 942 fi
 943
 944 # check for pre-built setting docs
 945 if test "$build_setting_docs" != "yes" \
 946         -a -f man/nm-settings.xml \
 947         -a -f man/nm-settings-keyfile.xml \
 948         -a -f man/nm-settings-ifcfg-rh.xml \
 949         -a -f docs/api/settings-spec.xml \
 950         -a -f clients/cli/settings-docs.c; then
 951     AC_DEFINE(HAVE_SETTING_DOCS, [1], [Define if you have pre-built settings docs])
 952     have_setting_docs=yes
 953 fi
 954
 955 AM_CONDITIONAL(BUILD_SETTING_DOCS, test "$build_setting_docs" = "yes")
 956 AM_CONDITIONAL(SETTING_DOCS_AVAILABLE, test "$build_setting_docs" = "yes" -o "$have_setting_docs" = "yes")
 957
 958
 959 AC_CONFIG_FILES([
 960 Makefile
 961 include/Makefile
 962 src/Makefile
 963 src/tests/Makefile
 964 src/tests/config/Makefile
 965 src/dhcp-manager/Makefile
 966 src/dhcp-manager/tests/Makefile
 967 src/dnsmasq-manager/tests/Makefile
 968 src/supplicant-manager/tests/Makefile
 969 src/ppp-manager/Makefile
 970 src/settings/plugins/Makefile
 971 src/settings/plugins/ifupdown/Makefile
 972 src/settings/plugins/ifupdown/tests/Makefile
 973 src/settings/plugins/ifnet/Makefile
 974 src/settings/plugins/ifnet/tests/Makefile
 975 src/settings/plugins/ifcfg-rh/Makefile
 976 src/settings/plugins/ifcfg-rh/tests/Makefile
 977 src/settings/plugins/ifcfg-rh/tests/network-scripts/Makefile
 978 src/settings/plugins/ibft/Makefile
 979 src/settings/plugins/ibft/tests/Makefile
 980 src/settings/plugins/keyfile/Makefile
 981 src/settings/plugins/keyfile/tests/Makefile
 982 src/settings/plugins/keyfile/tests/keyfiles/Makefile
 983 src/settings/plugins/example/Makefile
 984 src/platform/Makefile
 985 src/platform/tests/Makefile
 986 src/rdisc/Makefile
 987 src/rdisc/tests/Makefile
 988 src/devices/adsl/Makefile
 989 src/devices/bluetooth/Makefile
 990 src/devices/team/Makefile
 991 src/devices/wifi/Makefile
 992 src/devices/wifi/tests/Makefile
 993 src/devices/wwan/Makefile
 994 libnm-core/nm-version.h
 995 libnm-core/Makefile
 996 libnm-core/tests/Makefile
 997 libnm/libnm.pc
 998 libnm/Makefile
 999 libnm/tests/Makefile
1000 libnm-util/libnm-util.pc
1001 libnm-util/nm-version.h
1002 libnm-util/Makefile
1003 libnm-util/tests/Makefile
1004 libnm-glib/libnm-glib.pc
1005 libnm-glib/libnm-glib-vpn.pc
1006 libnm-glib/Makefile
1007 libnm-glib/tests/Makefile
1008 callouts/Makefile
1009 callouts/tests/Makefile
1010 tools/Makefile
1011 clients/Makefile
1012 clients/cli/Makefile
1013 clients/tui/Makefile
1014 clients/tui/newt/Makefile
1015 initscript/RedHat/NetworkManager
1016 initscript/Debian/NetworkManager
1017 initscript/Slackware/rc.networkmanager
1018 initscript/SUSE/networkmanager
1019 initscript/Arch/networkmanager
1020 initscript/Mandriva/networkmanager
1021 initscript/linexa/networkmanager
1022 introspection/Makefile
1023 introspection/all.xml
1024 man/Makefile
1025 man/NetworkManager.conf.xml
1026 man/nm-system-settings.conf.5
1027 man/nm-online.1
1028 man/nmcli.1
1029 man/nmtui.1
1030 po/Makefile.in
1031 policy/Makefile
1032 policy/org.freedesktop.NetworkManager.policy.in
1033 data/Makefile
1034 docs/Makefile
1035 docs/api/Makefile
1036 docs/api/version.xml
1037 docs/libnm-glib/Makefile
1038 docs/libnm-glib/version.xml
1039 docs/libnm-util/Makefile
1040 docs/libnm-util/version.xml
1041 docs/libnm/Makefile
1042 docs/libnm/version.xml
1043 NetworkManager.pc
1044 examples/Makefile
1045 examples/shell/Makefile
1046 examples/python/Makefile
1047 examples/python/dbus/Makefile
1048 examples/python/gi/Makefile
1049 examples/ruby/Makefile
1050 examples/lua/Makefile
1051 examples/lua/lgi/Makefile
1052 examples/C/Makefile
1053 examples/C/glib/Makefile
1054 examples/C/qt/Makefile
1055 examples/dispatcher/Makefile
1056 vapi/Makefile
1057 ])
1058 AC_CONFIG_SUBDIRS([libndp])
1059 AC_OUTPUT
1060
1061 # Print build configuration
1062 echo
1063 echo "System paths:"
1064 echo "  prefix: $prefix"
1065 echo "  exec_prefix: $exec_prefix"
1066 echo "  systemdunitdir: $with_systemdsystemunitdir"
1067 echo "  nmbinary: $nmbinary"
1068 echo "  nmconfdir: $nmconfdir"
1069 echo "  nmdatadir: $nmdatadir"
1070 echo "  nmstatedir: $nmstatedir"
1071 echo "  nmrundir: $nmrundir"
1072 echo
1073
1074 echo "Platform:"
1075 echo "  session tracking: $session_tracking"
1076 echo "  suspend/resume: $with_suspend_resume"
1077 if test "${enable_polkit}" = "yes"; then
1078         if test "${enable_modify_system}" = "yes"; then
1079                 echo "  policykit: yes (permissive modify.system) (default=${enable_polkit})"
1080         else
1081                 echo "  policykit: yes (restrictive modify.system) (default=${enable_polkit})"
1082         fi
1083 else
1084         echo  "  policykit: no"
1085 fi
1086 echo "  polkit agent: ${enable_polkit_agent}"
1087 echo "  selinux: $have_selinux"
1088 echo "  hostname persist: ${hostname_persist}"
1089 echo
1090
1091 echo "Features:"
1092 echo "  wext: $ac_with_wext"
1093 echo "  wifi: $enable_wifi"
1094 echo "  ppp: $enable_ppp"
1095 echo "  modemmanager-1: $with_modem_manager_1"
1096 echo "  concheck: $enable_concheck"
1097 echo "  libteamdctl: $enable_teamdctl"
1098 echo "  nmtui: $build_nmtui"
1099 echo
1100
1101 echo "Configuration plugins (main.plugins=${config_plugins_default})"
1102 echo "  ibft: ${enable_config_plugin_ibft}"
1103 echo "  ifcfg-rh: ${enable_ifcfg_rh}"
1104 echo "  ifupdown: ${enable_ifupdown}"
1105 echo "  ifnet: ${enable_ifnet}"
1106 echo
1107
1108 echo "Handlers for /etc/resolv.conf:"
1109 echo "  resolvconf: ${with_resolvconf}"
1110 echo "  netconfig: ${with_netconfig}"
1111 echo
1112
1113 echo "DHCP clients:"
1114 echo "  dhclient: $with_dhclient"
1115 echo "  dhcpcd: $with_dhcpcd"
1116 echo
1117
1118 echo "Miscellaneous:"
1119 echo "  documentation: $enable_gtk_doc"
1120 echo "  tests: $enable_tests"
1121 echo "  valgrind: $with_valgrind   $with_valgrind_suppressions"
1122 echo "  code coverage: $enable_code_coverage"
1123 echo "  LTO: $enable_lto"
1124 echo