libnm/tests: extend tests for handling invalid connections in NMClient
[NetworkManager.git] / configure.ac
1 AC_PREREQ([2.63])
2
3 dnl The NM version number
4 m4_define([nm_major_version], [1])
5 m4_define([nm_minor_version], [1])
6 m4_define([nm_micro_version], [91])
7 m4_define([nm_version],
8           [nm_major_version.nm_minor_version.nm_micro_version])
9 m4_define([nm_git_sha], [m4_esyscmd([ ( [ -d ./.git/ ] && [ "$(readlink -f ./.git/)" = "$(readlink -f "$(git rev-parse --git-dir 2>/dev/null)" 2>/dev/null)" ] && git rev-parse --verify -q HEAD 2>/dev/null ) || true ])])
10
11 AC_INIT([NetworkManager], [nm_version],
12         [http://bugzilla.gnome.org/enter_bug.cgi?product=NetworkManager],
13         [NetworkManager])
14
15 AC_CONFIG_HEADERS([config.h])
16 AC_CONFIG_MACRO_DIR([m4])
17 AC_CONFIG_AUX_DIR([build-aux])
18 AC_REQUIRE_AUX_FILE([tap-driver.sh])
19
20 AM_INIT_AUTOMAKE(1.12 tar-ustar no-dist-gzip dist-xz -Wno-portability)  dnl NB: Do not [quote] this parameter.
21 AM_MAINTAINER_MODE([enable])
22 AM_SILENT_RULES([yes])
23
24 dnl Define _SYSTEM_EXTENSIONS for various things like strcasestr()
25 AC_USE_SYSTEM_EXTENSIONS
26
27 dnl
28 dnl Require programs
29 dnl
30 AC_PROG_CC
31 AM_PROG_CC_C_O
32
33 # C++ only required if --enable-qt=yes
34 AC_PROG_CXX
35
36 AC_PROG_LN_S
37
38 dnl Initialize libtool
39 LT_PREREQ([2.2])
40 LT_INIT([disable-static])
41
42 dnl Version stuff
43 NM_MAJOR_VERSION=nm_major_version
44 NM_MINOR_VERSION=nm_minor_version
45 NM_MICRO_VERSION=nm_micro_version
46 NM_VERSION=nm_version
47 NM_GIT_SHA=nm_git_sha
48 AC_SUBST(NM_MAJOR_VERSION)
49 AC_SUBST(NM_MINOR_VERSION)
50 AC_SUBST(NM_MICRO_VERSION)
51 AC_SUBST(NM_VERSION)
52 AC_DEFINE_UNQUOTED(NM_GIT_SHA,"$NM_GIT_SHA",[git commit id of the original source code version])
53
54 dnl
55 dnl Checks for typedefs, structures, and compiler characteristics.
56 dnl
57 AC_TYPE_PID_T
58 AC_CHECK_SIZEOF(dev_t)
59
60 dnl
61 dnl translation support
62 dnl
63 IT_PROG_INTLTOOL([0.40.0])
64
65 AM_GNU_GETTEXT([external])
66 AM_GNU_GETTEXT_VERSION([0.17])
67
68 GETTEXT_PACKAGE=NetworkManager
69 AC_SUBST(GETTEXT_PACKAGE)
70 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [Gettext package])
71
72 dnl
73 dnl Make sha1.c happy on big endian systems
74 dnl
75 AC_C_BIGENDIAN
76
77 # Add runstatedir if not specified manually in autoconf < 2.70
78 AS_IF([test -z "$runstatedir"], runstatedir="$localstatedir/run")
79 AC_SUBST(runstatedir)
80
81 # NetworkManager paths
82 AC_SUBST(nmbinary, '${sbindir}'/$PACKAGE, [NetworkManager binary executable])
83 AC_SUBST(nmconfdir, '${sysconfdir}'/$PACKAGE, [NetworkManager configuration directory])
84 AC_SUBST(nmlibdir, '${prefix}'/lib/$PACKAGE, [NetworkManager library directory])
85 AC_SUBST(nmdatadir, '${datadir}'/$PACKAGE, [NetworkManager shared data directory])
86 AC_SUBST(nmstatedir, '${localstatedir}'/lib/$PACKAGE, [NetworkManager persistent state directory])
87 AC_SUBST(nmrundir, '${runstatedir}'/$PACKAGE, [NetworkManager runtime state directory])
88
89 AC_GNU_SOURCE
90 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
91
92 # Alternative configuration plugins
93 AC_ARG_ENABLE(config-plugin-ibft, AS_HELP_STRING([--enable-config-plugin-ibft], [enable ibft configuration plugin]))
94 AC_ARG_ENABLE(ifcfg-rh, AS_HELP_STRING([--enable-ifcfg-rh], [enable ifcfg-rh configuration plugin (Fedora/RHEL)]))
95 AC_ARG_ENABLE(ifcfg-suse, AS_HELP_STRING([--enable-ifcfg-suse], [enable ifcfg-suse configuration plugin (SUSE) (deprecated)]))
96 AC_ARG_ENABLE(ifupdown, AS_HELP_STRING([--enable-ifupdown], [enable ifupdown configuration plugin (Debian/Ubuntu)]))
97 AC_ARG_ENABLE(ifnet, AS_HELP_STRING([--enable-ifnet], [enable ifnet configuration plugin (Gentoo)]))
98 # Default alternative plugins by distribution
99 AS_IF([test -z "$enable_ifcfg_rh"], AC_CHECK_FILE(/etc/redhat-release, enable_ifcfg_rh=yes))
100 AS_IF([test -z "$enable_ifcfg_rh"], AC_CHECK_FILE(/etc/fedora-release, enable_ifcfg_rh=yes))
101 AS_IF([test -z "$enable_ifcfg_rh"], AC_CHECK_FILE(/etc/mandriva-release, enable_ifcfg_rh=yes))
102 AS_IF([test -z "$enable_ifcfg_suse"], AC_CHECK_FILE(/etc/SuSE-release, enable_ifcfg_suse=yes))
103 AS_IF([test -z "$enable_ifupdown"], AC_CHECK_FILE(/etc/debian_version, enable_ifupdown=yes))
104 AS_IF([test -z "$enable_ifnet"], AC_CHECK_FILE(/etc/gentoo-release, enable_ifnet=yes))
105 # Otherwise plugins default to "no"
106 AS_IF([test -z "$enable_ifcfg_rh"], enable_ifcfg_rh=no)
107 AS_IF([test -z "$enable_ifcfg_suse"], enable_ifcfg_suse=no)
108 AS_IF([test -z "$enable_ifupdown"], enable_ifupdown=no)
109 AS_IF([test -z "$enable_ifnet"], enable_ifnet=no)
110 # Enable ibft by default
111 AS_IF([test -z "$enable_config_plugin_ibft"], enable_config_plugin_ibft="yes")
112 # Create automake conditionals
113 AM_CONDITIONAL(CONFIG_PLUGIN_IBFT, test "$enable_config_plugin_ibft" = "yes")
114 AM_CONDITIONAL(CONFIG_PLUGIN_IFCFG_RH, test "$enable_ifcfg_rh" = "yes")
115 AM_CONDITIONAL(CONFIG_PLUGIN_IFUPDOWN, test "$enable_ifupdown" = "yes")
116 AM_CONDITIONAL(CONFIG_PLUGIN_IFNET, test "$enable_ifnet" = "yes")
117
118 AC_ARG_WITH(config-plugins-default, AS_HELP_STRING([--with-config-plugins-default=PLUGINS], [Default configuration option for main.plugins setting, used as fallback if the configuration option is unset]), [config_plugins_default="$withval"], [config_plugins_default=""])
119 if test -z "$config_plugins_default" -o "$config_plugins_default" = no; then
120     config_plugins_default=''
121     test "$enable_ifcfg_rh" = "yes"           && config_plugins_default="$config_plugins_default,ifcfg-rh"
122     test "$enable_ifupdown" = "yes"           && config_plugins_default="$config_plugins_default,ifupdown"
123     test "$enable_ifnet" = "yes"              && config_plugins_default="$config_plugins_default,ifnet"
124     test "$enable_config_plugin_ibft" = "yes" && config_plugins_default="$config_plugins_default,ibft"
125     config_plugins_default="${config_plugins_default#,}"
126 fi
127
128 test "$enable_ifcfg_rh" = "yes"           && distro_plugins="$distro_plugins,ifcfg-rh"
129 test "$enable_ifcfg_suse" = "yes"         && distro_plugins="$distro_plugins,ifcfg-suse"
130 test "$enable_ifupdown" = "yes"           && distro_plugins="$distro_plugins,ifupdown"
131 test "$enable_ifnet" = "yes"              && distro_plugins="$distro_plugins,ifnet"
132 distro_plugins="${distro_plugins#,}"
133
134 AC_DEFINE_UNQUOTED(CONFIG_PLUGINS_DEFAULT, "$config_plugins_default", [Default configuration option for main.plugins setting])
135 if test "${enable_config_plugin_ibft}" = yes; then
136         AC_DEFINE(WITH_SETTINGS_PLUGIN_IBFT, 1, [Whether compilation of ibft setting plugin is enabled])
137 else
138         AC_DEFINE(WITH_SETTINGS_PLUGIN_IBFT, 0, [Whether compilation of ibft setting plugin is enabled])
139 fi
140
141 if test "$enable_ifcfg_rh" = "yes"; then
142     DISTRO_NETWORK_SERVICE=network.service
143 fi
144 AC_SUBST(DISTRO_NETWORK_SERVICE)
145
146 # Code coverage
147 GNOME_CODE_COVERAGE
148
149 dnl
150 dnl Distribution version string
151 dnl
152 AC_ARG_WITH(dist-version, AS_HELP_STRING([--with-dist-version=<NM-distribution-version>], [Define the NM''s distribution version string]), ac_distver=$withval, ac_distver="")
153 if ! test x"$ac_distver" = x""; then
154   AC_DEFINE_UNQUOTED(NM_DIST_VERSION, "$ac_distver", [Define the distribution version string])
155 fi
156
157 AC_ARG_ENABLE(wifi, AS_HELP_STRING([--enable-wifi], [enable Wi-Fi support]))
158 if test "${enable_wifi}" != "no"; then
159         enable_wifi='yes'
160         AC_DEFINE(WITH_WIFI, 1, [Define if you have Wi-Fi support])
161 else
162         AC_DEFINE(WITH_WIFI, 0, [Define if you have Wi-Fi support])
163 fi
164 AM_CONDITIONAL(WITH_WIFI, test "${enable_wifi}" = "yes")
165
166 dnl
167 dnl Default to using WEXT but allow it to be disabled
168 dnl
169 AC_ARG_WITH(wext, AS_HELP_STRING([--with-wext=yes], [Enable or disable Linux Wireless Extensions]), ac_with_wext=$withval, ac_with_wext="$enable_wifi")
170 if test "$ac_with_wext" != 'no'; then
171         ac_with_wext='yes'
172 fi
173 if test x"$ac_with_wext" = x"yes"; then
174         if test "$enable_wifi" != "yes"; then
175                 AC_MSG_ERROR(Enabling WEXT support and disabling Wi-Fi makes no sense)
176         fi
177         AC_MSG_CHECKING([Linux kernel WEXT headers])
178         AC_COMPILE_IFELSE(
179                 [AC_LANG_PROGRAM(
180                       [[#ifndef __user
181                         #define __user
182                         #endif
183                         #include <sys/types.h>
184                         #include <linux/types.h>
185                         #include <sys/socket.h>
186                         #include <linux/wireless.h>]],
187                       [[#ifndef IWEVGENIE
188                         #error "not found"
189                         #endif]])],
190                 [ac_have_iwevgenie=yes],
191                 [ac_have_iwevgenie=no])
192         AC_MSG_RESULT($ac_have_iwevgenie)
193         if test "$ac_have_iwevgenie" = no; then
194                AC_MSG_ERROR(Linux kernel development header linux/wireless.h not installed or not functional)
195         fi
196         AC_DEFINE(HAVE_WEXT, 1, [Define if you have Linux Wireless Extensions support])
197 else
198         AC_DEFINE(HAVE_WEXT, 0, [Define if you have Linux Wireless Extensions support])
199 fi
200 AM_CONDITIONAL(WITH_WEXT, test x"${ac_with_wext}" = x"yes")
201
202 AC_MSG_CHECKING([Linux kernel nl80211 headers])
203 AC_COMPILE_IFELSE(
204         [AC_LANG_PROGRAM(
205               [[#ifndef __user
206                 #define __user
207                 #endif
208                 #include <sys/types.h>
209                 #include <linux/types.h>
210                 #include <sys/socket.h>
211                 #include <linux/nl80211.h>]],
212               [[int a = NL80211_RATE_INFO_BITRATE; a++;]])],
213         [ac_have_nl80211=yes],
214         [ac_have_nl80211=no])
215 AC_MSG_RESULT($ac_have_nl80211)
216 if test "$ac_have_nl80211" = no; then
217         AC_MSG_ERROR(Linux kernel development header linux/nl80211.h not installed or not functional)
218 fi
219
220 if test "$with_wifi" = "yes"; then
221         AC_MSG_CHECKING([Linux kernel nl80211 Critical Protocol Start/Stop])
222         AC_COMPILE_IFELSE(
223                 [AC_LANG_PROGRAM(
224                   [[#ifndef __user
225                     #define __user
226                     #endif
227                     #include <sys/types.h>
228                     #include <linux/types.h>
229                     #include <sys/socket.h>
230                     #include <linux/nl80211.h>]],
231                   [[unsigned int a = NL80211_CMD_CRIT_PROTOCOL_START; a++;]])],
232                 [ac_have_nl80211_critproto=yes],
233                 [ac_have_nl80211_critproto=no])
234         AC_MSG_RESULT($ac_have_nl80211_critproto)
235 else
236         ac_have_nl80211_critproto='no'
237 fi
238 if test "$ac_have_nl80211_critproto" = yes; then
239         AC_DEFINE(HAVE_NL80211_CRITICAL_PROTOCOL_CMDS, 1, [Define if nl80211 has critical protocol support])
240 else
241         AC_DEFINE(HAVE_NL80211_CRITICAL_PROTOCOL_CMDS, 0, [Define if nl80211 has critical protocol support])
242 fi
243
244 dnl
245 dnl Check for newer VLAN flags
246 dnl
247 AC_MSG_CHECKING([Linux kernel VLAN_FLAG_LOOSE_BINDING enum value])
248 AC_COMPILE_IFELSE(
249         [AC_LANG_PROGRAM(
250               [[#ifndef __user
251                 #define __user
252                 #endif
253                 #include <sys/types.h>
254                 #include <linux/types.h>
255                 #include <linux/if_vlan.h>]],
256               [[unsigned int a = VLAN_FLAG_LOOSE_BINDING;]])],
257         [ac_have_vlan_flag_loose_binding=yes],
258         [ac_have_vlan_flag_loose_binding=no])
259 AC_MSG_RESULT($ac_have_vlan_flag_loose_binding)
260 if test "$ac_have_vlan_flag_loose_binding" = yes; then
261         AC_DEFINE(HAVE_VLAN_FLAG_LOOSE_BINDING, 1, [Define if you have VLAN_FLAG_LOOSE_BINDING])
262 else
263         AC_DEFINE(HAVE_VLAN_FLAG_LOOSE_BINDING, 0, [Define if you have VLAN_FLAG_LOOSE_BINDING])
264 fi
265
266 dnl
267 dnl Checks for libm - needed for pow()
268 dnl
269 LT_LIB_M
270
271 dnl
272 dnl Checks for libdl - on certain platforms its part of libc
273 dnl
274 AC_CHECK_LIB([dl], [dladdr], LIBDL="-ldl", LIBDL="")
275 AC_SUBST(LIBDL)
276
277 PKG_CHECK_MODULES(GLIB, [gio-unix-2.0 >= 2.37.6 gmodule-2.0],
278         [AC_SUBST(LOG_DRIVER, '$(top_srcdir)/build-aux/tap-driver.sh')
279          AC_SUBST(AM_TESTS_FD_REDIRECT, '--tap')],
280         [PKG_CHECK_MODULES(GLIB, gio-unix-2.0 >= 2.32 gmodule-2.0)
281          AC_SUBST(LOG_DRIVER, '$(top_srcdir)/build-aux/test-driver')])
282
283 dnl GLIB_VERSION_MIN_REQUIRED should match the version above.
284 dnl GLIB_VERSION_MAX_ALLOWED should be set to the same version;
285 dnl nm-glib.h will cause it to be overridden for the functions
286 dnl we have compat versions of.
287 GLIB_CFLAGS="$GLIB_CFLAGS -DGLIB_VERSION_MIN_REQUIRED=GLIB_VERSION_2_32 -DGLIB_VERSION_MAX_ALLOWED=GLIB_VERSION_2_32"
288
289 AC_SUBST(GLIB_CFLAGS)
290 AC_SUBST(GLIB_LIBS)
291
292 AC_ARG_WITH(libnm-glib, AS_HELP_STRING([--without-libnm-glib], [don't build legacy libraries]))
293 if test "$with_libnm_glib" != "no"; then
294     PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.1 dbus-glib-1 >= 0.94, :,
295                             [AC_MSG_FAILURE([$DBUS_PKG_ERRORS
296
297 Configure with --without-libnm-glib if you do not need the legacy libraries])])
298     with_libnm_glib=yes
299 fi
300 AM_CONDITIONAL(WITH_LEGACY_LIBRARIES, test "$with_libnm_glib" != "no")
301
302 PKG_CHECK_MODULES(GUDEV, gudev-1.0 >= 165)
303
304 GOBJECT_INTROSPECTION_CHECK([0.9.6])
305
306 # Qt4
307 PKG_CHECK_MODULES(QT, [QtCore >= 4 QtDBus QtNetwork], [have_qt=yes],[have_qt=no])
308 AC_ARG_ENABLE(qt, AS_HELP_STRING([--enable-qt], [enable Qt examples]),
309                      [enable_qt=${enableval}], [enable_qt=${have_qt}])
310 if (test "${enable_qt}" = "yes"); then
311         if test x"$have_qt" = x"no"; then
312                 AC_MSG_ERROR(Qt development headers are required)
313         fi
314         # Check for moc-qt4 and if not found then moc
315         QT4_BINDIR=`$PKG_CONFIG QtCore --variable moc_location`
316         AC_CHECK_PROGS(MOC, [moc-qt4 moc],, [$QT4_BINDIR:$PATH])
317 fi
318 AM_CONDITIONAL(WITH_QT, test "${enable_qt}" = "yes")
319
320 AC_ARG_WITH(udev-dir, AS_HELP_STRING([--with-udev-dir=DIR], [Absolute path of the udev base directory. Set to 'no' not to install the udev rules]), [], [with_udev_dir="yes"])
321 if (test "$with_udev_dir" != 'no'); then
322         if (test "$with_udev_dir" != 'yes' && printf '%s' "$with_udev_dir" | grep -v -q '^/'); then
323                 AC_MSG_ERROR([--with-udev-dir must be an absolute path or 'yes' or 'no'. Instead it is '$with_udev_dir'])
324         fi
325         if (test "$with_udev_dir" = 'yes'); then
326                 with_udev_dir="\$(prefix)/lib/udev"
327         fi
328         UDEV_DIR="$with_udev_dir"
329         AC_SUBST(UDEV_DIR)
330 fi
331 AM_CONDITIONAL(WITH_UDEV_DIR, test "$with_udev_dir" != 'no')
332
333 # systemd unit support
334 AC_ARG_WITH([systemdsystemunitdir], AS_HELP_STRING([--with-systemdsystemunitdir=DIR],
335         [Directory for systemd service files]))
336 # default location
337 AS_IF([test -z "$with_systemdsystemunitdir" && $PKG_CONFIG systemd],
338         with_systemdsystemunitdir="\$(prefix)/lib/systemd/system")
339 AS_IF([test -z "$with_systemdsystemunitdir"], with_systemdsystemunitdir=no)
340 # add conditional and subst
341 AM_CONDITIONAL(HAVE_SYSTEMD, [test "$with_systemdsystemunitdir" != no])
342 if test "$with_systemdsystemunitdir" != no; then
343         AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
344         AC_DEFINE(HAVE_SYSTEMD, 1, [Define if systemd support is available])
345 else
346         AC_DEFINE(HAVE_SYSTEMD, 0, [Define if systemd support is available])
347 fi
348
349 PKG_CHECK_MODULES(SYSTEMD_200, [systemd >= 200], [have_systemd_200=yes],[have_systemd_200=no])
350 AM_CONDITIONAL(HAVE_SYSTEMD_200, test "${have_systemd_200}" = "yes")
351
352 # Hostname persist mode
353 AC_ARG_WITH(hostname-persist, AS_HELP_STRING([--with-hostname-persist=default|suse|gentoo],
354         [Hostname persist method]))
355
356 AS_IF([test "$with_hostname_persist" = "suse"], hostname_persist=suse)
357 AS_IF([test "$with_hostname_persist" = "gentoo"], hostname_persist=gentoo)
358 AS_IF([test "$with_hostname_persist" = "default"], hostname_persist=default)
359 # if the method was not explicitly set, try to guess it from the enabled plugins
360 AS_IF([test -z "$hostname_persist" -a "$distro_plugins" = "ifcfg-suse"], hostname_persist=suse)
361 AS_IF([test -z "$hostname_persist" -a "$distro_plugins" = "ifnet"], hostname_persist=gentoo)
362 AS_IF([test -z "$hostname_persist"], hostname_persist=default)
363
364 if test "$hostname_persist" = suse; then
365         AC_DEFINE(HOSTNAME_PERSIST_SUSE, 1, [Enable SuSE hostname persist method])
366 elif test "$hostname_persist" = gentoo; then
367         AC_DEFINE(HOSTNAME_PERSIST_GENTOO, 1, [Enable Gentoo hostname persist method])
368 fi
369
370 AC_ARG_WITH(systemd-journal, AS_HELP_STRING([--with-systemd-journal=yes|no], [Use systemd journal for logging]))
371 have_systemd_journal=no
372 if test "$with_systemd_journal" != "no"; then
373         PKG_CHECK_MODULES(SYSTEMD_JOURNAL,
374                           [libsystemd >= 209],
375                           [have_systemd_journal=yes],
376                           [PKG_CHECK_MODULES(SYSTEMD_JOURNAL,
377                                              [libsystemd-journal],
378                                              [have_systemd_journal=yes],
379                                              [have_systemd_journal=no])])
380         if test "$have_systemd_journal" != "yes"; then
381                 if test "$with_systemd_journal" = "yes"; then
382                         AC_MSG_ERROR([Missing systemd-journald support])
383                 fi
384         fi
385 fi
386 if test "$have_systemd_journal" = "yes"; then
387         AC_DEFINE([SYSTEMD_JOURNAL], 1, [Define to 1 if libsystemd-journald is available])
388 else
389         AC_DEFINE([SYSTEMD_JOURNAL], 0, [Define to 1 if libsystemd-journald is available])
390 fi
391
392 AC_ARG_WITH(config-logging-backend-default, AS_HELP_STRING([--with-logging-backend-default=backend], [Default value for logging.backend]), nm_config_logging_backend_default="$withval", nm_config_logging_backend_default="")
393 if test "$nm_config_logging_backend_default" != 'debug' \
394      -a "$nm_config_logging_backend_default" != 'syslog' \
395      -a "$nm_config_logging_backend_default" != 'journal' \
396      -a "$nm_config_logging_backend_default" != 'journal-syslog-style'; then
397         # unknown backend. Reset to default. Silently accept the invalid value to
398         # be future proof.
399         nm_config_logging_backend_default=''
400 fi
401 if test "$nm_config_logging_backend_default" = ""; then
402         if test "$have_systemd_journal" = "yes"; then
403                 nm_config_logging_backend_default='journal'
404         else
405                 nm_config_logging_backend_default='syslog'
406         fi
407 fi
408 AC_DEFINE_UNQUOTED(NM_CONFIG_LOGGING_BACKEND_DEFAULT, "$nm_config_logging_backend_default", [Default configuration option for logging.backend])
409 NM_CONFIG_LOGGING_BACKEND_DEFAULT_TEXT="$nm_config_logging_backend_default"
410 AC_SUBST(NM_CONFIG_LOGGING_BACKEND_DEFAULT_TEXT)
411
412 # Session tracking support
413 AC_ARG_WITH(systemd-logind, AS_HELP_STRING([--with-systemd-logind=yes|no],
414         [Support systemd session tracking]))
415 AC_ARG_WITH(consolekit, AS_HELP_STRING([--with-consolekit=yes|no],
416         [Support consolekit session tracking]))
417 AC_ARG_WITH(session-tracking, AS_HELP_STRING([--with-session-tracking=systemd|consolekit|no],
418         [Compatibility option to choose one session tracking module]))
419 # backwards compatibility
420 AS_IF([test "$with_session_tracking" = "ck"], [use_consolekit="yes" use_systemd_logind="no"])
421 AS_IF([test "$with_session_tracking" = "consolekit"], [use_consolekit="yes" use_systemd_logind="no"])
422 AS_IF([test "$with_session_tracking" = "systemd"], [use_consolekit="no" use_systemd_logind="yes"])
423 AS_IF([test "$with_session_tracking" = "no"], [use_consolekit="no" use_systemd_logind="no"])
424 AS_IF([test "$with_session_tracking" = "none"], [use_consolekit="no" use_systemd_logind="no"])
425 # current options
426 AS_IF([test -n "$with_systemd_logind" ], [use_systemd_logind="$with_systemd_logind"])
427 AS_IF([test -n "$with_consolekit" ], [use_consolekit="$with_consolekit"])
428 # defaults
429 AS_IF([test -z "$use_systemd_logind"], [use_systemd_logind="auto"])
430 AS_IF([test -z "$use_consolekit"], [use_consolekit="yes"])
431 # output
432 session_tracking=
433 if test "$use_systemd_logind" = "yes" -o "$use_systemd_logind" = "auto"; then
434     PKG_CHECK_MODULES(SYSTEMD_LOGIN, [libsystemd], [have_systemd_logind=yes], [PKG_CHECK_MODULES(SYSTEMD_LOGIN, [libsystemd-login], [have_systemd_logind=yes], [have_systemd_logind=no])])
435 else
436     have_systemd_logind=no
437 fi
438 if test "$use_systemd_logind" = "yes" -a "$have_systemd_logind" = "no"; then
439     AC_MSG_ERROR([You must have libsystemd installed to build with systemd-logind support.])
440 fi
441 if test "$have_systemd_logind" = "yes"; then
442         AC_DEFINE([SESSION_TRACKING_SYSTEMD], 1, [Define to 1 if libsystemd-login is available])
443         session_tracking="$session_tracking, systemd-logind"
444 fi
445 if test "$use_consolekit" = "yes"; then
446         AC_DEFINE([SESSION_TRACKING_CONSOLEKIT], 1, [Define to 1 if ConsoleKit is available])
447         AC_DEFINE([CKDB_PATH], "/var/run/ConsoleKit/database", [Path to ConsoleKit database])
448         session_tracking="$session_tracking, consolekit"
449 fi
450 session_tracking="$(printf '%s' "${session_tracking}" | sed 's/^, //')"
451
452 AC_ARG_WITH(suspend-resume, AS_HELP_STRING([--with-suspend-resume=upower|systemd|consolekit], [Build NetworkManager with specific suspend/resume support]))
453 if test "z$with_suspend_resume" = "z"; then
454     PKG_CHECK_EXISTS([libsystemd >= 209], [have_systemd_inhibit=yes],
455                      [PKG_CHECK_EXISTS([libsystemd-login >= 183], [have_systemd_inhibit=yes], [have_systemd_inhibit=no])])
456     if test "z${have_systemd_inhibit}" = "zyes"; then
457         # Use systemd if it's new enough
458         with_suspend_resume="systemd"
459     else
460         if test "$use_consolekit" = "yes"; then
461                 # Use consolekit suspend if session tracking is consolekit
462                 with_suspend_resume="consolekit"
463         else
464                 # Fall back to upower
465                 with_suspend_resume="upower"
466         fi
467     fi
468 fi
469
470 case $with_suspend_resume in
471     upower) ;;
472     systemd)
473         PKG_CHECK_MODULES(SYSTEMD_INHIBIT, [libsystemd >= 209],,
474                           [PKG_CHECK_MODULES(SYSTEMD_INHIBIT, [libsystemd-login >= 183])])
475         AC_DEFINE([SUSPEND_RESUME_SYSTEMD], 1, [Define to 1 to use systemd suspend api])
476         ;;
477     consolekit)
478         AC_DEFINE([SUSPEND_RESUME_CONSOLEKIT], 1, [Define to 1 to use ConsoleKit2 suspend api])
479         ;;
480     *)
481         AC_MSG_ERROR(--with-suspend-resume must be one of [upower, systemd, consolekit])
482         ;;
483 esac
484 AM_CONDITIONAL(SUSPEND_RESUME_UPOWER, test "x$with_suspend_resume" = "xupower")
485 AM_CONDITIONAL(SUSPEND_RESUME_SYSTEMD, test "x$with_suspend_resume" = "xsystemd")
486 AM_CONDITIONAL(SUSPEND_RESUME_CONSOLEKIT, test "x$with_suspend_resume" = "xconsolekit")
487
488 # SELinux support
489 AC_ARG_WITH(selinux, AS_HELP_STRING([--with-selinux=yes|no|auto], [Build with SELinux (default: auto)]),,[with_selinux=auto])
490 if test "$with_selinux" = "yes" -o "$with_selinux" = "auto"; then
491     PKG_CHECK_MODULES(SELINUX, libselinux, [have_selinux=yes], [have_selinux=no])
492 else
493     have_selinux=no
494 fi
495 if test "$with_selinux" = "yes" -a "$have_selinux" = "no"; then
496     AC_MSG_ERROR([You must have libselinux installed to build --with-selinux=yes.])
497 fi
498 if test "$have_selinux" = "yes"; then
499     AC_DEFINE(HAVE_SELINUX, 1, [Define if you have SELinux support])
500 else
501     AC_DEFINE(HAVE_SELINUX, 0, [Define if you have SELinux support])
502 fi
503
504 # libaudit support
505 AC_ARG_WITH(libaudit, AS_HELP_STRING([--with-libaudit=yes|yes-disabled-by-default|no|auto], [Build with audit daemon support (default: auto). yes-disabled-by-default enables support, but disables it unless explicitly configured via NetworkManager.conf]),,[with_libaudit=auto])
506 if test "$with_libaudit" = "yes" -o "$with_libaudit" = "yes-disabled-by-default" -o "$with_libaudit" = "auto"; then
507     PKG_CHECK_MODULES(LIBAUDIT, audit, [have_libaudit=yes], [have_libaudit=no])
508     if test "$with_libaudit" != "auto" -a "$have_libaudit" = "no"; then
509         AC_MSG_ERROR([You must have libaudit installed to build --with-libaudit=$with_libaudit.])
510     fi
511 else
512     have_libaudit=no
513 fi
514 if test "$have_libaudit" = "yes"; then
515     AC_DEFINE(HAVE_LIBAUDIT, 1, [Define if you have libaudit support])
516         if test "$with_libaudit" = "yes-disabled-by-default"; then
517                 AC_DEFINE(NM_CONFIG_DEFAULT_LOGGING_AUDIT, FALSE, [The default value of the logging.audit configuration option])
518                 NM_CONFIG_DEFAULT_LOGGING_AUDIT_TEXT='false'
519         else
520                 AC_DEFINE(NM_CONFIG_DEFAULT_LOGGING_AUDIT, TRUE,  [The default value of the logging.audit configuration option])
521                 NM_CONFIG_DEFAULT_LOGGING_AUDIT_TEXT='true'
522         fi
523 else
524     AC_DEFINE(HAVE_LIBAUDIT, 0, [Define if you have libaudit support])
525         AC_DEFINE(NM_CONFIG_DEFAULT_LOGGING_AUDIT, FALSE, [The default value of the logging.audit configuration option])
526     NM_CONFIG_DEFAULT_LOGGING_AUDIT_TEXT='false'
527 fi
528 AC_SUBST(NM_CONFIG_DEFAULT_LOGGING_AUDIT_TEXT)
529
530 # libnl support for the linux platform
531 PKG_CHECK_MODULES(LIBNL, libnl-3.0 >= 3.2.8)
532
533 # uuid library
534 PKG_CHECK_MODULES(UUID, uuid)
535
536 # Teamd control checks
537 PKG_CHECK_MODULES(LIBTEAMDCTL, [libteamdctl >= 1.9], [have_teamdctl=yes],[have_teamdctl=no])
538 AC_ARG_ENABLE(teamdctl, AS_HELP_STRING([--enable-teamdctl], [enable Teamd control support]),
539                      [enable_teamdctl=${enableval}], [enable_teamdctl=${have_teamdctl}])
540 if (test "${enable_teamdctl}" = "yes"); then
541         if test x"$have_teamdctl" = x"no"; then
542                 AC_MSG_ERROR(Teamd control is required)
543         fi
544         # temporary bug workaround
545         LIBTEAMDCTL_CFLAGS=`echo $LIBTEAMDCTL_CFLAGS | sed -e 's:/teamdctl.h::'`
546         AC_DEFINE(WITH_TEAMDCTL, 1, [Define if you have Teamd control support])
547 else
548         AC_DEFINE(WITH_TEAMDCTL, 0, [Define if you have Teamd control support])
549 fi
550 AM_CONDITIONAL(WITH_TEAMDCTL, test "${enable_teamdctl}" = "yes")
551
552 # we usually compile with polkit support. --enable-polkit=yes|no only sets the
553 # default configuration for main.auth-polkit. User can always enable/disable polkit
554 # autorization via config. Only when specifying --enable-polkit=disabled, we do
555 # not compile support. In this case, the user cannot enable polkit authorization via
556 # configuration.
557 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--enable-polkit=yes|no|disabled], [set default value for auth-polkit configuration option. This value can be overwritten by NM configuration. 'disabled' compiles NM without any support]),
558                      [enable_polkit=${enableval}], [enable_polkit=yes])
559 if (test "${enable_polkit}" != "no" -a "${enable_polkit}" != "disabled"); then
560         enable_polkit=yes
561         AC_DEFINE(NM_CONFIG_DEFAULT_AUTH_POLKIT, TRUE, [The default value of the auth-polkit configuration option])
562         NM_CONFIG_DEFAULT_AUTH_POLKIT_TEXT='true'
563 else
564         AC_DEFINE(NM_CONFIG_DEFAULT_AUTH_POLKIT, FALSE, [The default value of the auth-polkit configuration option])
565         NM_CONFIG_DEFAULT_AUTH_POLKIT_TEXT='false'
566 fi
567 if (test "${enable_polkit}" != "disabled"); then
568         AC_DEFINE(WITH_POLKIT, 1, [whether to compile polkit support])
569 else
570         AC_DEFINE(WITH_POLKIT, 0, [whether to compile polkit support])
571 fi
572 AC_SUBST(NM_CONFIG_DEFAULT_AUTH_POLKIT_TEXT)
573
574 PKG_CHECK_MODULES(POLKIT, [polkit-agent-1 >= 0.97], [have_pk_agent=yes],[have_pk_agent=no])
575 AC_ARG_ENABLE(polkit-agent, AS_HELP_STRING([--enable-polkit-agent], [enable polkit agent for clients]),
576                      [enable_polkit_agent=${enableval}], [enable_polkit_agent=${have_pk_agent}])
577 if (test "${enable_polkit_agent}" = "yes"); then
578         if test x"$have_pk_agent" = x"no"; then
579                 AC_MSG_ERROR(Polkit agent is required)
580         fi
581         AC_DEFINE(WITH_POLKIT_AGENT, 1, [Define if you have polkit agent])
582 else
583         AC_DEFINE(WITH_POLKIT_AGENT, 0, [Define if you have polkit agent])
584 fi
585 AM_CONDITIONAL(WITH_POLKIT_AGENT, test "${enable_polkit_agent}" = "yes")
586
587 AC_ARG_ENABLE(modify-system,
588               AS_HELP_STRING([--enable-modify-system], [Allow users to modify system connections]))
589 if test "${enable_modify_system}" = "yes"; then
590         NM_MODIFY_SYSTEM_POLICY="yes"
591 else
592         NM_MODIFY_SYSTEM_POLICY="auth_admin_keep"
593 fi
594 AC_SUBST(NM_MODIFY_SYSTEM_POLICY)
595
596 AC_ARG_WITH(crypto, AS_HELP_STRING([--with-crypto=nss|gnutls], [Cryptography library to use for certificate and key operations]),ac_crypto=$withval, ac_crypto=nss)
597
598 with_nss=no
599 with_gnutls=no
600 if test x"$ac_crypto" = xnss; then
601   PKG_CHECK_MODULES(NSS, [nss])
602
603   # Work around a pkg-config bug (fdo #29801) where exists != usable
604   FOO=`$PKG_CONFIG --cflags --libs nss`
605   if test x"$?" != "x0"; then
606     AC_MSG_ERROR([No usable NSS found])
607   fi
608
609   AC_DEFINE(HAVE_NSS, 1, [Define if you have NSS])
610   with_nss=yes
611 elif test x"$ac_crypto" = xgnutls; then
612   PKG_CHECK_MODULES(GNUTLS, [gnutls >= 2.12])
613   AC_DEFINE(HAVE_GNUTLS, 1, [Define if you have libgnutls])
614   with_gnutls=yes
615 else
616   AC_MSG_ERROR([Please choose either 'nss' or 'gnutls' for certificate and crypto operations])
617 fi
618 AM_CONDITIONAL(WITH_NSS, test x"$with_nss" != xno)
619 AM_CONDITIONAL(WITH_GNUTLS, test x"$with_gnutls" != xno)
620
621 # Shouldn't ever trigger this, but just in case...
622 if test x"$ac_nss" = xno -a x"$ac_gnutls" = xno; then
623   AC_MSG_ERROR([Could not find required development headers and libraries for '$ac_crypto'])
624 fi
625
626 GLIB_MAKEFILE='$(top_srcdir)/Makefile.glib'
627 AC_SUBST(GLIB_MAKEFILE)
628 GLIB_GENMARSHAL=`$PKG_CONFIG --variable=glib_genmarshal glib-2.0`
629 AC_SUBST(GLIB_GENMARSHAL)
630 GLIB_MKENUMS=`$PKG_CONFIG --variable=glib_mkenums glib-2.0`
631 AC_SUBST(GLIB_MKENUMS)
632
633 AC_ARG_WITH(dbus-sys-dir, AS_HELP_STRING([--with-dbus-sys-dir=DIR], [where D-BUS system.d directory is]))
634
635 if test -n "$with_dbus_sys_dir" ; then
636     DBUS_SYS_DIR="$with_dbus_sys_dir"
637 else
638     DBUS_SYS_DIR="${sysconfdir}/dbus-1/system.d"
639 fi
640 AC_SUBST(DBUS_SYS_DIR)
641
642 # pppd
643 AC_ARG_ENABLE(ppp, AS_HELP_STRING([--enable-ppp], [enable PPP/PPPoE support]),
644                      [enable_ppp=${enableval}], [enable_ppp=yes])
645 if (test "${enable_ppp}" = "yes"); then
646         AC_CHECK_HEADERS(pppd/pppd.h,,
647                 AC_MSG_ERROR("couldn't find pppd.h. pppd development headers are required."))
648
649         AC_DEFINE(WITH_PPP, 1, [Define if you have PPP support])
650 else
651         AC_DEFINE(WITH_PPP, 0, [Define if you have PPP support])
652 fi
653 AM_CONDITIONAL(WITH_PPP, test "${enable_ppp}" = "yes")
654
655 AC_ARG_WITH([pppd-plugin-dir], AS_HELP_STRING([--with-pppd-plugin-dir=DIR], [path to the pppd plugins directory]))
656
657 if test -n "$with_pppd_plugin_dir" ; then
658         PPPD_PLUGIN_DIR="$with_pppd_plugin_dir"
659 else
660         PPPD_PLUGIN_DIR="${libdir}/pppd/2.4.5"
661 fi
662 AC_SUBST(PPPD_PLUGIN_DIR)
663
664 AC_ARG_WITH(pppd, AS_HELP_STRING([--with-pppd=/path/to/pppd], [path to pppd binary]))
665 if test "x${with_pppd}" = x; then
666   AC_PATH_PROG(PPPD_PATH, pppd, [], $PATH:/sbin:/usr/sbin)
667 else
668   PPPD_PATH="$with_pppd"
669 fi
670 AC_DEFINE_UNQUOTED(PPPD_PATH, "$PPPD_PATH", [Define to path of pppd binary])
671 AC_SUBST(PPPD_PATH)
672
673 # ModemManager1 with libmm-glib
674 AC_ARG_WITH(modem-manager-1, AS_HELP_STRING([--with-modem-manager-1], [Enable new ModemManager1 interface support]),,[with_modem_manager_1=auto])
675 if (test "${with_modem_manager_1}" != "no"); then
676     PKG_CHECK_MODULES(MM_GLIB,
677                       [mm-glib >= 0.7.991],
678                       [have_libmm_glib=yes],
679                       [have_libmm_glib=no])
680
681     if (test "${have_libmm_glib}" = "no"); then
682         if (test "${with_modem_manager_1}" = "yes"); then
683             AC_MSG_ERROR([Couldn't find libmm-glib])
684         else
685             with_modem_manager_1="no"
686         fi
687     else
688         with_modem_manager_1="yes"
689     fi
690 fi
691
692 if (test "${with_modem_manager_1}" = "yes"); then
693     AC_DEFINE(WITH_MODEM_MANAGER_1, 1, [Define if you have ModemManager1 support])
694 else
695         AC_DEFINE(WITH_MODEM_MANAGER_1, 0, [Define if you have ModemManager1 support])
696 fi
697 AM_CONDITIONAL(WITH_MODEM_MANAGER_1, test "${with_modem_manager_1}" = "yes")
698
699 # Bluez5 DUN support
700 PKG_CHECK_MODULES(BLUEZ5, [bluez >= 5], [have_bluez5=yes],[have_bluez5=no])
701 AC_ARG_ENABLE(bluez5-dun, AS_HELP_STRING([--enable-bluez5-dun], [enable Bluez5 DUN support]),
702                 [enable_bluez5_dun=${enableval}], [enable_bluez5_dun=${have_bluez5}])
703 if (test "${enable_bluez5_dun}" = "yes"); then
704         if test x"$have_bluez5" = x"no"; then
705                 AC_MSG_ERROR(Bluez 5.x development headers are required)
706         fi
707         AC_DEFINE(WITH_BLUEZ5_DUN, 1, [Define if you have Bluez 5 libraries])
708 else
709         AC_DEFINE(WITH_BLUEZ5_DUN, 0, [Define if you have Bluez 5 libraries])
710 fi
711 AM_CONDITIONAL(WITH_BLUEZ5_DUN, test "${enable_bluez5_dun}" = "yes")
712
713 # DHCP client support
714 AC_ARG_WITH([dhclient], AS_HELP_STRING([--with-dhclient=yes|no|path], [Enable dhclient 4.x support]))
715 AC_ARG_WITH([dhcpcd], AS_HELP_STRING([--with-dhcpcd=yes|no|path], [Enable dhcpcd 4.x support]))
716 # Default to "yes"
717 AS_IF([test -z "$with_dhclient"], with_dhclient=yes)
718 AS_IF([test -z "$with_dhcpcd"], with_dhcpcd=yes)
719 # Search and check the executables
720 if test "$with_dhclient" = "yes"; then
721         AC_PATH_PROGS(with_dhclient, dhclient, no, /sbin:/usr/sbin:/usr/local/sbin)
722         if test "$with_dhclient" != "no"; then
723                 if ! $with_dhclient --version 2>&1 | grep -q "^isc-dhclient-4\."; then
724                         AC_MSG_WARN([Cannot use dhclient, version 4.x is required])
725                         with_dhclient=no
726                 fi
727         fi
728 fi
729 if test "$with_dhcpcd" = "yes"; then
730         AC_PATH_PROGS(with_dhcpcd, dhcpcd, no, /sbin:/usr/sbin:/usr/local/sbin)
731         if test "$with_dhcpcd" != "no"; then
732                 if ! $with_dhcpcd --version 2>&1 | grep -q "^dhcpcd [[456789]]\."; then
733                         AC_MSG_WARN([Cannot use dhcpcd, version 4.x or higher is required])
734                         with_dhcpcd=no
735                 elif $with_dhcpcd --version 2>&1 | grep -q "^dhcpcd [[6789]]\."; then
736                         AC_DEFINE(DHCPCD_SUPPORTS_IPV6, 1, [Define if dhcpcd supports IPv6 (6.x+)])
737                 fi
738         fi
739 fi
740 # Fallback
741 if test "$with_dhclient" = "no" -a "$with_dhcpcd" = "no"; then
742         AC_MSG_WARN([Could not find a suitable DHCP client, falling back to dhclient])
743         with_dhclient=/sbin/dhclient
744 fi
745 # Add substitutions
746 if test "$with_dhclient" != "no"; then
747         AC_DEFINE(WITH_DHCLIENT, TRUE, [Define if you have dhclient])
748         AC_SUBST(DHCLIENT_PATH, $with_dhclient)
749 else
750         AC_DEFINE(WITH_DHCLIENT, FALSE, [Define if you have dhclient])
751 fi
752 if test "$with_dhcpcd" != "no"; then
753         AC_DEFINE(WITH_DHCPCD, TRUE, [Define if you have dhcpcd])
754         AC_SUBST(DHCPCD_PATH, $with_dhcpcd)
755 else
756         AC_DEFINE(WITH_DHCPCD, FALSE, [Define if you have dhcpcd])
757 fi
758
759 # resolvconf and netconfig support
760 AC_ARG_WITH(resolvconf, AS_HELP_STRING([--with-resolvconf=yes|no|path], [Enable resolvconf support]))
761 AC_ARG_WITH(netconfig, AS_HELP_STRING([--with-netconfig=yes|no], [Enable SUSE netconfig support]))
762 # Use netconfig by default on SUSE
763 AS_IF([test -z "$with_netconfig"], AC_CHECK_FILE(/etc/SuSE-release, with_netconfig=yes))
764 # Otherwise default to "no"
765 AS_IF([test -z "$with_resolvconf"], with_resolvconf=no)
766 AS_IF([test -z "$with_netconfig"], with_netconfig=no)
767 # Find resolvconf and netconfig
768 if test "$with_resolvconf" = "yes"; then
769         AC_PATH_PROGS(with_resolvconf, resolvconf, no, /sbin:/usr/sbin:/usr/local/sbin)
770 fi
771 if test "$with_netconfig" = "yes"; then
772         AC_PATH_PROGS(with_netconfig, netconfig, no, /sbin:/usr/sbin:/usr/local/sbin)
773 fi
774 # Define resolvconf and netconfig paths
775 if test "$with_resolvconf" != "no"; then
776         AC_DEFINE_UNQUOTED(RESOLVCONF_PATH, "$with_resolvconf", [Path to resolvconf])
777 fi
778 if test "$with_netconfig" != "no"; then
779         AC_DEFINE_UNQUOTED(NETCONFIG_PATH, "$with_netconfig", [Path to netconfig])
780 fi
781
782 # iptables path
783 AC_ARG_WITH(iptables, AS_HELP_STRING([--with-iptables=/path/to/iptables], [path to iptables]))
784 if test "x${with_iptables}" = x; then
785   AC_PATH_PROG(IPTABLES_PATH, iptables, [], $PATH:/sbin:/usr/sbin)
786   if ! test -x "$IPTABLES_PATH"; then
787         AC_MSG_ERROR(iptables was not installed.)
788   fi
789 else
790   IPTABLES_PATH="$with_iptables"
791 fi
792 AC_DEFINE_UNQUOTED(IPTABLES_PATH, "$IPTABLES_PATH", [Define to path of iptables binary])
793 AC_SUBST(IPTABLES_PATH)
794
795 # dnsmasq path
796 AC_ARG_WITH(dnsmasq, AS_HELP_STRING([--with-dnsmasq=/path/to/dnsmasq], [path to dnsmasq]))
797 if test "x${with_dnsmasq}" = x; then
798   AC_PATH_PROG(DNSMASQ_PATH, dnsmasq, [], $PATH:/sbin:/usr/sbin)
799 else
800   DNSMASQ_PATH="$with_dnsmasq"
801 fi
802 AC_DEFINE_UNQUOTED(DNSMASQ_PATH, "$DNSMASQ_PATH", [Define to path of dnsmasq binary])
803 AC_SUBST(DNSMASQ_PATH)
804
805 # dnssec-trigger-script path
806 AC_ARG_WITH(dnssec_trigger, AS_HELP_STRING([--with-dnssec-trigger=/path/to/dnssec-trigger-script], [path to unbound dnssec-trigger-script]))
807 if test "x${with_dnssec_trigger}" = x; then
808   AC_PATH_PROG(DNSSEC_TRIGGER_SCRIPT, dnssec-trigger-script, /usr/libexec/dnssec-trigger-script, /usr/local/libexec:/usr/local/lib:/usr/local/lib/dnssec-trigger:/usr/libexec:/usr/lib:/usr/lib/dnssec-trigger)
809 else
810   DNSSEC_TRIGGER_SCRIPT="$with_dnssec_trigger"
811 fi
812 AC_DEFINE_UNQUOTED(DNSSEC_TRIGGER_SCRIPT, "$DNSSEC_TRIGGER_SCRIPT", [Define to path of unbound dnssec-trigger-script])
813 AC_SUBST(DNSSEC_TRIGGER_SCRIPT)
814
815 # system CA certificates path
816 AC_ARG_WITH(system-ca-path, AS_HELP_STRING([--with-system-ca-path=/path/to/ssl/certs], [path to system CA certificates])) 
817 if test "x${with_system_ca_path}" = x; then
818   SYSTEM_CA_PATH=/etc/ssl/certs
819 else
820   SYSTEM_CA_PATH="$with_system_ca_path"
821 fi
822 AC_DEFINE_UNQUOTED(SYSTEM_CA_PATH, "$SYSTEM_CA_PATH", [Define to path to system CA certificates])
823 AC_SUBST(SYSTEM_CA_PATH)
824
825 AC_ARG_WITH(kernel-firmware-dir, AS_HELP_STRING([--with-kernel-firmware-dir=DIR], [where kernel firmware directory is (default is /lib/firmware)]))
826
827 if test -n "$with_kernel_firmware_dir" ; then
828     KERNEL_FIRMWARE_DIR="$with_kernel_firmware_dir"
829 else
830     KERNEL_FIRMWARE_DIR="/lib/firmware"
831 fi
832 AC_DEFINE_UNQUOTED(KERNEL_FIRMWARE_DIR, "$KERNEL_FIRMWARE_DIR", [Define to path of the kernel firmware directory])
833 AC_SUBST(KERNEL_FIRMWARE_DIR)
834
835 PKG_CHECK_MODULES(LIBSOUP, [libsoup-2.4 >= 2.40], [have_libsoup=yes],[have_libsoup=no])
836 AC_ARG_WITH(libsoup, AS_HELP_STRING([--with-libsoup=yes|no], [Link against libsoup]), [], [with_libsoup=${have_libsoup}])
837 if test "$with_libsoup" != "no"; then
838         if test "$have_libsoup" != "yes"; then
839                 AC_MSG_ERROR(libsoup library not found)
840         fi
841         with_libsoup='yes'
842         AC_DEFINE(WITH_LIBSOUP, 1, [Define if you have libsoup])
843 else
844         AC_DEFINE(WITH_LIBSOUP, 0, [Define if you have libsoup])
845 fi
846 AM_CONDITIONAL(WITH_LIBSOUP, test "$with_libsoup" != "no")
847 LIBSOUP_CFLAGS="$LIBSOUP_CFLAGS -DSOUP_VERSION_MIN_REQUIRED=SOUP_VERSION_2_40 -DSOUP_VERSION_MAX_ALLOWED=SOUP_VERSION_2_40"
848
849 AC_ARG_ENABLE(concheck, AS_HELP_STRING([--enable-concheck], [enable connectivity checking support]),
850                      [enable_concheck=${enableval}], [enable_concheck=${with_libsoup}])
851 if (test "${enable_concheck}" = "yes"); then
852         if test x"$with_libsoup" = x"no"; then
853                 AC_MSG_ERROR(Connectivity checking requires libsoup)
854         fi
855         AC_DEFINE(WITH_CONCHECK, 1, [Define if you want connectivity checking support])
856 else
857         AC_DEFINE(WITH_CONCHECK, 0, [Define if you want connectivity checking support])
858 fi
859 AM_CONDITIONAL(WITH_CONCHECK, test "${enable_concheck}" = "yes")
860
861 PKG_CHECK_MODULES(LIBNDP, [libndp])
862
863 AC_ARG_WITH(nmcli, AS_HELP_STRING([--with-nmcli=yes|no], [Build nmcli]))
864 if test "$with_nmcli" != no; then
865     AX_LIB_READLINE
866     build_nmcli=yes
867 else
868     build_nmcli=no
869 fi
870 AM_CONDITIONAL(BUILD_NMCLI, test "$build_nmcli" = yes)
871
872 AC_ARG_WITH(nmtui, AS_HELP_STRING([--with-nmtui=yes|no], [Build nmtui]))
873 if test "$with_nmtui" != no; then
874     PKG_CHECK_MODULES(NEWT, [libnewt >= 0.52.15], [build_nmtui=yes], [build_nmtui=no])
875 else
876     build_nmtui=no
877 fi
878 if test "$with_nmtui" = yes -a "$build_nmtui" = no; then
879     AC_MSG_ERROR([You must have libnewt installed to build nmtui.])
880 fi
881 AM_CONDITIONAL(BUILD_NMTUI, test "$build_nmtui" = yes)
882
883
884 NM_COMPILER_WARNINGS
885
886 AC_ARG_ENABLE(more-asserts,
887               AS_HELP_STRING([--enable-more-asserts], [Enable more assertions for debugging (default: no). Deprecated option. Use --with-more-asserts=level]))
888 more_asserts=0
889 if test "${enable_more_asserts}" = "yes"; then
890     more_asserts=100
891 fi
892 AC_ARG_WITH(more-asserts,
893             AS_HELP_STRING([--with-more-asserts=level], [Enable more assertions for debugging (default: 0)]),
894             [more_asserts=${with_more_asserts}],
895             [])
896 if test "${more_asserts}" = "no"; then
897     more_asserts=0
898 else
899     if test "${more_asserts}" = "yes"; then
900         more_asserts=100
901     fi
902 fi
903 AC_DEFINE_UNQUOTED(NM_MORE_ASSERTS, $more_asserts, [Define if more asserts are enabled])
904
905 AC_ARG_ENABLE(more-logging,
906               AS_HELP_STRING([--enable-more-logging], [Enable more debug logging (default: no)]))
907 if test "${enable_more_logging}" = "yes"; then
908     AC_DEFINE(NM_MORE_LOGGING, [1], [Define if more debug logging is enabled])
909 fi
910
911 AC_ARG_ENABLE(lto, AS_HELP_STRING([--enable-lto], [Enable Link Time Optimization for smaller size (default: no)]))
912 if (test "${enable_lto}" = "yes"); then
913     CFLAGS="-flto $CFLAGS"
914 else
915     enable_lto='no'
916 fi
917
918
919 dnl -------------------------
920 dnl Vala bindings
921 dnl -------------------------
922
923 VAPIGEN_CHECK(0.17.1.24)
924
925 # Tests, utilities and documentation
926 AC_ARG_ENABLE(tests, AS_HELP_STRING([--enable-tests=root|yes|no], [Build NetworkManager tests (default: yes)]))
927 AC_ARG_WITH(valgrind, AS_HELP_STRING([--with-valgrind=yes|no|path], [Use valgrind to memory-check the tests (default: no)]))
928 # Fallback to --with-tests
929 AC_ARG_WITH(tests, AS_HELP_STRING([--with-tests], [Build NetworkManager tests (deprecated)]))
930 AS_IF([test -n "$with_tests"], enable_tests="$with_tests")
931 # Default to --enable-tests --with-valgrind=no
932 AS_IF([test -z "$enable_tests"], enable_tests="yes")
933 AS_IF([test -z "$with_valgrind"], with_valgrind="no")
934 # Normalize values
935 AS_IF([test "$enable_tests" != "yes" -a "$enable_tests" != "root"], enable_tests="no")
936 # Search for tools
937 AS_IF([test "$with_valgrind" == "yes"],
938         [AC_PATH_PROGS(with_valgrind, valgrind, no)])
939 # Add conditionals and substitutions
940 AM_CONDITIONAL(ENABLE_TESTS, test "$enable_tests" != "no")
941 AM_CONDITIONAL(REQUIRE_ROOT_TESTS, test "$enable_tests" == "root")
942 AC_ARG_WITH(valgrind-suppressions, AS_HELP_STRING([--with-valgrind-suppressions=path], [Use specific valgrind suppression file]))
943 if test "$with_valgrind" == no; then
944         with_valgrind_suppressions=
945 else
946         if test  "$with_valgrind_suppressions" == ""; then
947                 with_valgrind_suppressions='$(top_srcdir)/valgrind.suppressions'
948         fi
949 fi
950 AS_IF([test "$with_valgrind" != "no"],
951         AC_SUBST(VALGRIND_RULES, 'LOG_COMPILER = "$(top_srcdir)/tools/run-test-valgrind.sh" --called-from-make "$(LIBTOOL)" "$(with_valgrind)" '"$with_valgrind_suppressions"),
952         AC_SUBST(VALGRIND_RULES, []))
953 AM_CONDITIONAL(WITH_VALGRIND, test "${with_valgrind}" != "no")
954
955 GTK_DOC_CHECK(1.0)
956
957 # check for pregenerated manpages to be installed
958 install_pregen_manpages=no
959 if test "$enable_gtk_doc" != "yes" \
960         -a -f man/NetworkManager.conf.5 \
961         -a -f man/nm-settings.5 \
962         -a -f man/nm-settings-keyfile.5 \
963         -a -f man/nm-settings-ifcfg-rh.5 \
964         -a -f man/nmcli-examples.5 \
965         -a -f man/NetworkManager.8; then
966         install_pregen_manpages=yes
967 fi
968 AM_CONDITIONAL(INSTALL_PREGEN_MANPAGES, test "x${install_pregen_manpages}" = "xyes")
969
970 # check if we can build setting property documentation
971 if test -n "$INTROSPECTION_MAKEFILE" -a "$enable_gtk_doc" = "yes"; then
972     # If g-i is installed we know we have python, but we might not have pygobject
973     if python -c 'from gi.repository import GObject' >& /dev/null; then
974         have_pyobject=yes
975     fi
976
977     # gtk-doc depends on perl, but we can check for it anyway
978     AC_PATH_PROG(PERL, perl, no)
979     # check for needed perl modules (use YAML; YAML::XS is better, but may not be so widespread)
980     required_perl_modules="YAML"
981     for module in $required_perl_modules; do
982       AC_MSG_CHECKING([checking for perl module '$module'])
983       if ${PERL} -e 'use '$module 2>/dev/null ; then
984           AC_MSG_RESULT([Ok])
985           have_perl_modules=yes
986       else
987           AC_MSG_RESULT([Failed])
988           AC_MSG_ERROR([You must have Perl modules to build settings plugin docs: $required_perl_modules.])
989       fi
990     done
991
992     if test "$have_pyobject" = "yes" -a "$have_perl_modules" = "yes"; then
993         AC_DEFINE(BUILD_SETTING_DOCS, [1], [Define if you we can build nm-setting-docs.xml, nm-keyfile-docs.xml and nm-ifcfg-rh-docs.xml])
994         build_setting_docs=yes
995     fi
996 fi
997
998 # check for pre-built setting docs
999 if test "$build_setting_docs" != "yes" \
1000         -a -f man/nm-settings.xml \
1001         -a -f man/nm-settings-keyfile.xml \
1002         -a -f man/nm-settings-ifcfg-rh.xml \
1003         -a -f docs/api/settings-spec.xml \
1004         -a -f clients/cli/settings-docs.c; then
1005     AC_DEFINE(HAVE_SETTING_DOCS, [1], [Define if you have pre-built settings docs])
1006     have_setting_docs=yes
1007 fi
1008
1009 AM_CONDITIONAL(BUILD_SETTING_DOCS, test "$build_setting_docs" = "yes")
1010 AM_CONDITIONAL(SETTING_DOCS_AVAILABLE, test "$build_setting_docs" = "yes" -o "$have_setting_docs" = "yes")
1011
1012
1013 AC_CONFIG_FILES([
1014 Makefile
1015 shared/Makefile
1016 shared/nm-version-macros.h
1017 src/Makefile
1018 src/tests/Makefile
1019 src/tests/config/Makefile
1020 src/dhcp-manager/Makefile
1021 src/dhcp-manager/tests/Makefile
1022 src/dnsmasq-manager/tests/Makefile
1023 src/supplicant-manager/tests/Makefile
1024 src/supplicant-manager/tests/certs/Makefile
1025 src/ppp-manager/Makefile
1026 src/settings/plugins/Makefile
1027 src/settings/plugins/ifupdown/Makefile
1028 src/settings/plugins/ifupdown/tests/Makefile
1029 src/settings/plugins/ifnet/Makefile
1030 src/settings/plugins/ifnet/tests/Makefile
1031 src/settings/plugins/ifcfg-rh/Makefile
1032 src/settings/plugins/ifcfg-rh/tests/Makefile
1033 src/settings/plugins/ifcfg-rh/tests/network-scripts/Makefile
1034 src/settings/plugins/ibft/Makefile
1035 src/settings/plugins/ibft/tests/Makefile
1036 src/settings/plugins/keyfile/Makefile
1037 src/settings/plugins/keyfile/tests/Makefile
1038 src/settings/plugins/keyfile/tests/keyfiles/Makefile
1039 src/platform/Makefile
1040 src/platform/tests/Makefile
1041 src/rdisc/Makefile
1042 src/rdisc/tests/Makefile
1043 src/devices/Makefile
1044 src/devices/tests/Makefile
1045 src/devices/adsl/Makefile
1046 src/devices/bluetooth/Makefile
1047 src/devices/team/Makefile
1048 src/devices/wifi/Makefile
1049 src/devices/wifi/tests/Makefile
1050 src/devices/wwan/Makefile
1051 libnm-core/Makefile
1052 libnm-core/tests/Makefile
1053 libnm/libnm.pc
1054 libnm/Makefile
1055 libnm/tests/Makefile
1056 libnm-util/libnm-util.pc
1057 libnm-util/Makefile
1058 libnm-util/tests/Makefile
1059 libnm-glib/libnm-glib.pc
1060 libnm-glib/libnm-glib-vpn.pc
1061 libnm-glib/Makefile
1062 libnm-glib/tests/Makefile
1063 callouts/Makefile
1064 callouts/tests/Makefile
1065 tools/Makefile
1066 clients/Makefile
1067 clients/cli/Makefile
1068 clients/tui/Makefile
1069 clients/tui/newt/Makefile
1070 introspection/Makefile
1071 introspection/all.xml
1072 man/Makefile
1073 man/nm-system-settings.conf.5
1074 man/nm-online.1
1075 man/nmcli.1
1076 man/nmtui.1
1077 po/Makefile.in
1078 policy/Makefile
1079 policy/org.freedesktop.NetworkManager.policy.in
1080 data/Makefile
1081 docs/Makefile
1082 docs/api/Makefile
1083 docs/api/version.xml
1084 docs/libnm-glib/Makefile
1085 docs/libnm-glib/version.xml
1086 docs/libnm-util/Makefile
1087 docs/libnm-util/version.xml
1088 docs/libnm/Makefile
1089 docs/libnm/version.xml
1090 NetworkManager.pc
1091 examples/Makefile
1092 examples/shell/Makefile
1093 examples/python/Makefile
1094 examples/python/dbus/Makefile
1095 examples/python/gi/Makefile
1096 examples/python/python-networkmanager/Makefile
1097 examples/ruby/Makefile
1098 examples/lua/Makefile
1099 examples/lua/lgi/Makefile
1100 examples/C/Makefile
1101 examples/C/glib/Makefile
1102 examples/C/qt/Makefile
1103 examples/dispatcher/Makefile
1104 vapi/Makefile
1105 ])
1106 AC_CONFIG_SUBDIRS([libndp])
1107 AC_OUTPUT
1108
1109 # Print build configuration
1110 echo
1111 echo "System paths:"
1112 echo "  prefix: $prefix"
1113 echo "  exec_prefix: $exec_prefix"
1114 echo "  systemdunitdir: $with_systemdsystemunitdir"
1115 echo "  nmbinary: $nmbinary"
1116 echo "  nmconfdir: $nmconfdir"
1117 echo "  nmlibdir: $nmlibdir"
1118 echo "  nmdatadir: $nmdatadir"
1119 echo "  nmstatedir: $nmstatedir"
1120 echo "  nmrundir: $nmrundir"
1121 echo
1122
1123 echo "Platform:"
1124 echo "  session tracking: $session_tracking"
1125 echo "  suspend/resume: $with_suspend_resume"
1126 if test "${enable_polkit}" = "yes"; then
1127         if test "${enable_modify_system}" = "yes"; then
1128                 echo "  policykit: yes (permissive modify.system) (default: main.auth-polkit=${enable_polkit})"
1129         else
1130                 echo "  policykit: yes (restrictive modify.system) (default: main.auth-polkit=${enable_polkit})"
1131         fi
1132 else
1133         echo  "  policykit: no"
1134 fi
1135 echo "  polkit agent: ${enable_polkit_agent}"
1136 echo "  selinux: $have_selinux"
1137 echo "  systemd-journald: $have_systemd_journal (default: logging.backend=${nm_config_logging_backend_default})"
1138 echo "  hostname persist: ${hostname_persist}"
1139 echo "  libaudit: $have_libaudit (default: logging.audit=${NM_CONFIG_DEFAULT_LOGGING_AUDIT_TEXT})"
1140 echo
1141
1142 echo "Features:"
1143 echo "  wext: $ac_with_wext"
1144 echo "  wifi: $enable_wifi"
1145 echo "  ppp: $enable_ppp"
1146 echo "  modemmanager-1: $with_modem_manager_1"
1147 echo "  concheck: $enable_concheck"
1148 echo "  libteamdctl: $enable_teamdctl"
1149 echo "  libnm-glib: $with_libnm_glib"
1150 echo "  nmcli: $build_nmcli"
1151 echo "  nmtui: $build_nmtui"
1152 echo
1153
1154 echo "Configuration plugins (main.plugins=${config_plugins_default})"
1155 echo "  ibft: ${enable_config_plugin_ibft}"
1156 echo "  ifcfg-rh: ${enable_ifcfg_rh}"
1157 echo "  ifupdown: ${enable_ifupdown}"
1158 echo "  ifnet: ${enable_ifnet}"
1159 echo
1160
1161 echo "Handlers for /etc/resolv.conf:"
1162 echo "  resolvconf: ${with_resolvconf}"
1163 echo "  netconfig: ${with_netconfig}"
1164 echo
1165
1166 echo "DHCP clients:"
1167 echo "  dhclient: $with_dhclient"
1168 echo "  dhcpcd: $with_dhcpcd"
1169 echo
1170
1171 echo "Miscellaneous:"
1172 echo "  documentation: $enable_gtk_doc"
1173 echo "  tests: $enable_tests"
1174 echo "  more-asserts: $more_asserts"
1175 echo "  valgrind: $with_valgrind   $with_valgrind_suppressions"
1176 echo "  code coverage: $enable_code_coverage"
1177 echo "  LTO: $enable_lto"
1178 echo