configure.ac

   1 AC_PREREQ([2.63])
   2
   3 dnl The NM version number
   4 m4_define([nm_major_version], [1])
   5 m4_define([nm_minor_version], [1])
   6 m4_define([nm_micro_version], [0])
   7 m4_define([nm_version],
   8           [nm_major_version.nm_minor_version.nm_micro_version])
   9 m4_define([nm_git_sha], [m4_esyscmd([ ( [ -d ./.git/ ] && [ "$(readlink -f ./.git/)" = "$(readlink -f "$(git rev-parse --git-dir 2>/dev/null)" 2>/dev/null)" ] && git rev-parse --verify -q HEAD 2>/dev/null ) || true ])])
  10
  11 AC_INIT([NetworkManager], [nm_version],
  12         [http://bugzilla.gnome.org/enter_bug.cgi?product=NetworkManager],
  13         [NetworkManager])
  14
  15 AC_CONFIG_HEADERS([config.h])
  16 AC_CONFIG_MACRO_DIR([m4])
  17 AC_CONFIG_AUX_DIR([build-aux])
  18 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  19
  20 AM_INIT_AUTOMAKE(1.12 tar-ustar no-dist-gzip dist-bzip2 -Wno-portability)  dnl NB: Do not [quote] this parameter.
  21 AM_MAINTAINER_MODE([enable])
  22 AM_SILENT_RULES([yes])
  23
  24 dnl Define _SYSTEM_EXTENSIONS for various things like strcasestr()
  25 AC_USE_SYSTEM_EXTENSIONS
  26
  27 dnl
  28 dnl Require programs
  29 dnl
  30 AC_PROG_CC
  31 AM_PROG_CC_C_O
  32
  33 # C++ only required if --enable-qt=yes
  34 AC_PROG_CXX
  35
  36 dnl Initialize libtool
  37 LT_PREREQ([2.2])
  38 LT_INIT([disable-static])
  39
  40 dnl Version stuff
  41 NM_MAJOR_VERSION=nm_major_version
  42 NM_MINOR_VERSION=nm_minor_version
  43 NM_MICRO_VERSION=nm_micro_version
  44 NM_VERSION=nm_version
  45 NM_GIT_SHA=nm_git_sha
  46 AC_SUBST(NM_MAJOR_VERSION)
  47 AC_SUBST(NM_MINOR_VERSION)
  48 AC_SUBST(NM_MICRO_VERSION)
  49 AC_SUBST(NM_VERSION)
  50 AC_DEFINE_UNQUOTED(NM_GIT_SHA,"$NM_GIT_SHA",[git commit id of the original source code version])
  51
  52 dnl
  53 dnl Checks for typedefs, structures, and compiler characteristics.
  54 dnl
  55 AC_TYPE_PID_T
  56
  57 dnl
  58 dnl translation support
  59 dnl
  60 IT_PROG_INTLTOOL([0.40.0])
  61
  62 AM_GNU_GETTEXT([external])
  63 AM_GNU_GETTEXT_VERSION([0.17])
  64
  65 GETTEXT_PACKAGE=NetworkManager
  66 AC_SUBST(GETTEXT_PACKAGE)
  67 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [Gettext package])
  68
  69 dnl
  70 dnl Make sha1.c happy on big endian systems
  71 dnl
  72 AC_C_BIGENDIAN
  73
  74 # Add runstatedir if not specified manually in autoconf < 2.70
  75 AS_IF([test -z "$runstatedir"], runstatedir="$localstatedir/run")
  76 AC_SUBST(runstatedir)
  77
  78 # NetworkManager paths
  79 AC_SUBST(nmbinary, "$sbindir/$PACKAGE", [NetworkManager binary executable])
  80 AC_SUBST(nmconfdir, "$sysconfdir/$PACKAGE", [NetworkManager configuration directory])
  81 AC_SUBST(nmlibdir, "$prefix/lib/$PACKAGE", [NetworkManager library directory])
  82 AC_SUBST(nmdatadir, "$datadir/$PACKAGE", [NetworkManager shared data directory])
  83 AC_SUBST(nmstatedir, "$localstatedir/lib/$PACKAGE", [NetworkManager persistent state directory])
  84 AC_SUBST(nmrundir, "$runstatedir/$PACKAGE", [NetworkManager runtime state directory])
  85
  86 # Alternative configuration plugins
  87 AC_ARG_ENABLE(config-plugin-ibft, AS_HELP_STRING([--enable-config-plugin-ibft], [enable ibft configuration plugin]))
  88 AC_ARG_ENABLE(ifcfg-rh, AS_HELP_STRING([--enable-ifcfg-rh], [enable ifcfg-rh configuration plugin (Fedora/RHEL)]))
  89 AC_ARG_ENABLE(ifcfg-suse, AS_HELP_STRING([--enable-ifcfg-suse], [enable ifcfg-suse configuration plugin (SUSE) (deprecated)]))
  90 AC_ARG_ENABLE(ifupdown, AS_HELP_STRING([--enable-ifupdown], [enable ifupdown configuration plugin (Debian/Ubuntu)]))
  91 AC_ARG_ENABLE(ifnet, AS_HELP_STRING([--enable-ifnet], [enable ifnet configuration plugin (Gentoo)]))
  92 # Default alternative plugins by distribution
  93 AS_IF([test -z "$enable_ifcfg_rh"], AC_CHECK_FILE(/etc/redhat-release, enable_ifcfg_rh=yes))
  94 AS_IF([test -z "$enable_ifcfg_rh"], AC_CHECK_FILE(/etc/fedora-release, enable_ifcfg_rh=yes))
  95 AS_IF([test -z "$enable_ifcfg_rh"], AC_CHECK_FILE(/etc/mandriva-release, enable_ifcfg_rh=yes))
  96 AS_IF([test -z "$enable_ifcfg_suse"], AC_CHECK_FILE(/etc/SuSE-release, enable_ifcfg_suse=yes))
  97 AS_IF([test -z "$enable_ifupdown"], AC_CHECK_FILE(/etc/debian_version, enable_ifupdown=yes))
  98 AS_IF([test -z "$enable_ifnet"], AC_CHECK_FILE(/etc/gentoo-release, enable_ifnet=yes))
  99 # Otherwise plugins default to "no"
 100 AS_IF([test -z "$enable_ifcfg_rh"], enable_ifcfg_rh=no)
 101 AS_IF([test -z "$enable_ifcfg_suse"], enable_ifcfg_suse=no)
 102 AS_IF([test -z "$enable_ifupdown"], enable_ifupdown=no)
 103 AS_IF([test -z "$enable_ifnet"], enable_ifnet=no)
 104 # Enable ibft by default
 105 AS_IF([test -z "$enable_config_plugin_ibft"], enable_config_plugin_ibft="yes")
 106 # Create automake conditionals
 107 AM_CONDITIONAL(CONFIG_PLUGIN_IBFT, test "$enable_config_plugin_ibft" = "yes")
 108 AM_CONDITIONAL(CONFIG_PLUGIN_IFCFG_RH, test "$enable_ifcfg_rh" = "yes")
 109 AM_CONDITIONAL(CONFIG_PLUGIN_IFUPDOWN, test "$enable_ifupdown" = "yes")
 110 AM_CONDITIONAL(CONFIG_PLUGIN_IFNET, test "$enable_ifnet" = "yes")
 111
 112 AC_ARG_WITH(config-plugins-default, AS_HELP_STRING([--with-config-plugins-default=PLUGINS], [Default configuration option for main.plugins setting, used as fallback if the configuration option is unset]), [config_plugins_default="$withval"], [config_plugins_default=""])
 113 if test -z "$config_plugins_default" -o "$config_plugins_default" = no; then
 114     config_plugins_default=''
 115     test "$enable_ifcfg_rh" = "yes"           && config_plugins_default="$config_plugins_default,ifcfg-rh"
 116     test "$enable_ifupdown" = "yes"           && config_plugins_default="$config_plugins_default,ifupdown"
 117     test "$enable_ifnet" = "yes"              && config_plugins_default="$config_plugins_default,ifnet"
 118     test "$enable_config_plugin_ibft" = "yes" && config_plugins_default="$config_plugins_default,ibft"
 119     config_plugins_default="${config_plugins_default#,}"
 120 fi
 121
 122 test "$enable_ifcfg_rh" = "yes"           && distro_plugins="$distro_plugins,ifcfg-rh"
 123 test "$enable_ifcfg_suse" = "yes"         && distro_plugins="$distro_plugins,ifcfg-suse"
 124 test "$enable_ifupdown" = "yes"           && distro_plugins="$distro_plugins,ifupdown"
 125 test "$enable_ifnet" = "yes"              && distro_plugins="$distro_plugins,ifnet"
 126 distro_plugins="${distro_plugins#,}"
 127
 128 AC_DEFINE_UNQUOTED(CONFIG_PLUGINS_DEFAULT, "$config_plugins_default", [Default configuration option for main.plugins setting])
 129 if test "${enable_config_plugin_ibft}" = yes; then
 130         AC_DEFINE(WITH_SETTINGS_PLUGIN_IBFT, 1, [Whether compilation of ibft setting plugin is enabled])
 131 else
 132         AC_DEFINE(WITH_SETTINGS_PLUGIN_IBFT, 0, [Whether compilation of ibft setting plugin is enabled])
 133 fi
 134
 135 if test "$enable_ifcfg_rh" = "yes"; then
 136     DISTRO_NETWORK_SERVICE=network.service
 137 fi
 138 AC_SUBST(DISTRO_NETWORK_SERVICE)
 139
 140 # Code coverage
 141 GNOME_CODE_COVERAGE
 142
 143 dnl
 144 dnl Distribution version string
 145 dnl
 146 AC_ARG_WITH(dist-version, AS_HELP_STRING([--with-dist-version=<NM-distribution-version>], [Define the NM''s distribution version string]), ac_distver=$withval, ac_distver="")
 147 if ! test x"$ac_distver" = x""; then
 148   AC_DEFINE_UNQUOTED(NM_DIST_VERSION, "$ac_distver", [Define the distribution version string])
 149 fi
 150
 151 AC_ARG_ENABLE(wifi, AS_HELP_STRING([--enable-wifi], [enable Wi-Fi support]))
 152 if test "${enable_wifi}" != "no"; then
 153         enable_wifi='yes'
 154         AC_DEFINE(WITH_WIFI, 1, [Define if you have Wi-Fi support])
 155 else
 156         AC_DEFINE(WITH_WIFI, 0, [Define if you have Wi-Fi support])
 157 fi
 158 AM_CONDITIONAL(WITH_WIFI, test "${enable_wifi}" = "yes")
 159
 160 dnl
 161 dnl Default to using WEXT but allow it to be disabled
 162 dnl
 163 AC_ARG_WITH(wext, AS_HELP_STRING([--with-wext=yes], [Enable or disable Linux Wireless Extensions]), ac_with_wext=$withval, ac_with_wext="$enable_wifi")
 164 if test "$ac_with_wext" != 'no'; then
 165         ac_with_wext='yes'
 166 fi
 167 if test x"$ac_with_wext" = x"yes"; then
 168         if test "$enable_wifi" != "yes"; then
 169                 AC_MSG_ERROR(Enabling WEXT support and disabling Wi-Fi makes no sense)
 170         fi
 171         AC_MSG_CHECKING([Linux kernel WEXT headers])
 172         AC_COMPILE_IFELSE(
 173                 [AC_LANG_PROGRAM(
 174                       [[#ifndef __user
 175                         #define __user
 176                         #endif
 177                         #include <sys/types.h>
 178                         #include <linux/types.h>
 179                         #include <sys/socket.h>
 180                         #include <linux/wireless.h>]],
 181                       [[#ifndef IWEVGENIE
 182                         #error "not found"
 183                         #endif]])],
 184                 [ac_have_iwevgenie=yes],
 185                 [ac_have_iwevgenie=no])
 186         AC_MSG_RESULT($ac_have_iwevgenie)
 187         if test "$ac_have_iwevgenie" = no; then
 188                AC_MSG_ERROR(Linux kernel development header linux/wireless.h not installed or not functional)
 189         fi
 190         AC_DEFINE(HAVE_WEXT, 1, [Define if you have Linux Wireless Extensions support])
 191 else
 192         AC_DEFINE(HAVE_WEXT, 0, [Define if you have Linux Wireless Extensions support])
 193 fi
 194 AM_CONDITIONAL(WITH_WEXT, test x"${ac_with_wext}" = x"yes")
 195
 196 AC_MSG_CHECKING([Linux kernel nl80211 headers])
 197 AC_COMPILE_IFELSE(
 198         [AC_LANG_PROGRAM(
 199               [[#ifndef __user
 200                 #define __user
 201                 #endif
 202                 #include <sys/types.h>
 203                 #include <linux/types.h>
 204                 #include <sys/socket.h>
 205                 #include <linux/nl80211.h>]],
 206               [[int a = NL80211_RATE_INFO_BITRATE; a++;]])],
 207         [ac_have_nl80211=yes],
 208         [ac_have_nl80211=no])
 209 AC_MSG_RESULT($ac_have_nl80211)
 210 if test "$ac_have_nl80211" = no; then
 211         AC_MSG_ERROR(Linux kernel development header linux/nl80211.h not installed or not functional)
 212 fi
 213
 214 if test "$with_wifi" = "yes"; then
 215         AC_MSG_CHECKING([Linux kernel nl80211 Critical Protocol Start/Stop])
 216         AC_COMPILE_IFELSE(
 217                 [AC_LANG_PROGRAM(
 218                   [[#ifndef __user
 219                     #define __user
 220                     #endif
 221                     #include <sys/types.h>
 222                     #include <linux/types.h>
 223                     #include <sys/socket.h>
 224                     #include <linux/nl80211.h>]],
 225                   [[unsigned int a = NL80211_CMD_CRIT_PROTOCOL_START; a++;]])],
 226                 [ac_have_nl80211_critproto=yes],
 227                 [ac_have_nl80211_critproto=no])
 228         AC_MSG_RESULT($ac_have_nl80211_critproto)
 229 else
 230         ac_have_nl80211_critproto='no'
 231 fi
 232 if test "$ac_have_nl80211_critproto" = yes; then
 233         AC_DEFINE(HAVE_NL80211_CRITICAL_PROTOCOL_CMDS, 1, [Define if nl80211 has critical protocol support])
 234 else
 235         AC_DEFINE(HAVE_NL80211_CRITICAL_PROTOCOL_CMDS, 0, [Define if nl80211 has critical protocol support])
 236 fi
 237
 238 dnl
 239 dnl Check for newer VLAN flags
 240 dnl
 241 AC_MSG_CHECKING([Linux kernel VLAN_FLAG_LOOSE_BINDING enum value])
 242 AC_COMPILE_IFELSE(
 243         [AC_LANG_PROGRAM(
 244               [[#ifndef __user
 245                 #define __user
 246                 #endif
 247                 #include <sys/types.h>
 248                 #include <linux/types.h>
 249                 #include <linux/if_vlan.h>]],
 250               [[unsigned int a = VLAN_FLAG_LOOSE_BINDING;]])],
 251         [ac_have_vlan_flag_loose_binding=yes],
 252         [ac_have_vlan_flag_loose_binding=no])
 253 AC_MSG_RESULT($ac_have_vlan_flag_loose_binding)
 254 if test "$ac_have_vlan_flag_loose_binding" = yes; then
 255         AC_DEFINE(HAVE_VLAN_FLAG_LOOSE_BINDING, 1, [Define if you have VLAN_FLAG_LOOSE_BINDING])
 256 else
 257         AC_DEFINE(HAVE_VLAN_FLAG_LOOSE_BINDING, 0, [Define if you have VLAN_FLAG_LOOSE_BINDING])
 258 fi
 259
 260 dnl
 261 dnl Checks for libm - needed for pow()
 262 dnl
 263 LT_LIB_M
 264
 265 dnl
 266 dnl Checks for libdl - on certain platforms its part of libc
 267 dnl
 268 AC_CHECK_LIB([dl], [dladdr], LIBDL="-ldl", LIBDL="")
 269 AC_SUBST(LIBDL)
 270
 271 dnl
 272 dnl Checks for dbus-glib
 273 dnl
 274 PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.1 dbus-glib-1 >= 0.94)
 275
 276 PKG_CHECK_MODULES(GLIB, [gio-unix-2.0 >= 2.37.6 gmodule-2.0],
 277         [AC_SUBST(LOG_DRIVER, '$(top_srcdir)/build-aux/tap-driver.sh'),
 278          AC_SUBST(AM_TESTS_FD_REDIRECT, '--tap')],
 279         [PKG_CHECK_MODULES(GLIB, gio-unix-2.0 >= 2.32 gmodule-2.0)
 280          AC_SUBST(LOG_DRIVER, '$(top_srcdir)/build-aux/test-driver')])
 281
 282 dnl GLIB_VERSION_MIN_REQUIRED should match the version above.
 283 dnl GLIB_VERSION_MAX_ALLOWED should be set to the same version;
 284 dnl nm-glib.h will cause it to be overridden for the functions
 285 dnl we have compat versions of.
 286 GLIB_CFLAGS="$GLIB_CFLAGS -DGLIB_VERSION_MIN_REQUIRED=GLIB_VERSION_2_32 -DGLIB_VERSION_MAX_ALLOWED=GLIB_VERSION_2_32"
 287
 288 AC_SUBST(GLIB_CFLAGS)
 289 AC_SUBST(GLIB_LIBS)
 290
 291 PKG_CHECK_MODULES(GUDEV, gudev-1.0 >= 165)
 292
 293 GOBJECT_INTROSPECTION_CHECK([0.9.6])
 294
 295 # Qt4
 296 PKG_CHECK_MODULES(QT, [QtCore >= 4 QtDBus QtNetwork], [have_qt=yes],[have_qt=no])
 297 AC_ARG_ENABLE(qt, AS_HELP_STRING([--enable-qt], [enable Qt examples]),
 298                      [enable_qt=${enableval}], [enable_qt=${have_qt}])
 299 if (test "${enable_qt}" = "yes"); then
 300         if test x"$have_qt" = x"no"; then
 301                 AC_MSG_ERROR(Qt development headers are required)
 302         fi
 303         # Check for moc-qt4 and if not found then moc
 304         QT4_BINDIR=`$PKG_CONFIG QtCore --variable moc_location`
 305         AC_CHECK_PROGS(MOC, [moc-qt4 moc],, [$QT4_BINDIR:$PATH])
 306 fi
 307 AM_CONDITIONAL(WITH_QT, test "${enable_qt}" = "yes")
 308
 309 AC_ARG_WITH(udev-dir, AS_HELP_STRING([--with-udev-dir=DIR], [Absolute path of the udev base directory. Set to 'no' not to install the udev rules]), [], [with_udev_dir="yes"])
 310 if (test "$with_udev_dir" != 'no'); then
 311         if (test "$with_udev_dir" != 'yes' && printf '%s' "$with_udev_dir" | grep -v -q '^/'); then
 312                 AC_MSG_ERROR([--with-udev-dir must be an absolute path or 'yes' or 'no'. Instead it is '$with_udev_dir'])
 313         fi
 314         if (test "$with_udev_dir" = 'yes'); then
 315                 with_udev_dir="/lib/udev"
 316         fi
 317         UDEV_DIR="$with_udev_dir"
 318         AC_SUBST(UDEV_DIR)
 319 fi
 320 AM_CONDITIONAL(WITH_UDEV_DIR, test "$with_udev_dir" != 'no')
 321
 322 # systemd unit support
 323 AC_ARG_WITH([systemdsystemunitdir], AS_HELP_STRING([--with-systemdsystemunitdir=DIR],
 324         [Directory for systemd service files]))
 325 # default location
 326 AS_IF([test -z "$with_systemdsystemunitdir" && $PKG_CONFIG systemd],
 327         with_systemdsystemunitdir="\$(prefix)/lib/systemd/system")
 328 AS_IF([test -z "$with_systemdsystemunitdir"], with_systemdsystemunitdir=no)
 329 # add conditional and subst
 330 AM_CONDITIONAL(HAVE_SYSTEMD, [test "$with_systemdsystemunitdir" != no])
 331 if test "$with_systemdsystemunitdir" != no; then
 332         AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
 333         AC_DEFINE(HAVE_SYSTEMD, 1, [Define if systemd support is available])
 334 else
 335         AC_DEFINE(HAVE_SYSTEMD, 0, [Define if systemd support is available])
 336 fi
 337
 338 PKG_CHECK_MODULES(SYSTEMD_200, [systemd >= 200], [have_systemd_200=yes],[have_systemd_200=no])
 339 AM_CONDITIONAL(HAVE_SYSTEMD_200, test "${have_systemd_200}" = "yes")
 340
 341 # Hostname persist mode
 342 AC_ARG_WITH(hostname-persist, AS_HELP_STRING([--with-hostname-persist=default|suse|gentoo],
 343         [Hostname persist method]))
 344
 345 AS_IF([test "$with_hostname_persist" = "suse"], hostname_persist=suse)
 346 AS_IF([test "$with_hostname_persist" = "gentoo"], hostname_persist=gentoo)
 347 AS_IF([test "$with_hostname_persist" = "default"], hostname_persist=default)
 348 # if the method was not explicitly set, try to guess it from the enabled plugins
 349 AS_IF([test -z "$hostname_persist" -a "$distro_plugins" = "ifcfg-suse"], hostname_persist=suse)
 350 AS_IF([test -z "$hostname_persist" -a "$distro_plugins" = "ifnet"], hostname_persist=gentoo)
 351 AS_IF([test -z "$hostname_persist"], hostname_persist=default)
 352
 353 if test "$hostname_persist" = suse; then
 354         AC_DEFINE(HOSTNAME_PERSIST_SUSE, 1, [Enable SuSE hostname persist method])
 355 elif test "$hostname_persist" = gentoo; then
 356         AC_DEFINE(HOSTNAME_PERSIST_GENTOO, 1, [Enable Gentoo hostname persist method])
 357 fi
 358
 359 AC_ARG_WITH(systemd-journal, AS_HELP_STRING([--with-systemd-journal=yes|no], [Use systemd journal for logging]))
 360 have_systemd_journal=no
 361 if test "$with_systemd_journal" != "no"; then
 362         PKG_CHECK_MODULES(SYSTEMD_JOURNAL,
 363                           [libsystemd >= 209],
 364                           [have_systemd_journal=yes],
 365                           [PKG_CHECK_MODULES(SYSTEMD_JOURNAL,
 366                                              [libsystemd-journal],
 367                                              [have_systemd_journal=yes],
 368                                              [have_systemd_journal=no])])
 369         if test "$have_systemd_journal" != "yes"; then
 370                 if test "$with_systemd_journal" = "yes"; then
 371                         AC_MSG_ERROR([Missing systemd-journald support])
 372                 fi
 373         fi
 374 fi
 375 if test "$have_systemd_journal" = "yes"; then
 376         AC_DEFINE([SYSTEMD_JOURNAL], 1, [Define to 1 if libsystemd-journald is available])
 377 else
 378         AC_DEFINE([SYSTEMD_JOURNAL], 0, [Define to 1 if libsystemd-journald is available])
 379 fi
 380
 381 AC_ARG_WITH(config-logging-backend-default, AS_HELP_STRING([--with-logging-backend-default=backend], [Default value for logging.backend]), nm_config_logging_backend_default="$withval", nm_config_logging_backend_default="")
 382 if test "$nm_config_logging_backend_default" != 'debug' \
 383      -a "$nm_config_logging_backend_default" != 'syslog' \
 384      -a "$nm_config_logging_backend_default" != 'journal' \
 385      -a "$nm_config_logging_backend_default" != 'journal-syslog-style'; then
 386         # unknown backend. Reset to default. Silently accept the invalid value to
 387         # be future proof.
 388         nm_config_logging_backend_default=''
 389 fi
 390 if test "$nm_config_logging_backend_default" = ""; then
 391         if test "$have_systemd_journal" = "yes"; then
 392                 nm_config_logging_backend_default='journal-syslog-style'
 393         else
 394                 nm_config_logging_backend_default='syslog'
 395         fi
 396 fi
 397 AC_DEFINE_UNQUOTED(NM_CONFIG_LOGGING_BACKEND_DEFAULT, "$nm_config_logging_backend_default", [Default configuration option for logging.backend])
 398 NM_CONFIG_LOGGING_BACKEND_DEFAULT_TEXT="$nm_config_logging_backend_default"
 399 AC_SUBST(NM_CONFIG_LOGGING_BACKEND_DEFAULT_TEXT)
 400
 401 # Session tracking support
 402 AC_ARG_WITH(systemd-logind, AS_HELP_STRING([--with-systemd-logind=yes|no],
 403         [Support systemd session tracking]))
 404 AC_ARG_WITH(consolekit, AS_HELP_STRING([--with-consolekit=yes|no],
 405         [Support consolekit session tracking]))
 406 AC_ARG_WITH(session-tracking, AS_HELP_STRING([--with-session-tracking=systemd|consolekit|no],
 407         [Compatibility option to choose one session tracking module]))
 408 # backwards compatibility
 409 AS_IF([test "$with_session_tracking" = "ck"], [use_consolekit="yes" use_systemd_logind="no"])
 410 AS_IF([test "$with_session_tracking" = "consolekit"], [use_consolekit="yes" use_systemd_logind="no"])
 411 AS_IF([test "$with_session_tracking" = "systemd"], [use_consolekit="no" use_systemd_logind="yes"])
 412 AS_IF([test "$with_session_tracking" = "no"], [use_consolekit="no" use_systemd_logind="no"])
 413 AS_IF([test "$with_session_tracking" = "none"], [use_consolekit="no" use_systemd_logind="no"])
 414 # current options
 415 AS_IF([test -n "$with_systemd_logind" ], [use_systemd_logind="$with_systemd_logind"])
 416 AS_IF([test -n "$with_consolekit" ], [use_consolekit="$with_consolekit"])
 417 # defaults
 418 AS_IF([test -z "$use_systemd_logind"], [use_systemd_logind="auto"])
 419 AS_IF([test -z "$use_consolekit"], [use_consolekit="yes"])
 420 # output
 421 session_tracking=
 422 if test "$use_systemd_logind" = "yes" -o "$use_systemd_logind" = "auto"; then
 423     PKG_CHECK_MODULES(SYSTEMD_LOGIN, [libsystemd], [have_systemd_logind=yes], [PKG_CHECK_MODULES(SYSTEMD_LOGIN, [libsystemd-login], [have_systemd_logind=yes], [have_systemd_logind=no])])
 424 else
 425     have_systemd_logind=no
 426 fi
 427 if test "$use_systemd_logind" = "yes" -a "$have_systemd_logind" = "no"; then
 428     AC_MSG_ERROR([You must have libsystemd installed to build with systemd-logind support.])
 429 fi
 430 if test "$have_systemd_logind" = "yes"; then
 431         AC_DEFINE([SESSION_TRACKING_SYSTEMD], 1, [Define to 1 if libsystemd-login is available])
 432         session_tracking="$session_tracking, systemd-logind"
 433 fi
 434 if test "$use_consolekit" = "yes"; then
 435         AC_DEFINE([SESSION_TRACKING_CONSOLEKIT], 1, [Define to 1 if ConsoleKit is available])
 436         AC_DEFINE([CKDB_PATH], "/var/run/ConsoleKit/database", [Path to ConsoleKit database])
 437         session_tracking="$session_tracking, consolekit"
 438 fi
 439 session_tracking="$(printf '%s' "${session_tracking}" | sed 's/^, //')"
 440
 441 AC_ARG_WITH(suspend-resume, AS_HELP_STRING([--with-suspend-resume=upower|systemd|consolekit], [Build NetworkManager with specific suspend/resume support]))
 442 if test "z$with_suspend_resume" = "z"; then
 443     PKG_CHECK_EXISTS([libsystemd >= 209], [have_systemd_inhibit=yes],
 444                      [PKG_CHECK_EXISTS([libsystemd-login >= 183], [have_systemd_inhibit=yes], [have_systemd_inhibit=no])])
 445     if test "z${have_systemd_inhibit}" = "zyes"; then
 446         # Use systemd if it's new enough
 447         with_suspend_resume="systemd"
 448     else
 449         if test "$use_consolekit" = "yes"; then
 450                 # Use consolekit suspend if session tracking is consolekit
 451                 with_suspend_resume="consolekit"
 452         else
 453                 # Fall back to upower
 454                 with_suspend_resume="upower"
 455         fi
 456     fi
 457 fi
 458
 459 case $with_suspend_resume in
 460     upower) ;;
 461     systemd)
 462         PKG_CHECK_MODULES(SYSTEMD_INHIBIT, [libsystemd >= 209],,
 463                           [PKG_CHECK_MODULES(SYSTEMD_INHIBIT, [libsystemd-login >= 183])])
 464         AC_DEFINE([SUSPEND_RESUME_SYSTEMD], 1, [Define to 1 to use systemd suspend api])
 465         ;;
 466     consolekit)
 467         AC_DEFINE([SUSPEND_RESUME_CONSOLEKIT], 1, [Define to 1 to use ConsoleKit2 suspend api])
 468         ;;
 469     *)
 470         AC_MSG_ERROR(--with-suspend-resume must be one of [upower, systemd, consolekit])
 471         ;;
 472 esac
 473 AM_CONDITIONAL(SUSPEND_RESUME_UPOWER, test "x$with_suspend_resume" = "xupower")
 474 AM_CONDITIONAL(SUSPEND_RESUME_SYSTEMD, test "x$with_suspend_resume" = "xsystemd")
 475 AM_CONDITIONAL(SUSPEND_RESUME_CONSOLEKIT, test "x$with_suspend_resume" = "xconsolekit")
 476
 477 # SELinux support
 478 AC_ARG_WITH(selinux, AS_HELP_STRING([--with-selinux=yes|no|auto], [Build with SELinux (default: auto)]),,[with_selinux=auto])
 479 if test "$with_selinux" = "yes" -o "$with_selinux" = "auto"; then
 480     PKG_CHECK_MODULES(SELINUX, libselinux, [have_selinux=yes], [have_selinux=no])
 481 else
 482     have_selinux=no
 483 fi
 484 if test "$with_selinux" = "yes" -a "$have_selinux" = "no"; then
 485     AC_MSG_ERROR([You must have libselinux installed to build --with-selinux=yes.])
 486 fi
 487 if test "$have_selinux" = "yes"; then
 488     AC_DEFINE(HAVE_SELINUX, 1, [Define if you have SELinux support])
 489 else
 490     AC_DEFINE(HAVE_SELINUX, 0, [Define if you have SELinux support])
 491 fi
 492
 493 # libaudit support
 494 AC_ARG_WITH(libaudit, AS_HELP_STRING([--with-libaudit=yes|yes-disabled-by-default|no|auto], [Build with audit daemon support (default: auto). yes-disabled-by-default enables support, but disables it unless explicitly configured via NetworkManager.conf]),,[with_libaudit=auto])
 495 if test "$with_libaudit" = "yes" -o "$with_libaudit" = "yes-disabled-by-default" -o "$with_libaudit" = "auto"; then
 496     PKG_CHECK_MODULES(LIBAUDIT, audit, [have_libaudit=yes], [have_libaudit=no])
 497     if test "$with_libaudit" != "auto" -a "$have_libaudit" = "no"; then
 498         AC_MSG_ERROR([You must have libaudit installed to build --with-libaudit=$with_libaudit.])
 499     fi
 500 else
 501     have_libaudit=no
 502 fi
 503 if test "$have_libaudit" = "yes"; then
 504     AC_DEFINE(HAVE_LIBAUDIT, 1, [Define if you have libaudit support])
 505         if test "$with_libaudit" = "yes-disabled-by-default"; then
 506                 AC_DEFINE(NM_CONFIG_DEFAULT_LOGGING_AUDIT, FALSE, [The default value of the logging.audit configuration option])
 507                 NM_CONFIG_DEFAULT_LOGGING_AUDIT_TEXT='false'
 508         else
 509                 AC_DEFINE(NM_CONFIG_DEFAULT_LOGGING_AUDIT, TRUE,  [The default value of the logging.audit configuration option])
 510                 NM_CONFIG_DEFAULT_LOGGING_AUDIT_TEXT='true'
 511         fi
 512 else
 513     AC_DEFINE(HAVE_LIBAUDIT, 0, [Define if you have libaudit support])
 514         AC_DEFINE(NM_CONFIG_DEFAULT_LOGGING_AUDIT, FALSE, [The default value of the logging.audit configuration option])
 515     NM_CONFIG_DEFAULT_LOGGING_AUDIT_TEXT='false'
 516 fi
 517 AC_SUBST(NM_CONFIG_DEFAULT_LOGGING_AUDIT_TEXT)
 518
 519 # libnl support for the linux platform
 520 PKG_CHECK_MODULES(LIBNL, libnl-3.0 >= 3.2.8 libnl-route-3.0 libnl-genl-3.0)
 521
 522 AC_CHECK_LIB([nl-route-3], [rtnl_link_inet6_get_addr_gen_mode],
 523         ac_have_addr_gen_mode="1",
 524         ac_have_addr_gen_mode="0")
 525 AC_DEFINE_UNQUOTED(HAVE_LIBNL_INET6_ADDR_GEN_MODE,
 526         $ac_have_addr_gen_mode, [Define if libnl has rtnl_link_inet6_get_addr_gen_mode()])
 527
 528 AC_MSG_CHECKING([Linux kernel IN6_ADDR_GEN_MODE enum])
 529 AC_COMPILE_IFELSE(
 530         [AC_LANG_PROGRAM(
 531               [[#ifndef __user
 532                 #define __user
 533                 #endif
 534                 #include <linux/if_link.h>]],
 535               [[int a = IN6_ADDR_GEN_MODE_EUI64; a++;]])],
 536         [ac_have_kernel_gen_mode=yes],
 537         [ac_have_kernel_gen_mode=no])
 538 AC_MSG_RESULT($ac_have_kernel_gen_mode)
 539 if test "$ac_have_kernel_gen_mode" = yes; then
 540         AC_DEFINE(HAVE_KERNEL_INET6_ADDR_GEN_MODE, 1, [Define if the kernel has IN6_ADDR_GEN_MODE_*])
 541 else
 542         AC_DEFINE(HAVE_KERNEL_INET6_ADDR_GEN_MODE, 0, [Define if the kernel has IN6_ADDR_GEN_MODE_*])
 543 fi
 544
 545 # IPv6 tokenized identifiers support in libnl
 546 AC_CHECK_LIB([nl-route-3], [rtnl_link_inet6_get_token],
 547         ac_have_ipv6_token="1",
 548         ac_have_ipv6_token="0")
 549 AC_DEFINE_UNQUOTED(HAVE_LIBNL_INET6_TOKEN,
 550         $ac_have_ipv6_token, [Define if libnl has rtnl_link_inet6_get_token()])
 551
 552 # uuid library
 553 PKG_CHECK_MODULES(UUID, uuid)
 554
 555 dnl Checks for readline library - used by nmcli
 556 AX_LIB_READLINE
 557
 558 # Teamd control checks
 559 PKG_CHECK_MODULES(LIBTEAMDCTL, [libteamdctl >= 1.9], [have_teamdctl=yes],[have_teamdctl=no])
 560 AC_ARG_ENABLE(teamdctl, AS_HELP_STRING([--enable-teamdctl], [enable Teamd control support]),
 561                      [enable_teamdctl=${enableval}], [enable_teamdctl=${have_teamdctl}])
 562 if (test "${enable_teamdctl}" = "yes"); then
 563         if test x"$have_teamdctl" = x"no"; then
 564                 AC_MSG_ERROR(Teamd control is required)
 565         fi
 566         # temporary bug workaround
 567         LIBTEAMDCTL_CFLAGS=`echo $LIBTEAMDCTL_CFLAGS | sed -e 's:/teamdctl.h::'`
 568         AC_DEFINE(WITH_TEAMDCTL, 1, [Define if you have Teamd control support])
 569 else
 570         AC_DEFINE(WITH_TEAMDCTL, 0, [Define if you have Teamd control support])
 571 fi
 572 AM_CONDITIONAL(WITH_TEAMDCTL, test "${enable_teamdctl}" = "yes")
 573
 574 # we usually compile with polkit support. --enable-polkit=yes|no only sets the
 575 # default configuration for main.auth-polkit. User can always enable/disable polkit
 576 # autorization via config. Only when specifying --enable-polkit=disabled, we do
 577 # not compile support. In this case, the user cannot enable polkit authorization via
 578 # configuration.
 579 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--enable-polkit=yes|no|disabled], [set default value for auth-polkit configuration option. This value can be overwritten by NM configuration. 'disabled' compiles NM without any support]),
 580                      [enable_polkit=${enableval}], [enable_polkit=yes])
 581 if (test "${enable_polkit}" != "no" -a "${enable_polkit}" != "disabled"); then
 582         enable_polkit=yes
 583         AC_DEFINE(NM_CONFIG_DEFAULT_AUTH_POLKIT, TRUE, [The default value of the auth-polkit configuration option])
 584         NM_CONFIG_DEFAULT_AUTH_POLKIT_TEXT='true'
 585 else
 586         AC_DEFINE(NM_CONFIG_DEFAULT_AUTH_POLKIT, FALSE, [The default value of the auth-polkit configuration option])
 587         NM_CONFIG_DEFAULT_AUTH_POLKIT_TEXT='false'
 588 fi
 589 if (test "${enable_polkit}" != "disabled"); then
 590         AC_DEFINE(WITH_POLKIT, 1, [whether to compile polkit support])
 591 else
 592         AC_DEFINE(WITH_POLKIT, 0, [whether to compile polkit support])
 593 fi
 594 AC_SUBST(NM_CONFIG_DEFAULT_AUTH_POLKIT_TEXT)
 595
 596 PKG_CHECK_MODULES(POLKIT, [polkit-agent-1 >= 0.97], [have_pk_agent=yes],[have_pk_agent=no])
 597 AC_ARG_ENABLE(polkit-agent, AS_HELP_STRING([--enable-polkit-agent], [enable polkit agent for clients]),
 598                      [enable_polkit_agent=${enableval}], [enable_polkit_agent=${have_pk_agent}])
 599 if (test "${enable_polkit_agent}" = "yes"); then
 600         if test x"$have_pk_agent" = x"no"; then
 601                 AC_MSG_ERROR(Polkit agent is required)
 602         fi
 603         AC_DEFINE(WITH_POLKIT_AGENT, 1, [Define if you have polkit agent])
 604 else
 605         AC_DEFINE(WITH_POLKIT_AGENT, 0, [Define if you have polkit agent])
 606 fi
 607 AM_CONDITIONAL(WITH_POLKIT_AGENT, test "${enable_polkit_agent}" = "yes")
 608
 609 AC_ARG_ENABLE(modify-system,
 610               AS_HELP_STRING([--enable-modify-system], [Allow users to modify system connections]))
 611 if test "${enable_modify_system}" = "yes"; then
 612         NM_MODIFY_SYSTEM_POLICY="yes"
 613 else
 614         NM_MODIFY_SYSTEM_POLICY="auth_admin_keep"
 615 fi
 616 AC_SUBST(NM_MODIFY_SYSTEM_POLICY)
 617
 618 AC_ARG_WITH(crypto, AS_HELP_STRING([--with-crypto=nss|gnutls], [Cryptography library to use for certificate and key operations]),ac_crypto=$withval, ac_crypto=nss)
 619
 620 with_nss=no
 621 with_gnutls=no
 622 if test x"$ac_crypto" = xnss; then
 623   PKG_CHECK_MODULES(NSS, [nss >= 3.11])
 624
 625   # Work around a pkg-config bug (fdo #29801) where exists != usable
 626   FOO=`$PKG_CONFIG --cflags --libs nss`
 627   if test x"$?" != "x0"; then
 628     AC_MSG_ERROR([No usable NSS found])
 629   fi
 630
 631   AC_DEFINE(HAVE_NSS, 1, [Define if you have NSS])
 632   with_nss=yes
 633 elif test x"$ac_crypto" = xgnutls; then
 634   PKG_CHECK_MODULES(GNUTLS, [gnutls >= 2.12])
 635   AC_DEFINE(HAVE_GNUTLS, 1, [Define if you have libgnutls])
 636   with_gnutls=yes
 637 else
 638   AC_MSG_ERROR([Please choose either 'nss' or 'gnutls' for certificate and crypto operations])
 639 fi
 640 AM_CONDITIONAL(WITH_NSS, test x"$with_nss" != xno)
 641 AM_CONDITIONAL(WITH_GNUTLS, test x"$with_gnutls" != xno)
 642
 643 # Shouldn't ever trigger this, but just in case...
 644 if test x"$ac_nss" = xno -a x"$ac_gnutls" = xno; then
 645   AC_MSG_ERROR([Could not find required development headers and libraries for '$ac_crypto'])
 646 fi
 647
 648 GLIB_MAKEFILE='$(top_srcdir)/Makefile.glib'
 649 AC_SUBST(GLIB_MAKEFILE)
 650 GLIB_GENMARSHAL=`pkg-config --variable=glib_genmarshal glib-2.0`
 651 AC_SUBST(GLIB_GENMARSHAL)
 652 GLIB_MKENUMS=`pkg-config --variable=glib_mkenums glib-2.0`
 653 AC_SUBST(GLIB_MKENUMS)
 654
 655 AC_ARG_WITH(dbus-sys-dir, AS_HELP_STRING([--with-dbus-sys-dir=DIR], [where D-BUS system.d directory is]))
 656
 657 if test -n "$with_dbus_sys_dir" ; then
 658     DBUS_SYS_DIR="$with_dbus_sys_dir"
 659 else
 660     DBUS_SYS_DIR="${sysconfdir}/dbus-1/system.d"
 661 fi
 662 AC_SUBST(DBUS_SYS_DIR)
 663
 664 # pppd
 665 AC_ARG_ENABLE(ppp, AS_HELP_STRING([--enable-ppp], [enable PPP/PPPoE support]),
 666                      [enable_ppp=${enableval}], [enable_ppp=yes])
 667 if (test "${enable_ppp}" = "yes"); then
 668         AC_CHECK_HEADERS(pppd/pppd.h,,
 669                 AC_MSG_ERROR("couldn't find pppd.h. pppd development headers are required."))
 670
 671         AC_DEFINE(WITH_PPP, 1, [Define if you have PPP support])
 672 else
 673         AC_DEFINE(WITH_PPP, 0, [Define if you have PPP support])
 674 fi
 675 AM_CONDITIONAL(WITH_PPP, test "${enable_ppp}" = "yes")
 676
 677 AC_ARG_WITH([pppd-plugin-dir], AS_HELP_STRING([--with-pppd-plugin-dir=DIR], [path to the pppd plugins directory]))
 678
 679 if test -n "$with_pppd_plugin_dir" ; then
 680         PPPD_PLUGIN_DIR="$with_pppd_plugin_dir"
 681 else
 682         PPPD_PLUGIN_DIR="${libdir}/pppd/2.4.5"
 683 fi
 684 AC_SUBST(PPPD_PLUGIN_DIR)
 685
 686 AC_ARG_WITH(pppd, AS_HELP_STRING([--with-pppd=/path/to/pppd], [path to pppd binary]))
 687 if test "x${with_pppd}" = x; then
 688   AC_PATH_PROG(PPPD_PATH, pppd, [], $PATH:/sbin:/usr/sbin)
 689 else
 690   PPPD_PATH="$with_pppd"
 691 fi
 692 AC_DEFINE_UNQUOTED(PPPD_PATH, "$PPPD_PATH", [Define to path of pppd binary])
 693 AC_SUBST(PPPD_PATH)
 694
 695 # ModemManager1 with libmm-glib
 696 AC_ARG_WITH(modem-manager-1, AS_HELP_STRING([--with-modem-manager-1], [Enable new ModemManager1 interface support]),,[with_modem_manager_1=auto])
 697 if (test "${with_modem_manager_1}" != "no"); then
 698     PKG_CHECK_MODULES(MM_GLIB,
 699                       [mm-glib >= 0.7.991],
 700                       [have_libmm_glib=yes],
 701                       [have_libmm_glib=no])
 702
 703     if (test "${have_libmm_glib}" = "no"); then
 704         if (test "${with_modem_manager_1}" = "yes"); then
 705             AC_MSG_ERROR([Couldn't find libmm-glib])
 706         else
 707             with_modem_manager_1="no"
 708         fi
 709     else
 710         with_modem_manager_1="yes"
 711     fi
 712 fi
 713
 714 if (test "${with_modem_manager_1}" = "yes"); then
 715     AC_DEFINE(WITH_MODEM_MANAGER_1, 1, [Define if you have ModemManager1 support])
 716 else
 717         AC_DEFINE(WITH_MODEM_MANAGER_1, 0, [Define if you have ModemManager1 support])
 718 fi
 719 AM_CONDITIONAL(WITH_MODEM_MANAGER_1, test "${with_modem_manager_1}" = "yes")
 720
 721 # Bluez5 DUN support
 722 PKG_CHECK_MODULES(BLUEZ5, [bluez >= 5], [have_bluez5=yes],[have_bluez5=no])
 723 AC_ARG_ENABLE(bluez5-dun, AS_HELP_STRING([--enable-bluez5-dun], [enable Bluez5 DUN support]),
 724                 [enable_bluez5_dun=${enableval}], [enable_bluez5_dun=${have_bluez5}])
 725 if (test "${enable_bluez5_dun}" = "yes"); then
 726         if test x"$have_bluez5" = x"no"; then
 727                 AC_MSG_ERROR(Bluez 5.x development headers are required)
 728         fi
 729         AC_DEFINE(WITH_BLUEZ5_DUN, 1, [Define if you have Bluez 5 libraries])
 730 else
 731         AC_DEFINE(WITH_BLUEZ5_DUN, 0, [Define if you have Bluez 5 libraries])
 732 fi
 733 AM_CONDITIONAL(WITH_BLUEZ5_DUN, test "${enable_bluez5_dun}" = "yes")
 734
 735 # DHCP client support
 736 AC_ARG_WITH([dhclient], AS_HELP_STRING([--with-dhclient=yes|no|path], [Enable dhclient 4.x support]))
 737 AC_ARG_WITH([dhcpcd], AS_HELP_STRING([--with-dhcpcd=yes|no|path], [Enable dhcpcd 4.x support]))
 738 # Default to "yes"
 739 AS_IF([test -z "$with_dhclient"], with_dhclient=yes)
 740 AS_IF([test -z "$with_dhcpcd"], with_dhcpcd=yes)
 741 # Search and check the executables
 742 if test "$with_dhclient" = "yes"; then
 743         AC_PATH_PROGS(with_dhclient, dhclient, no, /sbin:/usr/sbin:/usr/local/sbin)
 744         if test "$with_dhclient" != "no"; then
 745                 if ! $with_dhclient --version 2>&1 | grep -q "^isc-dhclient-4\."; then
 746                         AC_MSG_WARN([Cannot use dhclient, version 4.x is required])
 747                         with_dhclient=no
 748                 fi
 749         fi
 750 fi
 751 if test "$with_dhcpcd" = "yes"; then
 752         AC_PATH_PROGS(with_dhcpcd, dhcpcd, no, /sbin:/usr/sbin:/usr/local/sbin)
 753         if test "$with_dhcpcd" != "no"; then
 754                 if ! $with_dhcpcd --version 2>&1 | grep -q "^dhcpcd [[456789]]\."; then
 755                         AC_MSG_WARN([Cannot use dhcpcd, version 4.x or higher is required])
 756                         with_dhcpcd=no
 757                 elif $with_dhcpcd --version 2>&1 | grep -q "^dhcpcd [[6789]]\."; then
 758                         AC_DEFINE(DHCPCD_SUPPORTS_IPV6, 1, [Define if dhcpcd supports IPv6 (6.x+)])
 759                 fi
 760         fi
 761 fi
 762 # Fallback
 763 if test "$with_dhclient" = "no" -a "$with_dhcpcd" = "no"; then
 764         AC_MSG_WARN([Could not find a suitable DHCP client, falling back to dhclient])
 765         with_dhclient=/sbin/dhclient
 766 fi
 767 # Add substitutions
 768 if test "$with_dhclient" != "no"; then
 769         AC_DEFINE(WITH_DHCLIENT, TRUE, [Define if you have dhclient])
 770         AC_SUBST(DHCLIENT_PATH, $with_dhclient)
 771 else
 772         AC_DEFINE(WITH_DHCLIENT, FALSE, [Define if you have dhclient])
 773 fi
 774 if test "$with_dhcpcd" != "no"; then
 775         AC_DEFINE(WITH_DHCPCD, TRUE, [Define if you have dhcpcd])
 776         AC_SUBST(DHCPCD_PATH, $with_dhcpcd)
 777 else
 778         AC_DEFINE(WITH_DHCPCD, FALSE, [Define if you have dhcpcd])
 779 fi
 780
 781 # resolvconf and netconfig support
 782 AC_ARG_WITH(resolvconf, AS_HELP_STRING([--with-resolvconf=yes|no|path], [Enable resolvconf support]))
 783 AC_ARG_WITH(netconfig, AS_HELP_STRING([--with-netconfig=yes|no], [Enable SUSE netconfig support]))
 784 # Use netconfig by default on SUSE
 785 AS_IF([test -z "$with_netconfig"], AC_CHECK_FILE(/etc/SuSE-release, with_netconfig=yes))
 786 # Otherwise default to "no"
 787 AS_IF([test -z "$with_resolvconf"], with_resolvconf=no)
 788 AS_IF([test -z "$with_netconfig"], with_netconfig=no)
 789 # Find resolvconf and netconfig
 790 if test "$with_resolvconf" = "yes"; then
 791         AC_PATH_PROGS(with_resolvconf, resolvconf, no, /sbin:/usr/sbin:/usr/local/sbin)
 792 fi
 793 if test "$with_netconfig" = "yes"; then
 794         AC_PATH_PROGS(with_netconfig, netconfig, no, /sbin:/usr/sbin:/usr/local/sbin)
 795 fi
 796 # Define resolvconf and netconfig paths
 797 if test "$with_resolvconf" != "no"; then
 798         AC_DEFINE_UNQUOTED(RESOLVCONF_PATH, "$with_resolvconf", [Path to resolvconf])
 799 fi
 800 if test "$with_netconfig" != "no"; then
 801         AC_DEFINE_UNQUOTED(NETCONFIG_PATH, "$with_netconfig", [Path to netconfig])
 802 fi
 803
 804 # iptables path
 805 AC_ARG_WITH(iptables, AS_HELP_STRING([--with-iptables=/path/to/iptables], [path to iptables]))
 806 if test "x${with_iptables}" = x; then
 807   AC_PATH_PROG(IPTABLES_PATH, iptables, [], $PATH:/sbin:/usr/sbin)
 808   if ! test -x "$IPTABLES_PATH"; then
 809         AC_MSG_ERROR(iptables was not installed.)
 810   fi
 811 else
 812   IPTABLES_PATH="$with_iptables"
 813 fi
 814 AC_DEFINE_UNQUOTED(IPTABLES_PATH, "$IPTABLES_PATH", [Define to path of iptables binary])
 815 AC_SUBST(IPTABLES_PATH)
 816
 817 # dnsmasq path
 818 AC_ARG_WITH(dnsmasq, AS_HELP_STRING([--with-dnsmasq=/path/to/dnsmasq], [path to dnsmasq]))
 819 if test "x${with_dnsmasq}" = x; then
 820   AC_PATH_PROG(DNSMASQ_PATH, dnsmasq, [], $PATH:/sbin:/usr/sbin)
 821 else
 822   DNSMASQ_PATH="$with_dnsmasq"
 823 fi
 824 AC_DEFINE_UNQUOTED(DNSMASQ_PATH, "$DNSMASQ_PATH", [Define to path of dnsmasq binary])
 825 AC_SUBST(DNSMASQ_PATH)
 826
 827 # system CA certificates path
 828 AC_ARG_WITH(system-ca-path, AS_HELP_STRING([--with-system-ca-path=/path/to/ssl/certs], [path to system CA certificates]))
 829 if test "x${with_system_ca_path}" = x; then
 830   SYSTEM_CA_PATH=/etc/ssl/certs
 831 else
 832   SYSTEM_CA_PATH="$with_system_ca_path"
 833 fi
 834 AC_DEFINE_UNQUOTED(SYSTEM_CA_PATH, "$SYSTEM_CA_PATH", [Define to path to system CA certificates])
 835 AC_SUBST(SYSTEM_CA_PATH)
 836
 837 AC_ARG_WITH(kernel-firmware-dir, AS_HELP_STRING([--with-kernel-firmware-dir=DIR], [where kernel firmware directory is (default is /lib/firmware)]))
 838
 839 if test -n "$with_kernel_firmware_dir" ; then
 840     KERNEL_FIRMWARE_DIR="$with_kernel_firmware_dir"
 841 else
 842     KERNEL_FIRMWARE_DIR="/lib/firmware"
 843 fi
 844 AC_DEFINE_UNQUOTED(KERNEL_FIRMWARE_DIR, "$KERNEL_FIRMWARE_DIR", [Define to path of the kernel firmware directory])
 845 AC_SUBST(KERNEL_FIRMWARE_DIR)
 846
 847 PKG_CHECK_MODULES(LIBSOUP, [libsoup-2.4 >= 2.26], [have_libsoup=yes],[have_libsoup=no])
 848 AC_ARG_WITH(libsoup, AS_HELP_STRING([--with-libsoup=yes|no], [Link against libsoup]), [], [with_libsoup=${have_libsoup}])
 849 if test "$with_libsoup" != "no"; then
 850         if test "$have_libsoup" != "yes"; then
 851                 AC_MSG_ERROR(libsoup library not found)
 852         fi
 853         with_libsoup='yes'
 854         AC_DEFINE(WITH_LIBSOUP, 1, [Define if you have libsoup])
 855 else
 856         AC_DEFINE(WITH_LIBSOUP, 0, [Define if you have libsoup])
 857 fi
 858 AM_CONDITIONAL(WITH_LIBSOUP, test "$with_libsoup" != "no")
 859
 860 AC_ARG_ENABLE(concheck, AS_HELP_STRING([--enable-concheck], [enable connectivity checking support]),
 861                      [enable_concheck=${enableval}], [enable_concheck=${with_libsoup}])
 862 if (test "${enable_concheck}" = "yes"); then
 863         if test x"$with_libsoup" = x"no"; then
 864                 AC_MSG_ERROR(Connectivity checking requires libsoup)
 865         fi
 866         AC_DEFINE(WITH_CONCHECK, 1, [Define if you want connectivity checking support])
 867 else
 868         AC_DEFINE(WITH_CONCHECK, 0, [Define if you want connectivity checking support])
 869 fi
 870 AM_CONDITIONAL(WITH_CONCHECK, test "${enable_concheck}" = "yes")
 871
 872 PKG_CHECK_MODULES(LIBNDP, [libndp])
 873
 874 AC_ARG_WITH(nmtui, AS_HELP_STRING([--with-nmtui=yes|no], [Build nmtui]))
 875 if test "$with_nmtui" != no; then
 876     PKG_CHECK_MODULES(NEWT, [libnewt >= 0.52.15], [build_nmtui=yes], [build_nmtui=no])
 877 else
 878     build_nmtui=no
 879 fi
 880 if test "$with_nmtui" = yes -a "$build_nmtui" = no; then
 881     AC_MSG_ERROR([You must have libnewt installed to build nmtui.])
 882 fi
 883 AM_CONDITIONAL(BUILD_NMTUI, test "$build_nmtui" = yes)
 884
 885
 886 NM_COMPILER_WARNINGS
 887
 888 AC_ARG_ENABLE(more-asserts,
 889               AS_HELP_STRING([--enable-more-asserts], [Enable more assertions for debugging (default: no)]))
 890 if test "${enable_more_asserts}" = "yes"; then
 891     AC_DEFINE(NM_MORE_ASSERTS, [1], [Define if more asserts are enabled])
 892 fi
 893
 894 AC_ARG_ENABLE(more-logging,
 895               AS_HELP_STRING([--enable-more-logging], [Enable more debug logging (default: no)]))
 896 if test "${enable_more_logging}" = "yes"; then
 897     AC_DEFINE(NM_MORE_LOGGING, [1], [Define if more debug logging is enabled])
 898 fi
 899
 900 AC_ARG_ENABLE(lto, AS_HELP_STRING([--enable-lto], [Enable Link Time Optimization for smaller size (default: no)]))
 901 if (test "${enable_lto}" = "yes"); then
 902     CFLAGS="-flto $CFLAGS"
 903 else
 904     enable_lto='no'
 905 fi
 906
 907
 908 dnl -------------------------
 909 dnl Vala bindings
 910 dnl -------------------------
 911
 912 VAPIGEN_CHECK(0.17.1.24)
 913
 914 # Tests, utilities and documentation
 915 AC_ARG_ENABLE(tests, AS_HELP_STRING([--enable-tests=root|yes|no], [Build NetworkManager tests (default: yes)]))
 916 AC_ARG_WITH(valgrind, AS_HELP_STRING([--with-valgrind=yes|no|path], [Use valgrind to memory-check the tests (default: no)]))
 917 # Fallback to --with-tests
 918 AC_ARG_WITH(tests, AS_HELP_STRING([--with-tests], [Build NetworkManager tests (deprecated)]))
 919 AS_IF([test -n "$with_tests"], enable_tests="$with_tests")
 920 # Default to --enable-tests --with-valgrind=no
 921 AS_IF([test -z "$enable_tests"], enable_tests="yes")
 922 AS_IF([test -z "$with_valgrind"], with_valgrind="no")
 923 # Normalize values
 924 AS_IF([test "$enable_tests" != "yes" -a "$enable_tests" != "root"], enable_tests="no")
 925 # Search for tools
 926 AS_IF([test "$with_valgrind" == "yes"],
 927         [AC_PATH_PROGS(with_valgrind, valgrind, no)])
 928 # Add conditionals and substitutions
 929 AM_CONDITIONAL(ENABLE_TESTS, test "$enable_tests" != "no")
 930 AM_CONDITIONAL(REQUIRE_ROOT_TESTS, test "$enable_tests" == "root")
 931 AC_ARG_WITH(valgrind-suppressions, AS_HELP_STRING([--with-valgrind-suppressions=path], [Use specific valgrind suppression file]))
 932 if test "$with_valgrind" == no; then
 933         with_valgrind_suppressions=
 934 else
 935         if test  "$with_valgrind_suppressions" == ""; then
 936                 with_valgrind_suppressions='$(top_srcdir)/valgrind.suppressions'
 937         fi
 938 fi
 939 AS_IF([test "$with_valgrind" != "no"],
 940         AC_SUBST(VALGRIND_RULES, 'LOG_COMPILER = "$(top_srcdir)/tools/run-test-valgrind.sh" "$(LIBTOOL)" "$(with_valgrind)" '"$with_valgrind_suppressions"),
 941         AC_SUBST(VALGRIND_RULES, []))
 942 AM_CONDITIONAL(WITH_VALGRIND, test "${with_valgrind}" != "no")
 943
 944 GTK_DOC_CHECK(1.0)
 945
 946 # check for pregenerated manpages to be installed
 947 install_pregen_manpages=no
 948 if test "$enable_gtk_doc" != "yes" \
 949         -a -f man/NetworkManager.conf.5 \
 950         -a -f man/nm-settings.5 \
 951         -a -f man/nm-settings-keyfile.5 \
 952         -a -f man/nm-settings-ifcfg-rh.5 \
 953         -a -f man/nmcli-examples.5 \
 954         -a -f man/NetworkManager.8; then
 955         install_pregen_manpages=yes
 956 fi
 957 AM_CONDITIONAL(INSTALL_PREGEN_MANPAGES, test "x${install_pregen_manpages}" = "xyes")
 958
 959 # check if we can build setting property documentation
 960 if test -n "$INTROSPECTION_MAKEFILE" -a "$enable_gtk_doc" = "yes"; then
 961     # If g-i is installed we know we have python, but we might not have pygobject
 962     if python -c 'from gi.repository import GObject' >& /dev/null; then
 963         have_pyobject=yes
 964     fi
 965
 966     # gtk-doc depends on perl, but we can check for it anyway
 967     AC_PATH_PROG(PERL, perl, no)
 968     # check for needed perl modules (use YAML; YAML::XS is better, but may not be so widespread)
 969     required_perl_modules="YAML"
 970     for module in $required_perl_modules; do
 971       AC_MSG_CHECKING([checking for perl module '$module'])
 972       if ${PERL} -e 'use '$module 2>/dev/null ; then
 973           AC_MSG_RESULT([Ok])
 974           have_perl_modules=yes
 975       else
 976           AC_MSG_RESULT([Failed])
 977           AC_MSG_ERROR([You must have Perl modules to build settings plugin docs: $required_perl_modules.])
 978       fi
 979     done
 980
 981     if test "$have_pyobject" = "yes" -a "$have_perl_modules" = "yes"; then
 982         AC_DEFINE(BUILD_SETTING_DOCS, [1], [Define if you we can build nm-setting-docs.xml, nm-keyfile-docs.xml and nm-ifcfg-rh-docs.xml])
 983         build_setting_docs=yes
 984     fi
 985 fi
 986
 987 # check for pre-built setting docs
 988 if test "$build_setting_docs" != "yes" \
 989         -a -f man/nm-settings.xml \
 990         -a -f man/nm-settings-keyfile.xml \
 991         -a -f man/nm-settings-ifcfg-rh.xml \
 992         -a -f docs/api/settings-spec.xml \
 993         -a -f clients/cli/settings-docs.c; then
 994     AC_DEFINE(HAVE_SETTING_DOCS, [1], [Define if you have pre-built settings docs])
 995     have_setting_docs=yes
 996 fi
 997
 998 AM_CONDITIONAL(BUILD_SETTING_DOCS, test "$build_setting_docs" = "yes")
 999 AM_CONDITIONAL(SETTING_DOCS_AVAILABLE, test "$build_setting_docs" = "yes" -o "$have_setting_docs" = "yes")
1000
1001
1002 AC_CONFIG_FILES([
1003 Makefile
1004 include/Makefile
1005 src/Makefile
1006 src/tests/Makefile
1007 src/tests/config/Makefile
1008 src/dhcp-manager/Makefile
1009 src/dhcp-manager/tests/Makefile
1010 src/dnsmasq-manager/tests/Makefile
1011 src/supplicant-manager/tests/Makefile
1012 src/ppp-manager/Makefile
1013 src/settings/plugins/Makefile
1014 src/settings/plugins/ifupdown/Makefile
1015 src/settings/plugins/ifupdown/tests/Makefile
1016 src/settings/plugins/ifnet/Makefile
1017 src/settings/plugins/ifnet/tests/Makefile
1018 src/settings/plugins/ifcfg-rh/Makefile
1019 src/settings/plugins/ifcfg-rh/tests/Makefile
1020 src/settings/plugins/ifcfg-rh/tests/network-scripts/Makefile
1021 src/settings/plugins/ibft/Makefile
1022 src/settings/plugins/ibft/tests/Makefile
1023 src/settings/plugins/keyfile/Makefile
1024 src/settings/plugins/keyfile/tests/Makefile
1025 src/settings/plugins/keyfile/tests/keyfiles/Makefile
1026 src/platform/Makefile
1027 src/platform/tests/Makefile
1028 src/rdisc/Makefile
1029 src/rdisc/tests/Makefile
1030 src/devices/adsl/Makefile
1031 src/devices/bluetooth/Makefile
1032 src/devices/team/Makefile
1033 src/devices/wifi/Makefile
1034 src/devices/wifi/tests/Makefile
1035 src/devices/wwan/Makefile
1036 libnm-core/nm-version.h
1037 libnm-core/Makefile
1038 libnm-core/tests/Makefile
1039 libnm/libnm.pc
1040 libnm/Makefile
1041 libnm/tests/Makefile
1042 libnm-util/libnm-util.pc
1043 libnm-util/nm-version.h
1044 libnm-util/Makefile
1045 libnm-util/tests/Makefile
1046 libnm-glib/libnm-glib.pc
1047 libnm-glib/libnm-glib-vpn.pc
1048 libnm-glib/Makefile
1049 libnm-glib/tests/Makefile
1050 callouts/Makefile
1051 callouts/tests/Makefile
1052 tools/Makefile
1053 clients/Makefile
1054 clients/cli/Makefile
1055 clients/tui/Makefile
1056 clients/tui/newt/Makefile
1057 initscript/RedHat/NetworkManager
1058 initscript/Debian/NetworkManager
1059 initscript/Slackware/rc.networkmanager
1060 initscript/SUSE/networkmanager
1061 initscript/Arch/networkmanager
1062 initscript/Mandriva/networkmanager
1063 initscript/linexa/networkmanager
1064 introspection/Makefile
1065 introspection/all.xml
1066 man/Makefile
1067 man/NetworkManager.conf.xml
1068 man/nm-system-settings.conf.5
1069 man/nm-online.1
1070 man/nmcli.1
1071 man/nmtui.1
1072 po/Makefile.in
1073 policy/Makefile
1074 policy/org.freedesktop.NetworkManager.policy.in
1075 data/Makefile
1076 docs/Makefile
1077 docs/api/Makefile
1078 docs/api/version.xml
1079 docs/libnm-glib/Makefile
1080 docs/libnm-glib/version.xml
1081 docs/libnm-util/Makefile
1082 docs/libnm-util/version.xml
1083 docs/libnm/Makefile
1084 docs/libnm/version.xml
1085 NetworkManager.pc
1086 examples/Makefile
1087 examples/shell/Makefile
1088 examples/python/Makefile
1089 examples/python/dbus/Makefile
1090 examples/python/gi/Makefile
1091 examples/ruby/Makefile
1092 examples/lua/Makefile
1093 examples/lua/lgi/Makefile
1094 examples/C/Makefile
1095 examples/C/glib/Makefile
1096 examples/C/qt/Makefile
1097 examples/dispatcher/Makefile
1098 vapi/Makefile
1099 ])
1100 AC_CONFIG_SUBDIRS([libndp])
1101 AC_OUTPUT
1102
1103 # Print build configuration
1104 echo
1105 echo "System paths:"
1106 echo "  prefix: $prefix"
1107 echo "  exec_prefix: $exec_prefix"
1108 echo "  systemdunitdir: $with_systemdsystemunitdir"
1109 echo "  nmbinary: $nmbinary"
1110 echo "  nmconfdir: $nmconfdir"
1111 echo "  nmlibdir: $nmlibdir"
1112 echo "  nmdatadir: $nmdatadir"
1113 echo "  nmstatedir: $nmstatedir"
1114 echo "  nmrundir: $nmrundir"
1115 echo
1116
1117 echo "Platform:"
1118 echo "  session tracking: $session_tracking"
1119 echo "  suspend/resume: $with_suspend_resume"
1120 if test "${enable_polkit}" = "yes"; then
1121         if test "${enable_modify_system}" = "yes"; then
1122                 echo "  policykit: yes (permissive modify.system) (default: main.auth-polkit=${enable_polkit})"
1123         else
1124                 echo "  policykit: yes (restrictive modify.system) (default: main.auth-polkit=${enable_polkit})"
1125         fi
1126 else
1127         echo  "  policykit: no"
1128 fi
1129 echo "  polkit agent: ${enable_polkit_agent}"
1130 echo "  selinux: $have_selinux"
1131 echo "  systemd-journald: $have_systemd_journal (default: logging.backend=${nm_config_logging_backend_default})"
1132 echo "  hostname persist: ${hostname_persist}"
1133 echo "  libaudit: $have_libaudit (default: logging.audit=${NM_CONFIG_DEFAULT_LOGGING_AUDIT_TEXT})"
1134 echo
1135
1136 echo "Features:"
1137 echo "  wext: $ac_with_wext"
1138 echo "  wifi: $enable_wifi"
1139 echo "  ppp: $enable_ppp"
1140 echo "  modemmanager-1: $with_modem_manager_1"
1141 echo "  concheck: $enable_concheck"
1142 echo "  libteamdctl: $enable_teamdctl"
1143 echo "  nmtui: $build_nmtui"
1144 echo
1145
1146 echo "Configuration plugins (main.plugins=${config_plugins_default})"
1147 echo "  ibft: ${enable_config_plugin_ibft}"
1148 echo "  ifcfg-rh: ${enable_ifcfg_rh}"
1149 echo "  ifupdown: ${enable_ifupdown}"
1150 echo "  ifnet: ${enable_ifnet}"
1151 echo
1152
1153 echo "Handlers for /etc/resolv.conf:"
1154 echo "  resolvconf: ${with_resolvconf}"
1155 echo "  netconfig: ${with_netconfig}"
1156 echo
1157
1158 echo "DHCP clients:"
1159 echo "  dhclient: $with_dhclient"
1160 echo "  dhcpcd: $with_dhcpcd"
1161 echo
1162
1163 echo "Miscellaneous:"
1164 echo "  documentation: $enable_gtk_doc"
1165 echo "  tests: $enable_tests"
1166 echo "  valgrind: $with_valgrind   $with_valgrind_suppressions"
1167 echo "  code coverage: $enable_code_coverage"
1168 echo "  LTO: $enable_lto"
1169 echo